Обход проблемы с HotKeySet/Accelerators при разных раскладках клавиатуры

[CreatoR [?]]

Вот так можно обойти эту проблему:

Код: AutoIt [Выделить]

#include <GUIConstantsEx.au3>
#include <GUIEdit.au3>
#include <WinAPIEx.au3>

_FixAccelHotKeyLayout()

HotKeySet("^+e", "_Quit")

$hGUI = GUICreate("Fix for hotkey/Accelerators assign problem", 300, 200)
$nEdit = GUICtrlCreateEdit("", 20, 40, 260, 120)

$nDummy = GUICtrlCreateDummy()
Dim $aAccelKeys[1][2] = [["^a", $nDummy]]
GUISetAccelerators($aAccelKeys)

GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $nDummy
            _GUICtrlEdit_SetSel($nEdit, 0, -1)
    EndSwitch
WEnd

Func _Quit()
    Exit
EndFunc

Func _FixAccelHotKeyLayout()
    Static $iKbrdLayout, $aKbrdLayouts
   
    If Execute('@exitMethod') <> '' Then
        Local $iUnLoad = 1
       
        For $i = 1 To $aKbrdLayouts[0]
            If Hex($iKbrdLayout) = Hex('0x' & StringRight($aKbrdLayouts[$i], 4)) Then
                $iUnLoad = 0
                ExitLoop
            EndIf
        Next
       
        If $iUnLoad Then
            _WinAPI_UnloadKeyboardLayout($iKbrdLayout)
        EndIf
       
        Return
    EndIf
   
    $iKbrdLayout = 0x0409
    $aKbrdLayouts = _WinAPI_GetKeyboardLayoutList()
    _WinAPI_LoadKeyboardLayout($iKbrdLayout, $KLF_ACTIVATE)
   
    OnAutoItExitRegister('_FixAccelHotKeyLayout')
EndFunc

[Dima1337 [?]]

CreatoR,
Большое спасибо 

[Skif_off [?]]

CreatoR
AutoIt 3.3.8.1: если завершать скрипт с помощью Exit, то вылезает сообщение об ошибке в строке

Код: AutoIt [Выделить]

For $i = 1 To $aKbrdLayouts[0]

что $aKbrdLayouts[0] - не массив. Как можно пофиксить?


Добавлено: Ноябрь 03, 2015, 01:27:09Если возможно, заодно сделать универсальной, заменив

Код: AutoIt [Выделить]

$iKbrdLayout = 0x0409

на полученный с помощью _WinAPI_GetKeyboardLayout()?

[CreatoR [?]]

Skif_off  [?]

Как можно пофиксить?

Заменить

Код: AutoIt [Выделить]

Static $iKbrdLayout, $aKbrdLayouts

на

Код: AutoIt [Выделить]

Global $iKbrdLayout, $aKbrdLayouts

[?]

Если возможно, заодно сделать универсальной, заменив

Идея в том, чтобы загружать английскую раскладку, а не ту что установлена в системе.

[Skif_off [?]]

CreatoR
Спасибо, так заработало.

Идея в том, чтобы загружать английскую раскладку, а не ту что установлена в системе.

Но в конце функции возвращается русская, если была включена

Код: AutoIt [Выделить]

$iKbrdLayout = 0x0409
$aKbrdLayouts = _WinAPI_GetKeyboardLayoutList()
_WinAPI_LoadKeyboardLayout($iKbrdLayout, $KLF_ACTIVATE)

А если в ОС нет русского 0x0409, а есть, например, греческий 0x0408? В этом смысле универсальная. Либо я просто не понял, как работает функция


Добавлено: Ноябрь 03, 2015, 02:23:53Прошу прощения, дошло: 0x0409 - это и есть английский, переклинило с 0x0419.