Что нового

If не правильно работает, где закралась ошибка?

JaG

Новичок
Сообщения
17
Репутация
0
Встретился с проблемой

Код:
#Include  <Crypt.au3>
#Include  <WinAPI.au3>

Global Const $UHID_MB = 0x00
Global Const $UHID_BIOS = 0x01
Global Const $UHID_CPU = 0x02
Global Const $UHID_HDD = 0x04

$gg = (_UniqueHardwaeIDv1() & @CR)

;ConsoleWrite(_UniqueHardwaeIDv1(BitOR($UHID_MB, $UHID_BIOS, $UHID_CPU)) & @CR)
;ConsoleWrite(_UniqueHardwaeIDv1(BitOR($UHID_MB, $UHID_BIOS, $UHID_CPU, $UHID_HDD)) & @CR)

Func _UniqueHardwaeIDv1($iFlags = 0)

    Local $oService = ObjGet('winmgmts:\\.\root\cimv2')

    If Not IsObj($oService) Then
        Return SetError(1, 0, '')
    EndIf

    Local $tSPQ, $tSDD, $oItems, $hFile, $Hash, $Ret, $Str, $Hw = '', $Result = 0

    $oItems = $oService.ExecQuery('SELECT * FROM Win32_ComputerSystemProduct')
    If Not IsObj($oItems) Then
        Return SetError(2, 0, '')
    EndIf
    For $Property In $oItems
        $Hw &= $Property.IdentifyingNumber
        $Hw &= $Property.Name
        $Hw &= $Property.SKUNumber
        $Hw &= $Property.UUID
        $Hw &= $Property.Vendor
        $Hw &= $Property.Version
    Next
    $Hw = StringStripWS($Hw, 8)
    If Not $Hw Then
        Return SetError(3, 0, '')
    EndIf
    If BitAND($iFlags, 0x01) Then
        $oItems = $oService.ExecQuery('SELECT * FROM Win32_BIOS')
        If Not IsObj($oItems) Then
            Return SetError(2, 0, '')
        EndIf
        $Str = ''
        For $Property In $oItems
            $Str &= $Property.IdentificationCode
            $Str &= $Property.Manufacturer
            $Str &= $Property.Name
            $Str &= $Property.SerialNumber
            $Str &= $Property.SMBIOSMajorVersion
            $Str &= $Property.SMBIOSMinorVersion
;           $Str &= $Property.Version
        Next
        $Str = StringStripWS($Str, 8)
        If $Str Then
            $Result += 0x01
            $Hw &= $Str
        EndIf
    EndIf
    If BitAND($iFlags, 0x02) Then
        $oItems = $oService.ExecQuery('SELECT * FROM Win32_Processor')
        If Not IsObj($oItems) Then
            Return SetError(2, 0, '')
        EndIf
        $Str = ''
        For $Property In $oItems
            $Str &= $Property.Architecture
            $Str &= $Property.Family
            $Str &= $Property.Level
            $Str &= $Property.Manufacturer
            $Str &= $Property.Name
            $Str &= $Property.ProcessorId
            $Str &= $Property.Revision
            $Str &= $Property.Version
        Next
        $Str = StringStripWS($Str, 8)
        If $Str Then
            $Result += 0x02
            $Hw &= $Str
        EndIf
    EndIf
    If BitAND($iFlags, 0x04) Then
        $oItems = $oService.ExecQuery('SELECT * FROM Win32_PhysicalMedia')
        If Not IsObj($oItems) Then
            Return SetError(2, 0, '')
        EndIf
        $Str = ''
        $tSPQ = DllStructCreate('dword;dword;byte[4]')
        $tSDD = DllStructCreate('ulong;ulong;byte;byte;byte;byte;ulong;ulong;ulong;ulong;dword;ulong;byte[512]')
        For $Property In $oItems
            $hFile = _WinAPI_CreateFile($Property.Tag, 2, 0, 0)
            If Not $hFile Then
                ContinueLoop
            EndIf
            $Ret = DllCall('kernel32.dll', 'int', 'DeviceIoControl', 'ptr', $hFile, 'dword', 0x002D1400, 'ptr', DllStructGetPtr($tSPQ), 'dword', DllStructGetSize($tSPQ), 'ptr', DllStructGetPtr($tSDD), 'dword', DllStructGetSize($tSDD), 'dword*', 0, 'ptr', 0)
            If (Not @error) And ($Ret[0]) And (Not DllStructGetData($tSDD, 5)) Then
                Switch DllStructGetData($tSDD, 11)
                    Case 0x03, 0x0B ; ATA, SATA
                        $Str &= $Property.SerialNumber
                EndSwitch
            EndIf
            _WinAPI_CloseHandle($hFile)
        Next
        $Str = StringStripWS($Str, 8)
        If $Str Then
            $Result += 0x04
            $Hw &= $Str
        EndIf
    EndIf
    $Hash = _Crypt_HashData($Hw, $CALG_MD5)
    If @error Then
        Return SetError(4, 0, '')
    EndIf
    $Hash = StringTrimLeft($Hash, 2)
    Return SetError(0, $Result, '{' & StringMid($Hash, 1, 8) & '-' & StringMid($Hash, 9, 4) & '-' & StringMid($Hash, 13, 4) & '-' & StringMid($Hash, 17, 4) & '-' & StringMid($Hash, 21, 12) & '}')
EndFunc   ;==>_UniqueHardwaeIDv1

If $gg = "{4A0BB37B-CF42-2A61-BD2A-9CE9EF636545}" Then
MsgBox(4096,"", "Value is positive.")
EndIf

скрипт определяет что значение не равно, хотя оно на 101% равно!

Можно ли както избавится от этой проблемы?

{4A0BB37B-CF42-2A61-BD2A-9CE9EF636545} на вашем компьютере, естесственно, будет другиим
 

SyDr

Сидра
Сообщения
651
Репутация
158
Re: If не правильно работает с большим текстовым значением

Какой проблемы? В приведённом примере $gg даже не объявлено. А после исправления, чтобы скрипт мог работать - всё срабатывает:
Код:
$gg = "4A0BB37BCF422A61BD2A9CE9EF636545"
If $gg = "4A0BB37BCF422A61BD2A9CE9EF636545" Then
    MsgBox(4096,"", "Value is positive.")
EndIf
 

dwerf

Использует ArchLinux
Сообщения
478
Репутация
218
Re: If не правильно работает с большим текстовым значением

JaG [?]
скрипт определяет что значение не равно, хотя оно на 101% равно!
Код:
$gg = "4A0BB37BCF422A61BD2A9CE9EF636545"
If $gg = "4A0BB37BCF422A61BD2A9CE9EF636545" Then
    MsgBox(4096,"", "Value is positive.")
EndIf


Работает прекрасно. Отсюда вывод: 101% не бывает, бывает 96%.
Ошибка где-то в другом месте.
 
Автор
J

JaG

Новичок
Сообщения
17
Репутация
0
Re: If не правильно работает с большим текстовым значением

Извеняюсь, подправил первый пост
 

dwerf

Использует ArchLinux
Сообщения
478
Репутация
218
Код:
$gg = (_UniqueHardwaeIDv1() & @CR)

Зачем вам тут @CR? Сотрите - заработает.
 
Автор
J

JaG

Новичок
Сообщения
17
Репутация
0
dwerf, спасибо большое, плюс видимо не могу поставить, или не могу найти где же ставить, форум не удобный...
 
Верх