Генератор повторяющихся строк текста

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
;~ #include <WinAPIEx.au3>
#include <WinAPIShPath.au3>
#include <String.au3>
#include <GuiEdit.au3>

Opt('TrayMenuMode', 1)
Opt('MustDeclareVars', 1)

Global $hGUI, $hEdit, $iInput, $iBtn, $sFileName, $sTxt, $iCount

$hGUI = GUICreate('Repeat Text', 300, 215)
GUICtrlCreateEdit('', 10, 10, 280, 100)
$hEdit = GUICtrlGetHandle(-1)
$iInput = GUICtrlCreateInput('', 40, 130, 80, 20, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER, $ES_CENTER))
_GUICtrlEdit_SetCueBanner($iInput, 'Repeat count')
$iBtn = GUICtrlCreateButton('Save', 170, 120, 80, 40)
GUISetState()
GUIRegisterMsg($WM_COMMAND, '_WM_COMMAND')

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $iBtn
			$sTxt = _GUICtrlEdit_GetText($hEdit)
			If Not $sTxt Then
				TrayTip('Repeat Text', 'Edit is empty.', 3, 3)
				AdlibRegister('_Kill_TrayTip', 5000)
				ContinueLoop
			EndIf
			$iCount = Int(GUICtrlRead($iInput))
			If Not $iCount Then
				TrayTip('Repeat Text', 'Repeat count can not be 0', 3, 3)
				AdlibRegister('_Kill_TrayTip', 10000)
				ContinueLoop
			EndIf
			$sFileName = _WinAPI_PathYetAnotherMakeUniqueName(@ScriptDir & '\RepeatFile.txt')
			FileWrite($sFileName, _StringRepeat($sTxt & @CRLF, $iCount))
			TrayTip('Repeat Text', 'Save repeat text to ' & $sFileName, 3, 1)
			AdlibRegister('_Kill_TrayTip', 5000)
			GUICtrlSetData($iInput, '')
			_GUICtrlEdit_SetText($hEdit, '')
			$sFileName = ''
			$sTxt = ''
			$iCount = 0
	EndSwitch
WEnd

Func _WM_COMMAND($h_Wnd, $i_Msg, $i_wParam, $i_lParam)
	Switch BitAND($i_wParam, 0xFFFF) ; _WinAPI_LoWord
		Case $iInput
			Switch BitShift($i_wParam, 16) ; _WinAPI_HiWord
				Case $EN_CHANGE
					Local $s_Txt = GUICtrlRead($iInput)
					If ($s_Txt) And (Not StringIsDigit($s_Txt)) Then
						GUICtrlSetData($iInput, '')
						TrayTip('Repeat Text', 'Only numbers.', 3, 3)
						AdlibRegister('_Kill_TrayTip', 5000)
					EndIf
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_COMMAND

Func _Kill_TrayTip()
	AdlibUnRegister('_Kill_TrayTip')
	TrayTip('', '', 0)
EndFunc   ;==>_Kill_TrayTip

Func _GUICtrlEdit_SetCueBanner($hWnd, $sText)
	If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)
	Local $tText = _WinAPI_MultiByteToWideChar(String($sText))
	Return _SendMessage($hWnd, $EM_SETCUEBANNER, False, $tText, 0, "wparam", "struct*") = 1
EndFunc   ;==>_GUICtrlEdit_SetCueBanner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate(@ScriptName, 623, 449, -1, -1)
$Edit1 = GUICtrlCreateEdit("", 10, 11, 601, 385, BitOR($ES_AUTOVSCROLL,$ES_WANTRETURN,$WS_VSCROLL))
$Input1 = GUICtrlCreateInput("10", 98, 414, 41, 21)
$Button1 = GUICtrlCreateButton("Создать", 536, 412, 75, 25)
$Label1 = GUICtrlCreateLabel("Кол. повторов:", 16, 416, 79, 17)
$Label2 = GUICtrlCreateLabel("Файл:", 155, 416, 36, 17)
$Input2 = GUICtrlCreateInput("myfile.txt", 195, 414, 121, 21)
GUISetState(@SW_SHOW)

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			_CreateRepeat()

	EndSwitch
WEnd


Func _CreateRepeat()

	Local $sTmpStr = ''
	$sText = GUICtrlRead($Edit1)

	For $i = 1 To GUICtrlRead($Input1)
		$sTmpStr &=StringFormat('%s\r\n\r\n', $sText)
	Next

	$hFile = FileOpen(StringFormat('%s\%s', @ScriptDir, GUICtrlRead($Input2)), 2)
	FileWrite($hFile, StringStripWS($sTmpStr, 2))
	FileClose($hFile)

	MsgBox(64, @ScriptName, 'Файл создан!')
EndFunc ;==>_CreateRepeat