Что нового

[Время, дата] Автоматическая смена времени, даты в файлах

RuslanTigran

Новичок
Версия AutoIt: установлю любую необходимую

Описание: Нужен скрипт, который будет сам менять у файлов время и дату на необходимую мне.

Примечания: На работе должен делать снимки и отчеты вовремя, с интервалом в 10 дней или типа того. Иногда пропускаю дедлайны или делаю всё в последний момент, приходится менять время и дату вручную. Бывает по 700-800 фотографий в месяц, менял вручную с помощью FileDate Changer

Иногда проверяют дату, типа "а че это у тебя всё сделано после дедлайна" Несколько раз у всех файлов скидывал дату в один день и одну минуту, типа " не знаю, само как-то ", но кажется, больше такое не прокатит :D

Что должен делать скрипт:
из папки выбрать файл, заменить на нем дату, (скажем вместо 26 ноября поставить 5 ноября) и поменять время, допустим на 12:53:15. Затем следующему файлу из этой папки поставить ту же дату, а время заменить +5 минут (желательно, чтобы был зазор плюс-минус несколько рандомных минут, а то будет подозрительно, что все файлы были созданы с четким интервалом)
Если будет возможность задавать конкретную начальную дату и время, а потом от нее циклом прибавлять время, было бы вообще круто.
ну или на крайняк, если скрипт будет брать мои значения, ну скажем из excel файла или блокнота
Итого, должна получится видимость, что я работал весь месяц добросовестно :3
 
A

Alofa

Гость
RuslanTigran сказал(а):
... а то будет подозрительно, что все файлы были созданы с четким интервалом...
Нет, если работу будете выполнять вовремя, то есть если это будет делать скрипт. Может быть такой вариант?

RuslanTigran сказал(а):
... должен делать снимки и отчеты...
В каком это все формате?

OffTopic:
Честно:
- Прикольный стиль описания, немногие посты читаю с удовольствием => Захотелось помочь
- Дочитал до конца => Подумал
- На самом-то деле все так грустно, по Российски :( => Неа, я пас.
 

joiner

Модератор
Локальный модератор
OffTopic:
капец народ ленивый. вообще работать не хотят. зато бабки давай.
Alofa, ты денег попроси с автора темы. пусть хоть свою лень оплатит.
Сообщество, прошу извинить меня за эмоции, но такой неприкрытой наглости пост задел.
 

Tempo

Скриптер
OffTopic:
Проверка уровня наглости

Код:
#include <DateTimeConstants.au3>
#include <GuiConstantsEx.au3>
#include <EditConstants.au3>
#include <File.au3>
Opt("TrayAutoPause", 0)
TraySetToolTip(Chr(0))

Global $iDate, $aInputs[4][2], $iStart, $sDir, $aList, $aDate, _
    $aRandom[4][3] = [[0, 30],[0, 23],[0, 60],[0, 60]], $vTemp, _
    $iType = 0, $iRadio1, $iRadio2, $iRadio3, $iMask, $sMask = "*"
GUICreate("Скрипт", 165, 250)
$iDate = GUICtrlCreateDate(Null, 5, 5, 155, 20)
GUICtrlSendMsg(-1, 0x1032, 0, ".../MM/yyyy")
$aInputs[0][0] = GUICtrlCreateInput(Null, 5, 30, 75, 20, $ES_NUMBER)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Число От")
GUICtrlSetLimit(-1, 2)
GUICtrlSetTip(-1, "По умолчанию 0")
$aInputs[0][1] = GUICtrlCreateInput(Null, 85, 30, 75, 20, $ES_NUMBER)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Число До")
GUICtrlSetLimit(-1, 2)
GUICtrlSetTip(-1, "По умолчанию 30")
$aInputs[1][0] = GUICtrlCreateInput(Null, 5, 55, 75, 20, $ES_NUMBER)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Час От")
GUICtrlSetLimit(-1, 2)
GUICtrlSetTip(-1, "По умолчанию 0")
$aInputs[1][1] = GUICtrlCreateInput(Null, 85, 55, 75, 20, $ES_NUMBER)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Час До")
GUICtrlSetLimit(-1, 2)
GUICtrlSetTip(-1, "По умолчанию 23")
$aInputs[2][0] = GUICtrlCreateInput(Null, 5, 80, 75, 20, $ES_NUMBER)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Минуты От")
GUICtrlSetLimit(-1, 2)
GUICtrlSetTip(-1, "По умолчанию 0")
$aInputs[2][1] = GUICtrlCreateInput(Null, 85, 80, 75, 20, $ES_NUMBER)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Минуты До")
GUICtrlSetLimit(-1, 2)
GUICtrlSetTip(-1, "По умолчанию 60")
$aInputs[3][0] = GUICtrlCreateInput(Null, 5, 105, 75, 20, $ES_NUMBER)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Секунды От")
GUICtrlSetLimit(-1, 2)
GUICtrlSetTip(-1, "По умолчанию 0")
$aInputs[3][1] = GUICtrlCreateInput(Null, 85, 105, 75, 20, $ES_NUMBER)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Секунды До")
GUICtrlSetLimit(-1, 2)
GUICtrlSetTip(-1, "По умолчанию 60")
$iMask = GUICtrlCreateInput(Null, 45, 130, 75, 20)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Маска *.*")
GUICtrlSetTip(-1, "По умолчанию все файлы")
GUICtrlCreateGroup("Дата", 5, 155, 155, 60)
$iRadio1 = GUICtrlCreateRadio("Создания", 10, 170, 70, 20)
$iRadio2 = GUICtrlCreateRadio("Открытия", 85, 170, 70, 20)
$iRadio3 = GUICtrlCreateRadio("Изменения", 10, 190, 75, 20)
GUICtrlSetState(-1, $GUI_CHECKED)
$iStart = GUICtrlCreateButton("Запуск", 40, 220, 85, 25)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $iStart
            $sDir = FileSelectFolder(Null, Null, 4)
            If Not @error Then
                GUISetState(@SW_HIDE)
                TrayTip("Скрипт", "Работает...", 5)
                TraySetToolTip("Работает...")
                $sMask = GUICtrlRead($iMask)
                If Not $sMask Then $sMask = "*"
                For $i = 0 To 3
                    $vTemp = GUICtrlRead($aInputs[$i][0])
                    If StringLen($vTemp) >= 1 Then $aRandom[$i][0] = $vTemp
                    $vTemp = GUICtrlRead($aInputs[$i][1])
                    If StringLen($vTemp) >= 1 Then $aRandom[$i][1] = $vTemp
                Next
                $aDate = StringSplit(GUICtrlRead($iDate), "/", 2)
                $aList = _FileListToArrayRec($sDir, $sMask, $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_FASTSORT, $FLTAR_FULLPATH)
                For $i = 1 To $aList[0]
                    For $j = 0 To 3
                        $aRandom[$j][2] = Random($aRandom[$j][0], $aRandom[$j][1], 1)
                        If StringLen($aRandom[$j][2]) = 1 Then $aRandom[$j][2] = 0 & $aRandom[$j][2]
                    Next
                    FileSetTime($aList[$i], $aDate[2] & $aDate[1] & $aRandom[0][2] & $aRandom[1][2] & $aRandom[2][2] & $aRandom[3][2], $iType)
                Next
                MsgBox(64, "Скрипт", "Закончил работу")
                GUISetState()
            EndIf
        Case $iRadio1
            $iType = 1
        Case $iRadio2
            $iType = 2
        Case $iRadio3
            $iType = 0
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
 
Автор
R

RuslanTigran

Новичок
Я и не прошу сделать мне бесплатно, это же стол заказов, или чо? Если я за эти деньги, которые там платят, буду делать работу так, как они хотят, у меня будет уходить слишком много времени и сил, работа потеряет свою актуальность.
Давайте вы свою мораль себе оставите, окда?) Я на этой работе работаю официально и даже налоги плачу. Вы все на своих работах налоги платите ?
В остальное время я работаю учителем и репетитором.


Добавлено:
Сообщение автоматически объединено:

Спасибо, Tempo , не знаю, как тут лайки работают, наверно у меня эта функция пока недоступна. :beer: :ok:
 
Верх