Тема: Создания Hash RDP пароля в autoit (Прочитано 1213 раз)

beliy · « **Создано:** Декабрь 07, 2011, 19:19:47 »

Версия AutoIt: последняя

Описание: Помогите получить способ генерации Hash rdp средствами Autoit

Примечания: это можно делать с помощью разных сторонних утилит, но хотелось бы получать автоматически самим скриптом. Что б вы понимали - пишу скрипт для генерации многих необходимых rdp подключений под конкретные логин/пасс дабы не создавать вручную новым пользователям...
Вот статья которая может помочь - http://www.remkoweijnen.nl/blog/2007/10/18/how-rdp-passwords-are-encrypted/
Заранее большое спасибо...

beliy

Извиняюсь, но вероятно мы не совсем друг друга поняли

Уточнения:
1. надо код на Autoit для генерации hash аналогично как это делает сама windows, а не готовая тулза
2. насколько мне известно шифруется hash не в RC4, а с помошью функции CryptProtectData - http://msdn.microsoft.com/en-us/library/ms884464.aspx.

P.S. Проблема уже решена - тему закрываю.

Вот функция Autoit:

Код: AutoIt [Выделить]

Func CryptRDPPassword($str)
    Local Const $CRYPTPROTECT_UI_FORBIDDEN = 0x1
    Local Const $DATA_BLOB = "int;ptr"

    Local $passStr = DllStructCreate("byte[1024]")
    Local $DataIn = DllStructCreate($DATA_BLOB)
    Local $DataOut = DllStructCreate($DATA_BLOB)
    $pwDescription = 'psw'
    $PwdHash = ""

    DllStructSetData($DataOut, 1, 0)
    DllStructSetData($DataOut, 2, 0)

    DllStructSetData($passStr, 1, StringToBinary($str,2)); UTF16 Little Endian
    DllStructSetData($DataIn, 2, DllStructGetPtr($passStr, 1))
    DllStructSetData($DataIn, 1, StringLen($str)*2)

    $return = DllCall("crypt32.dll","int", "CryptProtectData", _
                                    "ptr", DllStructGetPtr($DataIn), _
                                    "wstr", $pwDescription, _
                                    "ptr", 0, _
                                    "ptr", 0, _
                                    "ptr", 0, _
                                    "dword", $CRYPTPROTECT_UI_FORBIDDEN, _
                                    "ptr", DllStructGetPtr($DataOut))
    If @error Then Return ""

    $len = DllStructGetData($DataOut, 1)
    $PwdHash = Ptr(DllStructGetData($DataOut, 2))
    $PwdHash = DllStructCreate("byte[" & $len & "]", $PwdHash)
    Return DllStructGetData($PwdHash, 1)
EndFunc

Func UncryptRDPPassword($bin)
    Local Const $CRYPTPROTECT_UI_FORBIDDEN = 0x1
    Local Const $DATA_BLOB = "int;ptr"

    Local $passStr = DllStructCreate("byte[1024]")
    Local $DataIn = DllStructCreate($DATA_BLOB)
    Local $DataOut = DllStructCreate($DATA_BLOB)
    $pwDescription = 'psw'
    $PwdHash = ""

    DllStructSetData($DataOut, 1, 0)
    DllStructSetData($DataOut, 2, 0)

    DllStructSetData($passStr, 1, $bin)
    DllStructSetData($DataIn, 2, DllStructGetPtr($passStr, 1))
    DllStructSetData($DataIn, 1, BinaryLen($bin))

    $return = DllCall("crypt32.dll","int", "CryptUnprotectData", _
                                    "ptr", DllStructGetPtr($DataIn), _
                                    "ptr", 0, _
                                    "ptr", 0, _
                                    "ptr", 0, _
                                    "ptr", 0, _
                                    "dword", $CRYPTPROTECT_UI_FORBIDDEN, _
                                    "ptr", DllStructGetPtr($DataOut))
    If @error Then Return ""

    $len = DllStructGetData($DataOut, 1)
    $PwdHash = Ptr(DllStructGetData($DataOut, 2))
    $PwdHash = DllStructCreate("byte[" & $len & "]", $PwdHash)
    Return BinaryToString(DllStructGetData($PwdHash, 1), 2)
EndFunc
 

Русское сообщество AutoIt

Новости:

Автор Тема: Создания Hash RDP пароля в autoit (Прочитано 1213 раз)

beliy [?]

Создания Hash RDP пароля в autoit

beliy [?]

Re: Создания Hash RDP пароля в autoit