Что нового

Маркер выбора на 1 лист

lexaSF

Новичок
Сообщения
182
Репутация
3
У меня есть 2 List.Как мне сделать чтобы маркер выбора был только на одном, а то я выбираю и в 1 и в другом, и получается что у меня выбрано 2 строки.
 

madmasles

Модератор
Глобальный модератор
Сообщения
7 790
Репутация
2 319
lexaSF
:wacko: :'(
 
Автор
L

lexaSF

Новичок
Сообщения
182
Репутация
3
У меня есть List1 и List2.В каждом из них можно нажть на строку, которая станет синей.Как сделать чтобы можно было делать синей строку только на 1 из List?
 

madmasles

Модератор
Глобальный модератор
Сообщения
7 790
Репутация
2 319
lexaSF
Код:
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>

$hGui = GUICreate('Test', 400, 200)
$nList1 = GUICtrlCreateList('', 10, 10, 185, 180)
$nList2 = GUICtrlCreateList('', 195, 10, 185, 180)
GUISetState()
For $i = 1 To 10
	GUICtrlSetData($nList1, $i & ' string')
	GUICtrlSetData($nList2, $i & $i & ' string')
Next

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $nList1
			_GUICtrlListBox_SetCurSel(GUICtrlGetHandle($nList2), -1)
			MsgBox(0, '', GUICtrlRead($nList1))
		Case $nList2
			_GUICtrlListBox_SetCurSel(GUICtrlGetHandle($nList1), -1)
			MsgBox(0, '', GUICtrlRead($nList2))
	EndSwitch
WEnd

Или так:
Код:
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>

$hGui = GUICreate('Test', 400, 200)
$nList1 = GUICtrlCreateList('', 10, 10, 185, 180)
$nList2 = GUICtrlCreateList('', 195, 10, 185, 180)
GUISetState()
For $i = 1 To 10
	GUICtrlSetData($nList1, $i & ' string')
	GUICtrlSetData($nList2, $i & $i & ' string')
Next

While 1
	$aPos = GUIGetCursorInfo()
	If Not @error Then
		If $aPos[2] Then
			Switch $aPos[4]
				Case $nList1
					_GUICtrlListBox_SetCurSel(GUICtrlGetHandle($nList2), -1)
				Case $nList2
					_GUICtrlListBox_SetCurSel(GUICtrlGetHandle($nList1), -1)
			EndSwitch
		EndIf
	EndIf
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd
 
Автор
L

lexaSF

Новичок
Сообщения
182
Репутация
3
спасибо :D
 

kaster

Мой Аватар, он лучший самый
Команда форума
Глобальный модератор
Сообщения
4 020
Репутация
622
lexaSF
можно глупый вопрос?
если у человека, с проблемой подобной твоей возникнет желание сначала поискать по определенных ключевым словам нужную тему, сможет ли он найти твою? и еще, если человек будет искать что-то связанными с листами - прокатными, или формата А0-А4, либо тетради (мало-ли) что ему дас твоя тема, которая высветится в поиске?
 
Верх