Что нового

[Элементы GUI] Более 1300 checkbox

rybik

Новичок
Сообщения
84
Репутация
0
Код:
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#include <GUIScrollbars_Ex.au3>
#include <GUIConstants.au3>
#include <StructureConstants.au3>
#include <GUIScrollBars.au3>
#include <ScrollBarConstants.au3>
AutoItSetOption("WinTitleMatchMode", 3)
AutoItSetOption("GUIResizeMode", 2 + 32 + 256 + 512)
Global $aArray[1300], $ai
For $i = 0 To UBound($aArray) - 1
	$aArray[$i] = Int(Random(0,5))
Next

Global $wSetting = GUICreate("Setting", 1300, 700, -2, -2, BitOR($WS_MAXIMIZEBOX,$WS_MINIMIZEBOX, $WS_THICKFRAME,$WS_THICKFRAME,$WS_SYSMENU,$WS_CAPTION,$WS_OVERLAPPEDWINDOW,$WS_TILEDWINDOW,$WS_POPUP,$WS_POPUPWINDOW,$WS_GROUP,$WS_TABSTOP,$WS_BORDER,$WS_CLIPSIBLINGS, $WS_OVERLAPPEDWINDOW))
Global $step[10] = [3,3,3,3,3,3,3,3,3,3]



$GuiStats = GUICtrlCreateTab(0, 50, 1300, 1300)
GUICtrlCreateTabItem("000")

For $i = 0 To 1299
	Local $Xposition1 = 200
	If $aArray[$i] == 0 Then ;warrior
		$step[0] += 1
		GUICtrlCreateCheckbox($aArray[$i], 40, 25*$step[0], 140, 24)
	EndIf
	If $aArray[$i] == 1 Then
		$step[1] += 1
		GUICtrlCreateCheckbox($aArray[$i], $Xposition1+35, 25*$step[1], 140, 24)
	EndIf
	If $aArray[$i] == 2 Then
		$step[2] += 1
		GUICtrlCreateCheckbox($aArray[$i], $Xposition1+200+35, 25*$step[2], 140, 24)
	EndIf
	If $aArray[$i] == 3 Then
		$step[3] += 1
		GUICtrlCreateCheckbox($aArray[$i], $Xposition1+200*2+35, 25*$step[3], 140, 24)
	EndIf
	If $aArray[$i] == 4 Then
		$step[4] += 1
		GUICtrlCreateCheckbox($aArray[$i], $Xposition1+200*3+35, 25*$step[4], 140, 24)
	EndIf
	If $aArray[$i] == 5 Then
		$step[5] += 1
		GUICtrlCreateCheckbox($aArray[$i], $Xposition1+200*4+35, 25*$step[5], 140, 24)
	EndIf
Next
GUICtrlCreateGroup("0",5, 75, 180, 25*($step[0]))
GUICtrlCreateGroup("1",$Xposition1, 75, 180, 25*($step[1]))
GUICtrlCreateGroup("2",$Xposition1*2, 75, 180, 25*($step[2]))
GUICtrlCreateGroup("3",$Xposition1*3, 75, 180, 25*($step[3]))
GUICtrlCreateGroup("4",$Xposition1*4, 75, 180, 25*($step[4]))
GUICtrlCreateGroup("5",$Xposition1*5, 75, 180, 25*($step[5]))


GUICtrlCreateTabItem("0000")

_GUIScrollBars_Init($wSetting, -1, 1)
_GUIScrollBars_SetScrollInfoMax($wSetting, $SB_VERT, 30)
_GUIScrollBars_SetScrollInfoMax($wSetting, $SB_HORZ, 0)


GUIRegisterMsg($WM_VSCROLL, "WM_VSCROLL")
GUIRegisterMsg($WM_HSCROLL, "WM_HSCROLL")


GUISetState(@SW_SHOW) ; показывает созданное окно
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
 EndSwitch
WEnd

Func WM_HSCROLL($hWnd, $Msg, $wParam, $lParam)
    #forceref $Msg, $lParam
    Local $nScrollCode = BitAND($wParam, 0x0000FFFF)

    Local $index = -1, $xChar, $xPos
    Local $Min, $Max, $Page, $Pos, $TrackPos

    For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
        If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
            $index = $x
            $xChar = $__g_aSB_WindowInfo[$index][2]
            ExitLoop
        EndIf
    Next
    If $index = -1 Then Return 0

;~  ; Get all the horizontal scroll bar information
    Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_HORZ)
    $Min = DllStructGetData($tSCROLLINFO, "nMin")
    $Max = DllStructGetData($tSCROLLINFO, "nMax")
    $Page = DllStructGetData($tSCROLLINFO, "nPage")
    ; Save the position for comparison later on
    $xPos = DllStructGetData($tSCROLLINFO, "nPos")
    $Pos = $xPos
    $TrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")
    #forceref $Min, $Max
    Switch $nScrollCode

        Case $SB_LINELEFT ; user clicked left arrow
            DllStructSetData($tSCROLLINFO, "nPos", $Pos - 1)

        Case $SB_LINERIGHT ; user clicked right arrow
            DllStructSetData($tSCROLLINFO, "nPos", $Pos + 1)

        Case $SB_PAGELEFT ; user clicked the scroll bar shaft left of the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $Pos - $Page)

        Case $SB_PAGERIGHT ; user clicked the scroll bar shaft right of the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $Pos + $Page)

        Case $SB_THUMBTRACK ; user dragged the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $TrackPos)
    EndSwitch

;~    // Set the position and then retrieve it.  Due to adjustments
;~    //   by Windows it may not be the same as the value set.

    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
    ;// If the position has changed, scroll the window and update it
    $Pos = DllStructGetData($tSCROLLINFO, "nPos")
    If ($Pos <> $xPos) Then _GUIScrollBars_ScrollWindow($hWnd, $xChar * ($xPos - $Pos), 0)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_HSCROLL

Func WM_VSCROLL($hWnd, $Msg, $wParam, $lParam)
    #forceref $Msg, $wParam, $lParam
    Local $nScrollCode = BitAND($wParam, 0x0000FFFF)
    Local $index = -1, $yChar, $yPos
    Local $Min, $Max, $Page, $Pos, $TrackPos

    For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
        If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
            $index = $x
            $yChar = $__g_aSB_WindowInfo[$index][3]
            ExitLoop
        EndIf
    Next
    If $index = -1 Then Return 0


    ; Get all the vertial scroll bar information
    Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
    $Min = DllStructGetData($tSCROLLINFO, "nMin")
    $Max = DllStructGetData($tSCROLLINFO, "nMax")
    $Page = DllStructGetData($tSCROLLINFO, "nPage")
    ; Save the position for comparison later on
    $yPos = DllStructGetData($tSCROLLINFO, "nPos")
    $Pos = $yPos
    $TrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")

    Switch $nScrollCode
        Case $SB_TOP ; user clicked the HOME keyboard key
            DllStructSetData($tSCROLLINFO, "nPos", $Min)

        Case $SB_BOTTOM ; user clicked the END keyboard key
            DllStructSetData($tSCROLLINFO, "nPos", $Max)

        Case $SB_LINEUP ; user clicked the top arrow
            DllStructSetData($tSCROLLINFO, "nPos", $Pos - 1)

        Case $SB_LINEDOWN ; user clicked the bottom arrow
            DllStructSetData($tSCROLLINFO, "nPos", $Pos + 1)

        Case $SB_PAGEUP ; user clicked the scroll bar shaft above the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $Pos - $Page)

        Case $SB_PAGEDOWN ; user clicked the scroll bar shaft below the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $Pos + $Page)

        Case $SB_THUMBTRACK ; user dragged the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $TrackPos)
    EndSwitch

;~    // Set the position and then retrieve it.  Due to adjustments
;~    //   by Windows it may not be the same as the value set.

    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    ;// If the position has changed, scroll the window and update it
    $Pos = DllStructGetData($tSCROLLINFO, "nPos")

    If ($Pos <> $yPos) Then
        _GUIScrollBars_ScrollWindow($hWnd, 0, $yChar * ($yPos - $Pos))
        $yPos = $Pos
    EndIf

    Return $GUI_RUNDEFMSG

EndFunc   ;==>WM_VSCROLL


Мне нужно окно с большим количество чек боксов. Так же рядом с каждым чек боксом будет картинка. Так как большое количество элементов в окне, скрипт зависает. Возможно зависает из-за скрол бара, но без него не получится разместить все чек боксы. Как можно добиться, чтобы скрипт работал быстро и не зависал?
 

AZJIO

Меценат
Меценат
Сообщения
2,874
Репутация
1,194
Создать чекбоксы в листвью, тогда они будут обслуживаться внутренним профессиональным движком
 
Автор
R

rybik

Новичок
Сообщения
84
Репутация
0
AZJIO сказал(а):
Создать чекбоксы в листвью, тогда они будут обслуживаться внутренним профессиональным движком

Код:
#include <ListViewConstants.au3>
#include <GUIConstantsEx.au3>

Local $hGUI, $ListView, $button, $item1, $item2, $item3, $item4, $item5, $msg, $Count, $Sort

$hGUI = GUICreate("ListView", 240, 260, 150, 250)
GUISetBkColor(0xECE9D8) ; устанавливает цвет фона Gui

$ListView = GUICtrlCreateListView("Колонка1|кол2|кол3  ", 10, 10, 220, 150);,$LVS_SORTDESCENDING)
$item1 = GUICtrlCreateListViewItem("пункт2|кол22|кол23", $ListView)
$item2 = GUICtrlCreateListViewItem("пункт8|кол12|кол13", $ListView)
$item3 = GUICtrlCreateListViewItem("пункт5|кол32|кол33", $ListView)
$item4 = GUICtrlCreateListViewItem("пункт9|кол42|кол43", $ListView)
$item5 = GUICtrlCreateListViewItem("пункт3|кол52|кол53", $ListView)
GUICtrlSendMsg($ListView, $LVM_SETEXTENDEDLISTVIEWSTYLE, 0, $LVS_EX_CHECKBOXES + $LVS_EX_GRIDLINES)

$button = GUICtrlCreateButton("Стиль CheckBox и сетка", 45, 170, 150, 25)
$Sort = GUICtrlCreateButton("Сортировать", 75, 200, 90, 25)
$Count = GUICtrlCreateButton("Количество пунктов", 55, 230, 130, 25)

GUISetState()

GUICtrlSetData($item2, "ПУНКТ1")
GUICtrlSetData($item3, "||КОЛ33")
GUICtrlDelete($item1)

Do
     $msg = GUIGetMsg()

     Select ; рекомендуется использовать Switch вместо Select
         Case $msg = $button
             ; изменяет стиль, только с префиксом EX_ (расширенный)
             GUICtrlSendMsg($ListView, $LVM_SETEXTENDEDLISTVIEWSTYLE, 0, $LVS_EX_CHECKBOXES + $LVS_EX_GRIDLINES)
         Case $msg = $Count
             MsgBox(0, 'Количество пунктов', GUICtrlSendMsg($ListView, $LVM_GETITEMCOUNT, 0, 0), 0, $hGUI)
         Case $msg = $Sort
             GUICtrlSendMsg($ListView, $LVM_SORTITEMS, 0, 0)
         Case $msg = $ListView
             MsgBox(4096, "ListView", "колонка=" & GUICtrlGetState($ListView), 2, $hGUI)
     EndSelect
Until $msg = $GUI_EVENT_CLOSE


Вот что нашел, а возможно сделать чек боксы в каждом столбике?
 

joiner

Модератор
Локальный модератор
Сообщения
3,556
Репутация
628
TreeView
Может это подойдет? Там и чеки есть и картинки
 

xXx

╚{■_■}╗
Меценат
Сообщения
248
Репутация
95
Еще вариант с ListView:
Код:
#include <ListviewConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Local $hGUI, $iListView, $iLVItem[0], $iGUIWidth = 850, $j, $iUb = 1000

$hGUI = GUICreate('', $iGUIWidth, @DesktopHeight - 60, -1, 0, -1, $WS_EX_TOPMOST)
GUISetFont(12)
GUICtrlSetDefBkColor(0xD9FFFE)
$iListView = GUICtrlCreateListView('', 10, 35, $iGUIWidth - 20, @DesktopHeight - 140, BitOR(0x00a00003, $LVS_LIST), BitOR($LVS_EX_CHECKBOXES, $LVS_EX_DOUBLEBUFFER))
For $i = 0 To $iUb
	ReDim $iLVItem[UBound($iLVItem) + 1]
	$iLVItem[$i] = GUICtrlCreateListViewItem('Пункт ' & StringFormat('%04s', $i), $iListView)
	$j +=1
	If $j = 100 Then $j = 0
	GUICtrlSetImage(-1, 'Imageres.dll', $j)
	; GUICtrlSetState(-1, $GUI_CHECKED)
Next
GUISetState()

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			ExitLoop
	EndSwitch
WEnd
 
Автор
R

rybik

Новичок
Сообщения
84
Репутация
0
xXx сказал(а):
Еще вариант с ListView:
Код:
#include <ListviewConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Local $hGUI, $iListView, $iLVItem[0], $iGUIWidth = 850, $j, $iUb = 1000

$hGUI = GUICreate('', $iGUIWidth, @DesktopHeight - 60, -1, 0, -1, $WS_EX_TOPMOST)
GUISetFont(12)
GUICtrlSetDefBkColor(0xD9FFFE)
$iListView = GUICtrlCreateListView('', 10, 35, $iGUIWidth - 20, @DesktopHeight - 140, BitOR(0x00a00003, $LVS_LIST), BitOR($LVS_EX_CHECKBOXES, $LVS_EX_DOUBLEBUFFER))
For $i = 0 To $iUb
	ReDim $iLVItem[UBound($iLVItem) + 1]
	$iLVItem[$i] = GUICtrlCreateListViewItem('Пункт ' & StringFormat('%04s', $i), $iListView)
	$j +=1
	If $j = 100 Then $j = 0
	GUICtrlSetImage(-1, 'Imageres.dll', $j)
	; GUICtrlSetState(-1, $GUI_CHECKED)
Next
GUISetState()

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			ExitLoop
	EndSwitch
WEnd

Это то что нужно, но возможно как-нибудь разграничить по столбикам, чтобы все нули были в столбце с нулями, все единицы в столбце с единицами, а все двойки в столбце с двойками и так далее... ?


Добавлено:
Сообщение автоматически объединено:

Как читать положение чек бокса в GUICtrlCreateListView? Если GUICtrlRead выдает текст чек бокса...
 

ra4o

AutoIT Гуру
Сообщения
1,165
Репутация
246
Как читать полоКак читать положение чек бокса в GUICtrlCreateListView?жение чек бокса в GUICtrlCreateListView?
Можно так:
Код:
#include <GuiListView.au3>
_GUICtrlListView_GetItemChecked($hWnd, $iIndex)

Или без UDF так:
Код:
For $i=0 to $iUb
	If GuiCtrlRead($iLVItem[$i],1)==$GUI_CHECKED Then ConsoleWrite (GuiCtrlRead($iLVItem[$i])&@CR)
Next
 
Верх