Что нового

Отправка сообщений на E-Mail при выполнении условий в скрипте

Dk

Новичок
Сообщения
358
Репутация
2
Версия AutoIt:
3.3.14.2
Описание:
Здравствуйте.
Есть скрипт,
Код:
#include <WindowsConstants.au3>
#include <ListViewConstants.au3>
#include <GUIConstantsEx.au3>

Opt('GUIOnEventMode', 1)
Opt('TrayOnEventMode', 1)
Opt('TrayMenuMode', 3)

Local $iFile2GTime, $asText1, $asText2, $sText2, $sFile1Size, $hGUI, $hListView, $nCh1, $hButt1, $hButt2, $hButt3, $hButt4, $hGUIState, $hExit, $sLVText
Local $sFile1SizePrev = 0, $iOffset = 1, $hFile1, $sFile1 = @ScriptDir & '\1.txt', $sFile2 = @ScriptDir & '\2.txt'

$hGUI = GUICreate('Статистика:', 635, 280, -1, -1, $WS_OVERLAPPEDWINDOW)
GUISetBkColor(0xB9D1EA)
$hListView = GUICtrlCreateListView('ASIN-10  |Price[New]|Price[Old]|SalesRank|Name|Date & Time', 5, 5, 625, 240, _
        $LVS_NOSORTHEADER, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_GRIDLINES, $LVS_EX_HEADERDRAGDROP))
GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)
Opt("GUIResizeMode", $GUI_DOCKSTATEBAR)
$nCh1 = GUICtrlCreateCheckbox('Автоотправка Email', 255, 253, 120, 20)
$hButt1 = GUICtrlCreateButton('Скопировать все', 10, 250, 100, 25)
$hButt2 = GUICtrlCreateButton('Отправить Email', 130, 250, 100, 25)
$hButt3 = GUICtrlCreateButton('Очистить список', 390, 253, 100, 20)
$hButt4 = GUICtrlCreateButton('Выйти из программы', 510, 253, 120, 20)
$hGUIState = TrayCreateItem('Отобразить/Скрыть Окно')
TrayCreateItem('')
$hExit = TrayCreateItem('Выход')
GUISetOnEvent($GUI_EVENT_CLOSE, '_CLOSEClicked')
GUICtrlSetOnEvent($hButt1, '_ListViewCopy')
GUICtrlSetOnEvent($hButt3, '_ListViewClear')
GUICtrlSetOnEvent($hButt4, '_Exit')
TrayItemSetOnEvent($hGUIState, '_CLOSEClicked')
TrayItemSetOnEvent($hExit, '_Exit')

GUISetState(@SW_HIDE)

$iFile2GTime = FileGetTime($sFile2, 0, 1)
_FilesOpen_Reads(1)

While 1
    While 1
        $sFile1Size = FileGetSize($sFile1)
        Select
            Case $sFile1SizePrev < $sFile1Size
                $sFile1SizePrev = $sFile1Size
            Case $sFile1SizePrev > $sFile1Size
                $sFile1SizePrev = 0
                _FilesOpen_Reads(0)
        EndSelect
        $asText1 = StringRegExp(FileReadLine($hFile1), '^"(\w{10,12})"\t"(?:.+?)"(?:\t[\d\,N/A]+)\t([\d\,N/A]+)(?:\t[\d\,N/A]+\t.+?"?)(?:\t[\d\,N/A]+){3}\t([\d\,N/A]+)\t', 3)
        If @error Then
            Sleep(50)
            ContinueLoop
        EndIf
        For $i = 0 To 1
            $asText2 = StringRegExp($sText2, '\v' & $asText1[0] & '\|([\d\,N/A]+)\|(.+?)\|', 1, $iOffset)
            If @error Then
                $iOffset = 1
            Else
                $iOffset = @extended
                ExitLoop 2
            EndIf
        Next
        If @error Then ContinueLoop
    WEnd
    If $asText1[1] <> 'N/A' And $asText2[0] <> 'N/A' Then
;~      If Number(StringReplace($asText2[0], ',', '.')) / Number(StringReplace($asText1[1], ',', '.')) >= 2 And Number($asText1[2]) < 300000 Then
        If Number(StringReplace($asText2[0], ',', '.')) > Number(StringReplace($asText1[1], ',', '.')) And Number($asText1[2]) < 30000000 Then
            $sLVItemText = $asText1[0] & '|' & $asText1[1] & '|' & $asText2[0] & '|' & $asText1[2] & '|' & _
                    $asText2[1] & '|' & @MDAY & '/' & @MON & '/' & @YEAR & ' ' & @HOUR & ':' & @MIN & ':' & @SEC
            GUICtrlCreateListViewItem($sLVItemText, $hListView)
            GUISetState(@SW_SHOWNORMAL)
            ;SoundPlay(@WindowsDir & '\media\Windows Ringin.wav') ; Отключил пока, для чистоты эксперимента
            $sLVText &= $sLVItemText & '|' & @CRLF
        EndIf
    EndIf
WEnd

Func _FilesOpen_Reads($iFirstStart)
    Local $iF2GT, $i = 0
    $sText2 = ''
    If Not $iFirstStart Then
        FileClose($hFile1)
        While 1
            $i += 1
            $iF2GT = FileGetTime($sFile2, 0, 1)
            If $iF2GT > $iFile2GTime Then
                $iFile2GTime = $iF2GT
                ExitLoop
            EndIf
            If $i >= 60 Then Exit MsgBox(16, 'Ошибка!', 'Файл "2.txt" не обновился.' & @LF & 'Программа будет закрыта.')
            Sleep(100)
        WEnd
    EndIf
    For $i = 0 To 30
        $hFile1 = FileOpen($sFile1)
        If $hFile1 <> -1 Then ExitLoop
        Sleep(100)
    Next
    If $hFile1 = -1 Then Exit MsgBox(16, 'Ошибка!', 'Неудалось открыть файл "1.txt".' & @LF & 'Программа будет закрыта.')
    For $i = 0 To 30
        $sText2 = StringRegExpReplace(FileRead($sFile2), '\n"(\w{10,12})"\t"(.+?)"(?:\t[\d\,N/A]+?)\t([\d\,N/A]+)\t.+', '${1}|${3}|${2}|')
        If Not @error Then Return
        Sleep(100)
    Next
    MsgBox(16, 'Ошибка!', 'Не удалось открыть или прочитать файл "2.txt".' & @LF & 'Программа будет закрыта.')
    _Exit()
EndFunc   ;==>_FilesOpen_Reads

Func _CLOSEClicked()
    GUISetState(BitAND(WinGetState($hGUI), 2) ? @SW_HIDE : @SW_SHOWNORMAL)
EndFunc   ;==>_CLOSEClicked

Func _ListViewCopy()
    ClipPut($sLVText)
EndFunc   ;==>_ListViewCopy

Func _ListViewClear()
    GUICtrlSendMsg($hListView, $LVM_DELETEALLITEMS, 0, 0)
    $sLVText = ''
EndFunc   ;==>_ListViewClear

Func _Exit()
    If $hFile1 Then FileClose($hFile1)
    Exit
EndFunc   ;==>_Exit
который сравнивает цены из двух текстовых файлов 1.тхт и 2.тхт и при определённых условиях выдаёт совпадения в окне сообщений
Ссылка на файлы
http://files.d-lan.dp.ua/download?file=1cb84ef41ff8c2c94c121b72b93e84b1 1.txt
http://files.d-lan.dp.ua/download?file=e7aeca3d027bf49f0fb6d95641ad74d4 2.txt

Мне нужно, что бы при выполнении этих условий
Код:
If Number(StringReplace($asText2[0], ',', '.')) > Number(StringReplace($asText1[1], ',', '.')) And Number($asText1[2]) < 30000000 Then

происходила отправка сообщений мне на почту.
Вот эти сообщения - массивы, которые должны приходить на почту.
Код:
$asText1[0] & '|' & $asText1[1] & '|' & $asText2[0] & '|' & $asText1[2] & '|' & _
                    $asText2[1] & '|' & @MDAY & '/' & @MON & '/' & @YEAR & ' ' & @HOUR & ':' & @MIN & ':' & @SEC


Примечания:
Вот построение письма, который должен отсылаться на почту.

Rang: $asText1[2]
ASIN: ($asText1[0]) (Формат как текст)
Title : $asText2[1]
Link : ($asText1[0]) (Формат как гиперссылка, а не как текст.)
Time: @MDAY & '/' & @MON & '/' & @YEAR & ' ' & @HOUR & ':' & @MIN & ':' & @SEC
Old Price: $asText2[0] New Price: $asText1[1]
 
Автор
D

Dk

Новичок
Сообщения
358
Репутация
2
Alofa сказал(а):
А где его брать?

URL это просто ISBN номер отосланный на почту, но как гиперсылка, а не как текст
Вот как пример 3789167061

Я сейчас исправлю - точнее напишу.
 
Автор
D

Dk

Новичок
Сообщения
358
Репутация
2
Alofa сказал(а):
Вы наверно хотели написать:[box]Old Price: $asText2[0] New Price: $asText1[1][/box]
Точно, перепутал, спасибо, исправил.

Я так понимаю это ссылка на страницу товара, а как мне ее вычислить?
Не нужно вычислять, мне просто пока нужно что бы номер приходил как ссылка, а в дальнейшем я уже исправлю.
 

ra4o

AutoIT Гуру
Сообщения
1,165
Репутация
246
Я пользуюсь таким методом отправки почты
Код:
$str = "http://schemas.microsoft.com/cdo/configuration/"
$hMAIL = ObjCreate ("CDO.Message")
    With $hMAIL
        .From = "";Адрес отправителя
        .To = ""; Адрес получателя
        .Subject = "Тема"; Тема письма
        .TextBody = "Текст письма"; Текст письма
       .AddAttachment ("")  ;файл для отправки
    EndWith
    With $hMAIL.Configuration.Fields
        .Item ($str & "sendusing") = 2
        .Item ($str & "smtpserver") = "smtp.inbox.ru" ;SMTP Server
		.Item ($str & "smtpusessl") = True
        .Item ($str & "smtpauthenticate") = 1
        .Item ($str & "sendusername") = "";Логин (адрес отправителя)
        .Item ($str & "sendpassword") = "" ;Пароль SMTP-сервер
        .Item ($str & "smtpserverport") = 465		;Порт
        .Update
    EndWith
$hMAIL.Send
Думаю, что если в тексте письма будет ссылка, то почтовик сам её выделит.
 
Автор
D

Dk

Новичок
Сообщения
358
Репутация
2
ra4o сказал(а):
Я пользуюсь таким методом отправки почты
Код:
$str = "http://schemas.microsoft.com/cdo/configuration/"
$hMAIL = ObjCreate ("CDO.Message")
    With $hMAIL
        .From = "";
        .To = ""
        .Subject = "Тема"
        .TextBody = "Текст письма"
       .AddAttachment ("")  ;файл для отправки
    EndWith
    With $hMAIL.Configuration.Fields
        .Item ($str & "sendusing") = 2
        .Item ($str & "smtpserver") = "smtp.inbox.ru" ;SMTP Server
		.Item ($str & "smtpusessl") = True
        .Item ($str & "smtpauthenticate") = 1
        .Item ($str & "sendusername") = ""
        .Item ($str & "sendpassword") = "" ;Пароль SMTP-сервер
        .Item ($str & "smtpserverport") = 465		;Порт
        .Update
    EndWith
$hMAIL.Send
Думаю, что если в тексте письма будет ссылка, то почтовик сам её выделит.

Такой маленький? Ок, вечером проверю. :scratch:
 
A

Alofa

Гость
ra4o (для меня это впервой) если правильно понял:
Код:
With $hMAIL
        .From = ""; Адрес Эл. почты отправителя (можно ли оставить пустым?)
        .To = "" ; Адрес Эл. почты получателя
 

ra4o

AutoIT Гуру
Сообщения
1,165
Репутация
246
Пустым нельзя, там должны быть адреса , так же в ".Item ($str & "sendusername") = " нужен тот-же адрес, что и в ".From"
 

ildar

Осваивающий
Сообщения
252
Репутация
29
То же самое, только вид сбоку
Код:
$SmtpServer = "smtp.mail.ru"								; адрес smtp-сервера вашей эл. почты
$FromName = "Иван Жуков"									; ваше имя
$FromAddress = "[email protected]"								; ваш почтовый адрес
$ToAddress = "На деревню дедушке.... Константину Макарычу"	; адрес получателя
$Subject = "Милый дедушка, Константин Макарыч!"				; тема
$Body = "Христом богом тебя молю, возьми меня отседа."		; содержание
$AttachFiles = ""
$CcAddress = ""
$BccAddress = ""
$Importance = "Normal"
$Username = ""												; логин
$Password = ""												; пароль
$IPPort = 25
$ssl = 0



Global $oMyRet[2]
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")

 $rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $IPPort, $ssl)


 ; The UDF
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
;~          ConsoleWrite('@@ Debug : $S_Files2Attach[$x] = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                ConsoleWrite('+> File attachment added: ' & $S_Files2Attach[$x] & @LF)
                $objEmail.AddAttachment($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 then $IPPort = 25
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Set Email Importance
    Switch $s_Importance
        Case "High"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
        Case "Normal"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Normal"
        Case "Low"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Low"
    EndSwitch
    $objEmail.Fields.Update
    ; Sent the Message
    $objEmail.Send
    If @error Then
        SetError(2)
        Return $oMyRet[1]
    EndIf
    $objEmail=""
 EndFunc   ;==>_INetSmtpMailCom
 ;
;
; Com Error Handler
Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    $oMyRet[0] = $HexNumber
    $oMyRet[1] = StringStripWS($oMyError.description, 3)
    ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc   ;==>MyErrFunc
 
A

Alofa

Гость
Себе для справки.:

А чтой то никто не пользует?
Код:
_INetSmtpMail()

Может какие-то известные проблемы есть?
 
Автор
D

Dk

Новичок
Сообщения
358
Репутация
2
ra4o сказал(а):
Я пользуюсь таким методом отправки почты
Код:
$str = "http://schemas.microsoft.com/cdo/configuration/"
$hMAIL = ObjCreate ("CDO.Message")
    With $hMAIL
        .From = "";Адрес отправителя
        .To = ""; Адрес получателя
        .Subject = "Тема"; Тема письма
        .TextBody = "Текст письма"; Текст письма
       .AddAttachment ("")  ;файл для отправки
    EndWith
    With $hMAIL.Configuration.Fields
        .Item ($str & "sendusing") = 2
        .Item ($str & "smtpserver") = "smtp.inbox.ru" ;SMTP Server
		.Item ($str & "smtpusessl") = True
        .Item ($str & "smtpauthenticate") = 1
        .Item ($str & "sendusername") = "";Логин (адрес отправителя)
        .Item ($str & "sendpassword") = "" ;Пароль SMTP-сервер
        .Item ($str & "smtpserverport") = 465		;Порт
        .Update
    EndWith
$hMAIL.Send
Думаю, что если в тексте письма будет ссылка, то почтовик сам её выделит.

Очень даже работает. Спасибо.
Только один вопрос, что за файл Untitled.bin он мне постоянно докидывает??



Добавлено:
Сообщение автоматически объединено:

ildar сказал(а):
То же самое, только вид сбоку
Код:
$SmtpServer = "smtp.mail.ru"								; адрес smtp-сервера вашей эл. почты
$FromName = "Иван Жуков"									; ваше имя
$FromAddress = "[email protected]"								; ваш почтовый адрес
$ToAddress = "На деревню дедушке.... Константину Макарычу"	; адрес получателя
$Subject = "Милый дедушка, Константин Макарыч!"				; тема
$Body = "Христом богом тебя молю, возьми меня отседа."		; содержание
$AttachFiles = ""
$CcAddress = ""
$BccAddress = ""
$Importance = "Normal"
$Username = ""												; логин
$Password = ""												; пароль
$IPPort = 25
$ssl = 0



Global $oMyRet[2]
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")

 $rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $IPPort, $ssl)


 ; The UDF
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
;~          ConsoleWrite('@@ Debug : $S_Files2Attach[$x] = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                ConsoleWrite('+> File attachment added: ' & $S_Files2Attach[$x] & @LF)
                $objEmail.AddAttachment($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 then $IPPort = 25
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Set Email Importance
    Switch $s_Importance
        Case "High"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
        Case "Normal"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Normal"
        Case "Low"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Low"
    EndSwitch
    $objEmail.Fields.Update
    ; Sent the Message
    $objEmail.Send
    If @error Then
        SetError(2)
        Return $oMyRet[1]
    EndIf
    $objEmail=""
 EndFunc   ;==>_INetSmtpMailCom
 ;
;
; Com Error Handler
Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    $oMyRet[0] = $HexNumber
    $oMyRet[1] = StringStripWS($oMyError.description, 3)
    ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc   ;==>MyErrFunc


У меня выдаёт следующее

### COM Error ! Number: 80020009 ScriptLine: 80 Description:?????? ???????? ????? ???????????. ?????? ???????: 550 SMTP is available only with SSL or TLS connection enabled. :-\
 

ra4o

AutoIT Гуру
Сообщения
1,165
Репутация
246
Только один вопрос, что за файл Untitled.bin он мне постоянно докидывает??
Уточните - где этот файл появляется ?
Я данным методом отправляю документы Excel , ничего лишнего к ним не цепляется.
SMTP is available only with SSL or TLS connection enabled.
Шифроваться хочет, попробуйте поставить "$ssl = 1"
 
Автор
D

Dk

Новичок
Сообщения
358
Репутация
2
ra4o сказал(а):
Только один вопрос, что за файл Untitled.bin он мне постоянно докидывает??
Уточните - где этот файл появляется ?
Я данным методом отправляю документы Excel , ничего лишнего к ним не цепляется.

На почте - у получателя. Идёт текст а внизу этот файл, он пустой.
И ещё, я попробовал отослать текст вот так [ URL ]Text pisma[/url] , а он его не распознал как ссылку. Что делать, как быть
Если просто отсылать линьк например http://translit.net, то распознаёт.
 

ra4o

AutoIT Гуру
Сообщения
1,165
Репутация
246
Автор
D

Dk

Новичок
Сообщения
358
Репутация
2
ra4o сказал(а):
Шифроваться хочет, попробуйте поставить "$ssl = 1"
Да, так таботает! Спасибо. У Ильдара файла Untitled.bin нет.


Добавлено:
Сообщение автоматически объединено:

ra4o сказал(а):
не нужно тегов, просто ссылку в тексте пишите, почтовик сам её выделить должен
внимательно посмотрите, что вы указали в ".AddAttachment ("")"
1)А если я хочу чтоб именно текст был как ссылка, что сделать? как быть?
2)Он абсолютно пустой, там ничего не указанно. .AddAttachment ("")


Вот у человека такая же проблемма была.
http://forum.lissyara.su/viewtopic.php?t=9067
Но из-за того что название прикреплённых файлов содержало кирилицу, а я вообще ничего не прикрепляю.
Отсылаю на gmail. приходит файл под названиме NONAME
 

ra4o

AutoIT Гуру
Сообщения
1,165
Репутация
246
Может в тексте что то лишнее. Вы текст из переменных берёте ? Продублируйте все параметры через "ConsoleWrite()". Эти два метода абсолютно одинаковые, реализация несколько отличается -
То же самое, только вид сбоку
 
Автор
D

Dk

Новичок
Сообщения
358
Репутация
2
ra4o сказал(а):
Может в тексте что то лишнее. Вы текст из переменных берёте ? Продублируйте все параметры через "ConsoleWrite()". Эти два метода абсолютно одинаковые, реализация несколько

Нет лишнего точно ничего не было. Текст пишу напрямую - не из переменных
Я отключил полностью .AddAttachment ("") и теперь ничего не присылает. Всмысле этот файл не присылает больше.
 
Верх