[Окна, Диалоги] Создание вторичного окна

[БЕШАННЫЙ]

Люди помогите я сейчас создаю программу при написание скрипта я столкнулся с такой проблемой:
При нажатие кнопки $Button1 (Настройка) у меня выбивает окно настроек! Но при закрытии окна настройки закрывается весь скрипт! А мне нужно чтобы окно настройки можна было свободно открывать и закрыть без закрытия программы!
Вот сам скрипт!

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 224, 51, 500, 442)
GUISetBkColor(0xFFFFFF)
$Button1 = GUICtrlCreateButton("Настройка", 8, 8, 89, 33)
$Button2 = GUICtrlCreateButton("Exit", 128, 8, 89, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
Case $Button1
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 413, 298, 351, 216)
GUISetBkColor(0xFFFFFF)
$Button1 = GUICtrlCreateButton("Ok", 8, 256, 89, 33)
$Button2 = GUICtrlCreateButton("Exit", 320, 256, 89, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit


Case $Button2
Exit


 EndSwitch
WEnd



Case $Button2
Exit

 EndSwitch
WEnd

 

[CreatoR]

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region Main form
$hMain_GUI = GUICreate("Form1", 224, 51, 500, 442)
GUISetBkColor(0xFFFFFF)
$nPrefs_Btn = GUICtrlCreateButton("Настройка", 8, 8, 89, 33)
$nExit_Btn = GUICtrlCreateButton("Exit", 128, 8, 89, 33)
GUISetState(@SW_SHOW, $hMain_GUI)
#EndRegion Main form

#Region Settings form
$hSettings_GUI = GUICreate("Form1", 413, 298, 351, 216)
GUISetBkColor(0xFFFFFF)
$nStngs_Ok_Btn = GUICtrlCreateButton("Ok", 8, 256, 89, 33)
$nStngs_Close_Btn = GUICtrlCreateButton("Close", 320, 256, 89, 33)
#EndRegion Settings form

While 1
	$aMsg = GUIGetMsg(1)
	
	Switch $aMsg[0]
		Case $GUI_EVENT_CLOSE, $nExit_Btn, $nStngs_Close_Btn
			If $aMsg[1] = $hMain_GUI Or $aMsg[0] = $nExit_Btn Then
				Exit
			EndIf
			
			If $aMsg[1] = $hSettings_GUI Or $aMsg[0] = $nStngs_Close_Btn Then
				GUISetState(@SW_HIDE, $hSettings_GUI)
			EndIf
		Case $nPrefs_Btn
			GUISetState(@SW_SHOW, $hSettings_GUI)
	EndSwitch
WEnd