Скачать определенную картинку со страницы сайта и закачать ее на свой сайт

; открыл сайт донор
#include <IE.au3>
$IE =  _IECreate("http://www.ayda.ru/stories/show_v.php?v=12") 

;не знаю, как извлечь ссыль и вставить в следующий код???

$hImageBin = InetRead ('http://www.ayda.ru/stories/photos/independent-travel.jpg')
MsgBox(0,'',$hImageBin)
$OPEN=FileOpen('1.jpg',2+16)
FileWrite($OPEN,$hImageBin)
FileClose($OPEN)

; открываю свой сайт (уже авторизованный)

Sleep(3000)
_IENavigate ($IE, "http://localhost/test.ru/silvers.php?mod=addnews&action=addnews")

; и вставляю 1.jpg в форму закачки картинок (с этим пока тоже есть проблемы).

;~ HttpSetProxy(1)

Local $s_Url = 'http://www.ayda.ru/stories/show_v.php?v=12', $s_Html, $a_ImgLink, $i_Ub, $i_Count, $i_Err = 0, $s_Dir = @ScriptDir & '\ImgDL\'

$s_Html = InetRead($s_Url, 17)
If @error Then Exit 1
$s_Html = BinaryToString($s_Html)
$a_ImgLink = StringRegExp($s_Html, '<img src=.*?(http[^''">\h]+?/photos/[^''">\h]+?jpg)(?=[''">\h])', 3)
$s_Html = ''
$i_Ub = UBound($a_ImgLink)
If Not $i_Ub Then Exit 2
If FileExists($s_Dir) Then
	FileDelete($s_Dir & '*.*')
Else
	DirCreate($s_Dir)
EndIf
For $i = 0 To $i_Ub - 1
;~ 	$a_ImgLink[$i] = InetGet($a_ImgLink[$i], $s_Dir & StringRegExpReplace($a_ImgLink[$i], '^.*/', ''), 17, 1);оригинальное имя картинки
	$a_ImgLink[$i] = InetGet($a_ImgLink[$i], $s_Dir & $i + 1 & '.jpg', 17, 1);имя картинки по номеру, начиная с 1.jpg
Next
While $i_Ub > $i_Count
	For $i = 0 To $i_Ub - 1
		If $a_ImgLink[$i] Then
			If InetGetInfo($a_ImgLink[$i], 2) Then
				If InetGetInfo($a_ImgLink[$i], 4) Then $i_Err += 1
				InetClose($a_ImgLink[$i])
				$a_ImgLink[$i] = 0
				$i_Count += 1
				ConsoleWrite('Downloaded image number ' & $i + 1 & ', ' & $i_Count & ' (' & $i_Ub & '), errors: ' & $i_Err & @LF)
			EndIf
		EndIf
	Next
	Sleep(1000)
WEnd

;~ HttpSetProxy(1)

Local $s_Url = 'http://bondhd.livejournal.com/2056.html', $s_Html, $a_ImgLink, $i_Ub, $i_Count, $i_Err = 0, $s_Dir = @ScriptDir & '\ImgDL\'

$s_Html = InetRead($s_Url, 17)
If @error Then Exit 1
$s_Html = BinaryToString($s_Html)
$a_ImgLink = StringRegExp($s_Html, '<img src=.*?(http[^''">\h]+?/bondhd/[^''">\h]+?jpg)(?=[''">\h])', 3)
$s_Html = ''
$i_Ub = UBound($a_ImgLink)
If Not $i_Ub Then Exit 2
If FileExists($s_Dir) Then
    FileDelete($s_Dir & '*.*')
Else
    DirCreate($s_Dir)
EndIf
For $i = 0 To $i_Ub - 1
;~  $a_ImgLink[$i] = InetGet($a_ImgLink[$i], $s_Dir & StringRegExpReplace($a_ImgLink[$i], '^.*/', ''), 17, 1);оригинальное имя картинки
    $a_ImgLink[$i] = InetGet($a_ImgLink[$i], $s_Dir & $i + 1 & '.jpg', 17, 1);имя картинки по номеру, начиная с 1.jpg
Next
While $i_Ub > $i_Count
    For $i = 0 To $i_Ub - 1
        If $a_ImgLink[$i] Then
            If InetGetInfo($a_ImgLink[$i], 2) Then
                If InetGetInfo($a_ImgLink[$i], 4) Then $i_Err += 1
                InetClose($a_ImgLink[$i])
                $a_ImgLink[$i] = 0
                $i_Count += 1
                ConsoleWrite('Downloaded image number ' & $i + 1 & ', ' & $i_Count & ' (' & $i_Ub & '), errors: ' & $i_Err & @LF)
            EndIf
        EndIf
    Next
    Sleep(1000)
WEnd