Что нового

Строка адреса IE

aranea

Новичок
Сообщения
27
Репутация
4
Как получить строку адреса из IE?
ControlGetText( ) выдает не url, а другой текст.
Задача состоит в том что бы проверить адрес и если он тот что ожидается подставить другой.
 

snoitaleR

AutoIT Гуру
Сообщения
854
Репутация
223
aranea
Мой вариант:

Код:
; НАЧАЛО

 If WinExists("[CLASS:IEFrame]") Then
  $TEXT=ControlGetText("[CLASS:IEFrame]","","[CLASS:Edit;INSTANCE:1]")
  MsgBox(0,"Текст в адресной строке:",$TEXT)
 Else
  MsgBox(0,"Внимание!","Нет открытых окон MIE...")
 EndIf

; КОНЕЦ
 
Автор
A

aranea

Новичок
Сообщения
27
Репутация
4
Спасибо
 

madmasles

Модератор
Глобальный модератор
Сообщения
7 790
Репутация
2 319
aranea
Можно, наверное, еще так попробовать:
Код:
#include <IE.au3>

$sUrlOld = 'http://mail.ru/' ;адрес для проверки
$sUrlNew = 'http://autoit-script.ru/' ;адрес для перехода
If Not WinExists("[CLASS:IEFrame]") Then
	MsgBox(0, "Error", "Нет открытого окна IE", 10)
	Exit
EndIf
$hHandle = WinGetHandle("[CLASS:IEFrame]")
If @error Then
	MsgBox(0, "Error", "Ошибка получения $hHandle IE", 10)
	Exit
EndIf
$oIE = _IEAttach($hHandle, "HWND")
If _IEPropertyGet($oIE, "locationurl") = $sUrlOld Then
	_IENavigate($oIE, $sUrlNew)
Else
	MsgBox(0, "The URL", _IEPropertyGet($oIE, "locationurl"))
EndIf
 

CreatoR

Must AutoIt!
Команда форума
Администратор
Сообщения
8 472
Репутация
2 401
А можно ещё через DDE:

Код:
#include <Array.au3>

$Ret = OpenGetURL("", -1, 1, "IExplore")
_ArrayDisplay($Ret, "IExplore")

$Ret = OpenGetURL("", -1, 1, "FireFox")
_ArrayDisplay($Ret, "FireFox")

$Ret = OpenGetURL("", -1, 1, "Opera")
_ArrayDisplay($Ret, "Opera")

;===============================================================================
;
; Function Name:  OpenGetURL()
;
; Parameter(s):		$sURL			[optional] Address of page to open,
;									if this is empty string (default), then returned Url from address field of particular tab.
;					$hWin			[optional] Number of tab:
;										-1 = Current tab.
;										0 = New tab (when opening).
;					$RetType 		[optional] Definds returned value:
;										0 = String with Title and URL address.
;										1 = Array with 3 elements...
;											[0] = Title
;											[1] = URL address
;											[2] = String with Title And URL address.
;					$Server			[optional] Serever to open/get Url in/from.
;					$iWait			[optional] Waiting Timeout in milliseconds, on overload will return an error.
;
; Requirement(s):	None
; Return Value(s):	On Success -  See 'Parameter(s)'.
;					On Failure -  Empty string and set @error as following:
;						1 = Error to open Dll (user32.dll)
;						2 = Error Initializing DDE (@extended include more details about the returned value from DllCall).
;						3 = Other DDE Errors (@extended include more details about the returned value from DllCall).
; Author(s):        amel27
;
;=====================================================================
Func OpenGetURL($sURL = "", $hWin = -1, $RetType = 0, $Server="IExplore", $iWait = 10000)
	Local $ret, $err, $uIdInst = DllStructCreate("int")
	Local $hServer[1], $hTopic[1], $hItem[1], $hConv[1], $hData[1], $sData[1]
	Local $sTopic = "WWW_OpenURL", $sItem = $sURL & ',,0x' & Hex($hWin)
	
	If $sURL = '' Then
		$sTopic = "WWW_GetWindowInfo"
		$sItem = "0x" & Hex($hWin)
	EndIf
	
	Local $hDll = DllOpen("user32.dll")
	If $hDll=-1 Then Return SetError(1, 0, "") ; Error to open Dll
	$ret = DllCall("user32.dll", "int", "DdeInitialize", "ptr", DllStructGetPtr($uIdInst), "ptr", 0, "int", 0, "int", 0)
	If $ret[0] Then Return SetError(2, $ret[0], "") ; Error Initializing DDE
	$hServer = DllCall($hDll, "int", "DdeCreateStringHandle", "int", DllStructGetData($uIdInst,1), "str", $Server, "int", 1004)
	
	If $hServer[0] Then
		$hTopic = DllCall($hDll, "int", "DdeCreateStringHandle", "int", DllStructGetData($uIdInst,1), "str", $sTopic, "int", 1004)
		If $hTopic[0] Then
			$hItem = DllCall($hDll, "int", "DdeCreateStringHandle", "int", DllStructGetData($uIdInst,1), "str", $sItem, "int", 1004)
			If $hItem[0] Then
				$hConv = DllCall($hDll, "int", "DdeConnect", "int", _
					DllStructGetData($uIdInst,1), "int", $hServer[0], "int", $hTopic[0], "int", 0)
				If $hConv[0] Then
					$hData = DllCall($hDll, "int", "DdeClientTransaction", "ptr", 0, "int", 0, _
						"int", $hConv[0], "int", $hItem[0], "int", 1, "int", 0x20B0, "int", $iWait, "ptr", 0)
					If $hData[0] Then $sData = DllCall($hDll, "str", "DdeAccessData", "int", $hData[0], "ptr", 0)
				EndIf
			EndIf
		EndIf
	EndIf
	
	$iErr = DllCall($hDll, "int", "DdeGetLastError", "int", DllStructGetData($uIdInst, 1))
	If $hData[0] Then DllCall($hDll, "int", "DdeFreeDataHandle", "int", $hData[0])
	If $hConv[0] Then DllCall($hDll, "int", "DdeFreeDataHandle", "int", $hConv[0])
	If $hItem[0] Then DllCall($hDll, "int", "DdeFreeDataHandle", "int", $hItem[0])
	If $hTopic[0] Then DllCall($hDll, "int", "DdeFreeDataHandle", "int", $hTopic[0])
	If $hServer[0] Then DllCall($hDll, "int", "DdeFreeDataHandle", "int", $hServer[0])
	If $iErr[0] Then Return SetError(3, $iErr[0], "") ; Othe DDE Errors
	DllCall($hDll, "int", "DdeUninitialize", "int", DllStructGetData($uIdInst, 1))
	DllClose($hDll)
	
	$sData[0] = StringRegExpReplace($sData[0], ',""$', '')
	If $sURL = '' Then $sURL = StringRegExpReplace($sData[0], '^"([^"]*)",.*', '\1')
	
	Local $iRetTitle = StringRegExpReplace($sData[0], '^.*","([^"]*)"$', '\1')
	Local $RetURL[3] = [$sData[0], $sURL, $iRetTitle]
	
	If $RetType = 1 Then Return $RetURL
	Return $sData[0]
EndFunc
 

madmasles

Модератор
Глобальный модератор
Сообщения
7 790
Репутация
2 319
Только надо учесть, что OpenGetURL() возвращает адрес в кавычках.
 

kalpak44

Новичок
Сообщения
45
Репутация
1
люди плиз на хром подскажите как узнать открытый адресс???
 
Верх