Что нового

Цвет текста GUICtrlCreateCheckbox

rusreg79

Продвинутый
Сообщения
159
Репутация
57
Как изменить цвет текста у элемента GUICtrlCreateCheckbox, что не делаю он всегда черный :wacko:


Код:
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 125, 48, 192, 124)
GUISetBkColor(0x808000)


$Checkbox1 = GUICtrlCreateCheckbox("Цвет текста", 16, 16, 97, 17)
GUICtrlSetColor(-1, 0xFF0000);красный



GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit

	EndSwitch
WEnd
 

madmasles

Модератор
Глобальный модератор
Сообщения
7 790
Репутация
2 319
rusreg79
Можно, наверное, так попробовать:
Код:
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 125, 48, 192, 124)
GUISetBkColor(0x808000)

$Checkbox1 = GUICtrlCreateCheckbox("", 16, 16, 16, 16)
GUICtrlCreateLabel("Цвет текста", 32, 17, 70, 16)
GUICtrlSetColor(-1, 0xFF0000);красный
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd
 

dwerf

Использует ArchLinux
Сообщения
478
Репутация
218
Отсюда

Код:
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1_1 = GUICreate("Big Checkbox", 210, 180, 300, 233)
;i normale Checkbox
$Checkbox0 = GUICtrlCreateCheckbox("Checkbox basic", 30, 10, 150, 35)
;i Checkbox color
DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox color", 30, 50, 150, 35)
GUICtrlSetColor(-1, 0xFF0000) ;i rot
DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 7)
;i grosse Checkbox Schriftart und Grösse anders
$Checkbox2 = GUICtrlCreateCheckbox("Grosse Checkbox", 30, 90, 150, 35, BitOR($BS_CHECKBOX,$BS_AUTOCHECKBOX,$BS_PUSHLIKE,$WS_TABSTOP))
GUICtrlSetFont(-1, 12, 400, 0, "Wingdings")
;i grosse Checkbox mit Icon
$Checkbox3 = GUICtrlCreateCheckbox("&s", 30, 130, 150, 35, BitOR($BS_ICON, $BS_PUSHLIKE))
GUICtrlSetImage(-1, "shell32.dll", 7)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

А вообще я бы сделал checkbox без текста и дорисовал бы рядом label, как madmasles.
Мало ли, придёться скрипт на чужой системе запускать, а там проблема с этой dll'кой.
 
Верх