Label не работает прокрутка $WS_VSCROLL

[RUVATA]

Всем доброго времени суток...
Я ни как не могу понять почему у меня не работает вертикальная прокрутка в элементе Label
Я потратил уже неприлично много времени на решение этой проблемы, прошу помощи у коллективного разума...

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

$Form1 = GUICreate("Form1", 634, 127, 192, 371)
$Start = GUICtrlCreateButton("Начать", 16, 8, 129, 41)
$LowLevelStat = GUICtrlCreateLabel("0%", 16, 64, 610, 49, BitOR($SS_CENTER,$SS_CENTERIMAGE,$WS_BORDER))
$DynamicStat = GUICtrlCreateLabel("", 16, 63, 12, 49, BitOR($SS_CENTER,$SS_CENTERIMAGE,$WS_BORDER))
GUICtrlSetBkColor(-1, 0x4395D1)
$Console = GUICtrlCreateLabel("...", 152, 8, 470, 42, BitOR($SS_SUNKEN,$WS_VSCROLL))
GUICtrlSetColor(-1, 0x00FF00)
GUICtrlSetBkColor(-1, 0x000000)
GUISetState(@SW_SHOW)

GUICtrlSetState($DynamicStat, $GUI_HIDE)
GUICtrlSetData($Console, "111111111111" & @CRLF & "1111111111" & @CRLF & "111111111111" & @CRLF & "111111111111" & @CRLF & "1111111111111" & @CRLF & "1111111111111111111" & @CRLF & "11111111111111111" & @CRLF & "111111111111")


While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
 EndSwitch
WEnd

Скрол отображается но ни хрена не прокручивает.

PS: Если важно AutoIt v3.3.6.1 Windows 7 Pro (x86)

 

[CreatoR]

А кто сказал что Label должен прокручиваться?


Добавлено:

Сообщение автоматически объединено: 17 Фев 2012

Можно сделать так:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

$Form1 = GUICreate("Form1", 634, 127, 192, 371)

$nDummy = GUICtrlCreateInput('', -100, -100)

$nConsole = GUICtrlCreateEdit("...", 152, 8, 470, 60, BitOR($SS_SUNKEN, $WS_VSCROLL))
GUICtrlSetData($nConsole, "111111111111" & @CRLF & "1111111111" & @CRLF & "111111111111" & @CRLF & "111111111111" & @CRLF & "1111111111111" & @CRLF & "1111111111111111111" & @CRLF & "11111111111111111" & @CRLF & "111111111111")
GUICtrlSetColor(-1, 0x00FF00)
GUICtrlSetBkColor(-1, 0x000000)

GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
	$nMsg = GUIGetMsg()
	
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd

Func WM_COMMAND($hWnd, $nMsg, $wParam, $lParam)
	Local $nNotifyCode = BitShift($wParam, 16)
	Local $nID = BitAND($wParam, 0xFFFF)
	
	Switch $nID
		Case $nConsole
			Switch $nNotifyCode
				Case $EN_SETFOCUS
					ControlFocus($hWnd, '', $nDummy)
			EndSwitch
	EndSwitch
	
	Return $GUI_RUNDEFMSG
EndFunc

 

[sayman]

Хммм а если я хочу сделать форматированный текст?

 

[CreatoR]

а если я хочу сделать форматированный текст?

То нужна другая тема: GUIRichLabel