Что нового

нажать на кнопку, картинку

trudmoy

Новичок
Сообщения
15
Репутация
1
Версия AutoIt: 3.

На страничке http://www.tripadvisor.com/SmartDeals-g188553-The_Netherlands-Hotel-Deals.html есть оранжевая кнопка: связанный текст: CHECK RATES! Как сделать на ней клик функцией _IE*.
Через поиск пикселя не получается - на другом ПК пиксель не находит. Хотелось бы обойтись без мышки вообще.

Примечания:
 

Garrett

Модератор
Локальный модератор
Сообщения
3 999
Репутация
964
Код:
#include<IE.au3>
$oIE = _IECreate("http://www.tripadvisor.com/SmartDeals-g188553-The_Netherlands-Hotel-Deals.html")
$oButton = _IEGetObjById($oIE, "CHECK_RATE") ; 1-я кнопка
_IEAction($oButton, "click") ; щёлкаем на 1-й кнопке
 

`p r o x y

«Улыбайтесь, господа!»
Команда форума
Глобальный модератор
Сообщения
596
Репутация
157
На все кнопки. Причем в зависимости от элемента IMG или DIV

Код:
#include <IE.au3>

Opt('MustDeclareVars',		1)

Global	$oIE, $oDiv, $sTeg='DIV', $oLinks, $oLink

$oIE 	 = _IECreate('http://www.tripadvisor.com/SmartDeals-g188553-The_Netherlands-Hotel-Deals.html')
$oDiv 	 = _IEGetObjById($oIE, 'SDSLTOP')

$oLink 	 = _IEGetObjById($oIE, 'CHECK_RATE')
If StringLeft(_IEPropertyGet($oLink, 'outerhtml'), 4) == '<IMG' Then $sTeg = 'IMG'
ConsoleWrite($sTeg & @CRLF)

$oLinks  = _IETagNameGetCollection($oDiv, $sTeg)
For $oLink In $oLinks
	If $oLink.id == 'CHECK_RATE' Then
		;MsgBox(0,0, _IEPropertyGet($oLink, 'outerhtml'))
		_IEAction($oLink, 'click')
	EndIf
Next
 

Garrett

Модератор
Локальный модератор
Сообщения
3 999
Репутация
964
Ещё вариант.
Функция выбора кнопки:
Код:
#include<IE.au3>
Dim $oIE = _IECreate("http://www.tripadvisor.com/SmartDeals-g188553-The_Netherlands-Hotel-Deals.html")

_ClickButton($oIE, 2) ; щёлкаем по 2-й кнопке

Func _ClickButton(ByRef $_Obj, $iNum)
	Local $i, $oButtons = _IEImgGetCollection($_Obj)

	For $oButton In $oButtons ; "CHECK_RATE"
		If $oButton.getAttribute("id") == "CHECK_RATE" Then
			$i += 1
				If $i = $iNum Then
				_IEAction($oButton, "click")
			EndIf
		EndIf
	Next
EndFunc ;==>_ClickButton
 
Автор
trudmoy

trudmoy

Новичок
Сообщения
15
Репутация
1
Всем - большое, человеческое, спасибо!
 
Верх