Что нового

Не могу поставить циклический FileOpen из примера на свой скрипт

Автор
B

bulldog5293

Знающий
Сообщения
172
Репутация
10
Мда, появилась новая проблема. В скрипте
Код:
while true

    Switch GUIGetMsg()
       case -3
            exitloop
       case $BUTTON
            Assign("ITEM"&$CITEM+1,GUICtrlCreateListViewItem(GUICtrlRead($INPUT1),$LIST))
            Assign("ITEM"&$CITEM+2,GUICtrlCreateListViewItem(GUICtrlRead($INPUT2),$LIST))
        $TEXT=$TEXT&GUICtrlRead($INPUT1)&"|"&GUICtrlRead($INPUT2)&"|"&GUICtrlRead($INPUT3)
        $TEXT=StringReplace($TEXT,"|",@CRLF)
        MsgBox(0,'$TEXT',$TEXT)
       Save($TEXT); Переход на ф-ию записи
       ; $FILE=FileOpen($ADDR,1)
       ; FileWrite($FILE,$TEXT &  @CRLF)
       ; FileClose($FILE)
    EndSwitch

 wend
 

Func Read($FILE)
   ;$sText = FileRead($FILE)
   $FILE=FileOpen($ADDR,0)
   $NSTR=_FileCountLines($ADDR)
   $NSTR=Ceiling($NSTR/9) ; Количество строк массива
   Dim $ARR[$NSTR][2] ; Массив для ListView
   While $ROW<$NSTR
       $ARR[$ROW][$COL]=FileReadLine($FILE)
       If @error=-1 Then ExitLoop
       If $TRIGGER=0 Then
           $COL+=1
           $TRIGGER=1
       ElseIf $TRIGGER=1 Then
           $ROW+=1
           $COL=0
           $TRIGGER=2
       Else
           $TRIGGER=0
       EndIf
   WEnd
   FileClose($FILE)
   _ArrayDisplay($ARR)
   For $i=0 To UBound($ARR,1)-1
      GUICtrlCreateListViewItem($ARR[$i][0]& '|' & $ARR[$i][1],$LIST)
   Next
EndFunc


Func Save($sText)
   $FILE=FileOpen($ADDR,1)
   FileWrite($FILE,$sText &  @CRLF)
   FileClose($FILE)
EndFunc

Обозначается 3 раза для трёх разных окон, которые в свою очередь обращаются к трём разным txt? но которые лежат в одной папке, при этом создаётся ещё по каждому txt файлу название для которых берётся из первого инпута. Проблемма в том что отдельные файлы с названием создаются, на них стоит только запись, а чтение в лист производится из основных файлов, но они не прочитываются, патался миновать возводя большенство значений в global (те которые там и стояли я прост их переименовал), но чтение в лист не происходят, может это быть связанно с тем что я не выстовлял Local?
 

gregaz

AutoIT Гуру
Сообщения
1,166
Репутация
299
bulldog5293 [?]
а чтение в лист производится из основных файлов, но они не прочитываются,

А где у тебя обращение к ф-ии : Read($FILE) :
Кто ее будет заставлять читать ?
 
Автор
B

bulldog5293

Знающий
Сообщения
172
Репутация
10
да из основных, реад функция вот:
Код:
Func Read1($FILE1)
   ;$sText = FileRead($FILE)
   $FILE1=FileOpen($ADDR1,0)
   $NSTR1=_FileCountLines($ADDR1)
   $NSTR1=Ceiling($NSTR1/21) ; Количество строк массива
   If $NSTR1<1 Then $NSTR1=1
Dim $ARR1[$NSTR1][2]
   While $ROW1<$NSTR1
       $ARR1[$ROW1][$COL1]=FileReadLine($FILE1)
       If @error=-1 Then ExitLoop
       If $TRIGGER1=0 Then
           $COL1+=1
           $TRIGGER1=1
       ElseIf $TRIGGER1=1 Then
           $ROW1+=1
           $COL1=0
           $TRIGGER1=2
       Else
           $TRIGGER1=0
       EndIf
   WEnd
   FileClose($FILE1)
   _ArrayDisplay($ARR1)
   For $i1=0 To UBound($ARR1,1)-1
      GUICtrlCreateListViewItem($ARR1[$i1][0]& '|' & $ARR1[$i1][1],$LIST1)
   Next
EndFunc
 

gregaz

AutoIT Гуру
Сообщения
1,166
Репутация
299
bulldog5293 [?]
да из основных, реад функция вот:

Да сама функция и в примере есть
Как ты ей управляешь ? Кто ее запускает ?



Добавлено:
Сообщение автоматически объединено:

Для того чтобы ф-ия начала работать нужно выполнить обращение к ней.
Например для ф-ии Save($sText) у тебя есть управляющая строка : Save($TEXT); Переход на ф-ию записи
А здесь где управление ф-ей?
 
Автор
B

bulldog5293

Знающий
Сообщения
172
Репутация
10
Типа это?
Код:
Read1($ADDR1); Переход на ф-ию чтения
Read2($ADDR2); Переход на ф-ию чтения
Read3($ADDR3); Переход на ф-ию чтения

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
		Case $GUI_EVENT_CLOSE
         Exit
	 Case $btShow;
         ShowWindow()
		case $BUTTON1
     GUISetState(@SW_Hide, $LognPassDlg) 
 Case $BUTTON_cancel1
	 GUISetState(@SW_Hide, $LognPassDlg) 
	 Case $btS	 
		 Window();
	 case $BUTTON2
	GUISetState(@SW_Hide, $LognPass) 	 
Case $BUTTON_cancel2
	GUISetState(@SW_Hide, $LognPass) 	 
	 Case $Show
		 Show();
	 case $BUTTON3
	GUISetState(@SW_Hide, $LognDlg) 	 	 
Case $BUTTON_cancel3
	GUISetState(@SW_Hide, $LognDlg) 	 	 
Case $Button_add1
	$NAME1=GUICtrlRead($INPUT1)
    $File1=FileOpen(@ScriptDir&"\"&$NAME1&".TXT",1)
    $NAME1=GUICtrlRead($INPUT1)
	FileWriteLine($File1,$NAME1)
	$NAME2=GUICtrlRead($INPUT2)
	FileWriteLine($File1,$NAME2)
    $NAME3=GUICtrlRead($INPUT3)
    FileWriteLine($File1,$NAME3)
            Assign("ITEM"&$CITEM1+1,GUICtrlCreateListViewItem(GUICtrlRead($INPUT1),$LIST1))
            Assign("ITEM"&$CITEM2+2,GUICtrlCreateListViewItem(GUICtrlRead($INPUT2),$LIST1))
        $TEXT1=$TEXT1&GUICtrlRead($INPUT1)&"|"&GUICtrlRead($INPUT2)&"|"&GUICtrlRead($INPUT3)
        $TEXT1=StringReplace($TEXT1,"|",@CRLF)
        MsgBox(0,'$TEXT',$TEXT1)
       Save1($TEXT1); Переход на ф-ию записи
       ; $FILE=FileOpen($ADDR,1)
       ; FileWrite($FILE,$TEXT &  @CRLF)
       ; FileClose($FILE)
Case $Button_add2
	$NAME4=GUICtrlRead($INPUT4)
    $File2=FileOpen(@ScriptDir&"\"&$NAME4&".TXT",1)
    $NAME4=GUICtrlRead($INPUT4)
	FileWriteLine($FILE2,$NAME4)
	$NAME5=GUICtrlRead($INPUT6)
	FileWriteLine($FILE2,$NAME5)
    $NAME6=GUICtrlRead($INPUT6)
    FileWriteLine($FILE2,$NAME6)
            Assign("ITEM"&$CITEM3+1,GUICtrlCreateListViewItem(GUICtrlRead($INPUT4),$LIST2))
            Assign("ITEM"&$CITEM4+2,GUICtrlCreateListViewItem(GUICtrlRead($INPUT5),$LIST2))
        $TEXT2=$TEXT2&GUICtrlRead($INPUT4)&"|"&GUICtrlRead($INPUT5)&"|"&GUICtrlRead($INPUT6)
        $TEXT2=StringReplace($TEXT2,"|",@CRLF)
        MsgBox(0,'$TEXT',$TEXT2)
       Save1($TEXT2); Переход на ф-ию записи
       ; $FILE=FileOpen($ADDR,1)
       ; FileWrite($FILE,$TEXT &  @CRLF)
       ; FileClose($FILE)
Case $Button_add3
	$NAME7=GUICtrlRead($INPUT7)
    $File3=FileOpen(@ScriptDir&"\"&$NAME7&".TXT",1)
    $NAME7=GUICtrlRead($INPUT8)
	FileWriteLine($File3,$NAME7)
	$NAME8=GUICtrlRead($INPUT9)
	FileWriteLine($File3,$NAME8)
    $NAME9=GUICtrlRead($INPUT3)
    FileWriteLine($File3,$NAME9)
            Assign("ITEM"&$CITEM5+1,GUICtrlCreateListViewItem(GUICtrlRead($INPUT7),$LIST3))
            Assign("ITEM"&$CITEM6+2,GUICtrlCreateListViewItem(GUICtrlRead($INPUT8),$LIST3))
        $TEXT3=$TEXT1&GUICtrlRead($INPUT7)&"|"&GUICtrlRead($INPUT8)&"|"&GUICtrlRead($INPUT9)
        $TEXT3=StringReplace($TEXT3,"|",@CRLF)
        MsgBox(0,'$TEXT',$TEXT3)
       Save1($TEXT3); Переход на ф-ию записи
       ; $FILE=FileOpen($ADDR,1)
       ; FileWrite($FILE,$TEXT &  @CRLF)
       ; FileClose($FILE)	   
	EndSwitch
WEnd



Добавлено:
Сообщение автоматически объединено:

Тока заметил и не могу понять там значения стоят
Код:
$ADDR1=@ScriptDir&"\1.txt"
$ADDR1=@ScriptDir&"\2.txt"
$ADDR1=@ScriptDir&"\3.txt"

Но значения заносятся только в
Код:
$ADDR1=@ScriptDir&"\1.txt"
почему так, ведь я всё разделял так что бы через разное окно записывать в разный файл?
 

gregaz

AutoIT Гуру
Сообщения
1,166
Репутация
299
bulldog5293 [?]
почему так, ведь я всё разделял так что бы через разное окно записывать в разный файл?

1. Функции для того и создаются ,чтобы к ним можно было обращаться несколько раз не создавая новую ф-ию.
Зачем у тебя несколько ф-й : Save1,Save2,Save3 ? Достаточно одной : Save ("Имя файла", "Текст"). И обращайся к ней с разными параметрами сколько угодно.
Тоже самое для ф-ии : Read("Имя файла")
2. Зачем ты записываешь в файл построчно , а затем еще весь текст ?
3. Зачем Для выполнения одной операции : GUISetState(@SW_Hide, $LognPass) 6 раз уставливать Case ?
Установи :
Код:
Case $BUTTON1,$BUTTON2,$BUTTON3,$BUTTON_cancel1,$BUTTON_cancel2,$BUTTON_cancel3
         GUISetState(@SW_Hide, $LognPassDlg)

4. Зачем нужен 2-хмерный массив ? В ListView можно сразу заносить элементы (как показано в примере)
Поскольку смысл всего скрипта непонятен ,то и помочь практически невозможно.
Но вот Работающий пример чтения -записи (может он не то записывает и читает,но это только тебе известно)
Код:
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiListView.au3>
#include <GUIConstants.au3>
#include <file.au3>
#include <Array.au3>
Global $ii,$sLineText=''

$sAdr1=@ScriptDir&"\1.txt"
$sAdr2=@ScriptDir&"\2.txt"
$sAdr3=@ScriptDir&"\3.txt"

$hGUI=GUICreate("Сохранение текста в полях",300,520)
$hInput1=GUICtrlCreateInput("Введите текст",10,10,280,25)
$hInput2=GUICtrlCreateInput("Введите текст",10,35,280,25)
$hInput3=GUICtrlCreateInput("Введите текст",10,60,280,25)
$hListView = GUICtrlCreateListView("1 Данные                |2 Данные               ",10,85,280,300)

$hBtAdd1=GUICtrlCreateButton("Добавить1",10,425,280,25)
$hBtAdd2=GUICtrlCreateButton("Добавить2",10,450,280,25)
$hBtAdd3=GUICtrlCreateButton("Добавить3",10,475,280,25)


GUISetState()

Read($sAdr1); ===> Переход на ф-ию чтения
Read($sAdr2); ===> Переход на ф-ию чтения
Read($sAdr3); ===> Переход на ф-ию чтения


While 1
    Switch GUIGetMsg()
		Case -3
            Exitloop
		;Case $BUTTON1,$BUTTON2,$BUTTON3,$BUTTON_cancel1,$BUTTON_cancel2,$BUTTON_cancel3
			;GUISetState(@SW_Hide, $LognPassDlg) 
		Case $hBtAdd1
			$sName1=GUICtrlRead($hInput1)
			$sName2=GUICtrlRead($hInput2)
			$sName3=GUICtrlRead($hInput3)
			GUICtrlCreateListViewItem($sName1 & "|" & $sName2,$hListView)
			$sText =$sName1 & @CRLF & $sName2 & @CRLF & $sName3 & @CRLF
			Save($sAdr1,$sText);===> Запись в 1-й файл	
		Case $hBtAdd2
			;$sName1=GUICtrlRead($hInput4)
			;$sName2=GUICtrlRead($hInput5)
			;$sName3=GUICtrlRead($hInput6)
			;GUICtrlCreateListViewItem($sName1 & "|" & $sName2,$hListView)
			;$sText =$sName1 & @CRLF & $sName2 & @CRLF & $sName3 & @CRLF
			;Save($sAdr2,$sText);===>Запись в 2-й файл	
		;Case $hBtAdd3	
		; ................
	EndSwitch
Wend

Func Save($sFile,$sTxt)
   $hFile=FileOpen($sFile,1)
   FileWrite($hFile,$sTxt)
   FileClose($hFile)
EndFunc

Func Read($sFile)
	$nStr=_FileCountLines($sFile)
	If  $nStr=0 Then Return
	$hFile=FileOpen($sFile,0)
	While 1
		$ii+=1
		$sLineText &=FileReadLine($hFile)& "|"
		If @error=-1 Then ExitLoop
		If IsInt ($ii/3) Then ; если число целое
			GUICtrlCreateListViewItem($sLineText,$hListView)
			$sLineText=''
		EndIf
		ConsoleWrite($sLineText & @LF)
	Wend
	FileClose($hFile)
EndFunc
Похоже пора тебе уже начать скрипт заново с учетом появившихся навыков и составлять его по частям:
1.Создание элементов
2.Запись в файлы
3.Чтение файлов
и т.п.





Добавлено:
Сообщение автоматически объединено:

Наверняка не нужно и несколько окон с их закрыванием -открыванием
Да и количество Input'ов наверняка неоправданно завышено . Достаточно 3.
О кол-ве файлов уже не говорю . Непонятен смысл создания стольких файлов.
Короче. Разъяснил бы общую задачу скрипта.
 
Автор
B

bulldog5293

Знающий
Сообщения
172
Репутация
10
начеркал гуи простой, из-за того что скрипт предыдущей потерял. Суть моей проблемы в том что при сохранение данных из любого окна создаётся только один файл, но нада получить 3. Тоесть 3 окна 3 файла с разными данными(теми которые вводили). Скрипт вот
Код:
#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$ADDR=@ScriptDir&"\text1.txt"

$ADDR=@ScriptDir&"\text2.txt"

$ADDR=@ScriptDir&"\text3.txt"
$FILE=FileOpen($ADDR,0) ; Режим чтения
$TEXT=FileRead($FILE)
FileClose($FILE)
$TEXT=StringReplace($TEXT,@CRLF,"|")
 

$BminerFrm = GUICreate("My GUI", 610, 350 , 180, 100)  ; will create a dialog box that when displayed is centered
$btShow1 = GUICtrlCreateButton ("Настройки1 ", 490, 30, 120, 20)
$btShow2 = GUICtrlCreateButton ("Настройки2 ", 490, 55, 120, 20)
$btShow3 = GUICtrlCreateButton ("Настройки3 ", 490, 80, 120, 20)
GUISetState ()       ; will display an empty dialog box
$LognPassDlg =  GUICreate ( "Введите ваши данные1", 502, 392, 192, 124,'', '', $BminerFrm ) ; Установив принадлежность к $BminerFrm
$input1 = GUICtrlCreateInput("", 300, 5, 150, 20)
$input2 = GUICtrlCreateInput("", 300, 30, 150, 20)
$input 3 = GUICtrlCreateInput("", 300, 55, 150, 20)
$save1 = GUICtrlCreateButton("сохранить", 350, 90, 60, 30)
$List1 = GUICtrlCreateListView("----------------------------------------------------------------------", 1, 1, 250, 350, $LVS_NOCOLUMNHEADER + $LVS_SHOWSELALWAYS)
$item1=GUICtrlCreateListViewItem($TEXT1, $List1)
GUISetState(@SW_SHOW, $BminerFrm )     
$LognDlg =  GUICreate ( "Введите ваши данные2", 502, 392, 192, 124,'', '', $BminerFrm ) ; Установив принадлежность к $BminerFrm
$input4 = GUICtrlCreateInput("", 300, 5, 150, 20)
$input5 = GUICtrlCreateInput("", 300, 30, 150, 20)
$input6 = GUICtrlCreateInput("", 300, 55, 150, 20)
$save2 = GUICtrlCreateButton("сохранить", 350, 90, 60, 30)
$List2 = GUICtrlCreateListView("----------------------------------------------------------------------", 1, 1, 250, 350, $LVS_NOCOLUMNHEADER + $LVS_SHOWSELALWAYS)
$item2=GUICtrlCreateListViewItem($Text2, $List2)
GUISetState(@SW_SHOW, $BminerFrm )     
$PassDlg =  GUICreate ( "Введите ваши данные3", 502, 392, 192, 124,'', '', $BminerFrm ) ; Установив принадлежность к $BminerFrm
$input7 = GUICtrlCreateInput("", 300, 5, 150, 20)
$input8 = GUICtrlCreateInput("", 300, 30, 150, 20)
$input9 = GUICtrlCreateInput("", 300, 55, 150, 20)
$save3 = GUICtrlCreateButton("сохранить", 350, 90, 60, 30)
$List3 = GUICtrlCreateListView("----------------------------------------------------------------------", 1, 1, 250, 350, $LVS_NOCOLUMNHEADER + $LVS_SHOWSELALWAYS)
$item3=GUICtrlCreateListViewItem($TEXT3, $List3)
GUISetState(@SW_SHOW, $BminerFrm )     
Func  ShowWindow1()
   GUISetState(@SW_SHOW, $LognPassDlg)
EndFunc
Func  ShowWindow2()
   GUISetState(@SW_SHOW, $LognDlg)
EndFunc
Func  ShowWindow3()
   GUISetState(@SW_SHOW, $PassDlg)
EndFunc
While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_CLOSE
         Exit
	Case $btShow1
         ShowWindow1()  
	Case $btShow2
         ShowWindow2()
    Case $btShow3
         ShowWindow3()  		 
   EndSwitch
WEnd
 

gregaz

AutoIT Гуру
Сообщения
1,166
Репутация
299
bulldog5293 [?]
Суть моей проблемы в том что при сохранение данных из любого окна создаётся только один файл, но нада получить 3. Тоесть 3 окна 3 файла с разными данными(теми которые вводили). Скрипт вот

У тебя же здесь вовсе нет записи???
А как будет записываться в 3 файла , если у всех 3-х одно имя : $ADDR и оно глобально.
Вот :
Код:
#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$ADDR1=@ScriptDir&"\text1.txt"
$TEXT1=Read($ADDR1)
$ADDR2=@ScriptDir&"\text2.txt"
$TEXT2=Read($ADDR2)
$ADDR3=@ScriptDir&"\text3.txt"
$TEXT3=Read($ADDR3)
 

$BminerFrm = GUICreate("My GUI", 610, 350 , 180, 100)  ; will create a dialog box that when displayed is centered
$btShow1 = GUICtrlCreateButton ("Настройки1 ", 490, 30, 120, 20)
$btShow2 = GUICtrlCreateButton ("Настройки2 ", 490, 55, 120, 20)
$btShow3 = GUICtrlCreateButton ("Настройки3 ", 490, 80, 120, 20)
;GUISetState ()       ; will display an empty dialog box
$LognPassDlg =  GUICreate ( "Введите ваши данные1", 502, 392, 192, 124,'', '', $BminerFrm ) ; Установив принадлежность к $BminerFrm
$input1 = GUICtrlCreateInput("", 300, 5, 150, 20)
$input2 = GUICtrlCreateInput("", 300, 30, 150, 20)
$input3 = GUICtrlCreateInput("", 300, 55, 150, 20)
$save1 = GUICtrlCreateButton("сохранить", 350, 90, 60, 30)
$List1 = GUICtrlCreateListView("----------------------------------------------------------------------", 1, 1, 250, 350, $LVS_NOCOLUMNHEADER + $LVS_SHOWSELALWAYS)
$item1=GUICtrlCreateListViewItem($TEXT1, $List1)
;GUISetState(@SW_SHOW, $BminerFrm )     
$LognDlg =  GUICreate ( "Введите ваши данные2", 502, 392, 192, 124,'', '', $BminerFrm ) ; Установив принадлежность к $BminerFrm
$input4 = GUICtrlCreateInput("", 300, 5, 150, 20)
$input5 = GUICtrlCreateInput("", 300, 30, 150, 20)
$input6 = GUICtrlCreateInput("", 300, 55, 150, 20)
$save2 = GUICtrlCreateButton("сохранить", 350, 90, 60, 30)
$List2 = GUICtrlCreateListView("----------------------------------------------------------------------", 1, 1, 250, 350, $LVS_NOCOLUMNHEADER + $LVS_SHOWSELALWAYS)
$item2=GUICtrlCreateListViewItem($Text2, $List2)
;GUISetState(@SW_SHOW, $BminerFrm )     
$PassDlg =  GUICreate ( "Введите ваши данные3", 502, 392, 192, 124,'', '', $BminerFrm ) ; Установив принадлежность к $BminerFrm
$input7 = GUICtrlCreateInput("", 300, 5, 150, 20)
$input8 = GUICtrlCreateInput("", 300, 30, 150, 20)
$input9 = GUICtrlCreateInput("", 300, 55, 150, 20)
$save3 = GUICtrlCreateButton("сохранить", 350, 90, 60, 30)
$List3 = GUICtrlCreateListView("----------------------------------------------------------------------", 1, 1, 250, 350, $LVS_NOCOLUMNHEADER + $LVS_SHOWSELALWAYS)
$item3=GUICtrlCreateListViewItem($TEXT3, $List3)
GUISetState(@SW_SHOW, $BminerFrm )     
GUISetState(@SW_Hide, $LognPassDlg )
GUISetState(@SW_Hide, $LognDlg )
GUISetState(@SW_Hide, $PassDlg)


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $btShow1
			ShowWindow($LognPassDlg)  
		Case $btShow2
			ShowWindow($LognDlg)
		Case $btShow3
			ShowWindow($PassDlg)           
		Case $save1
			$sName1=GUICtrlRead($input1)
			$sName2=GUICtrlRead($input2)
			$sName3=GUICtrlRead($input3)
			$sText =$sName1 & @CRLF & $sName2 & @CRLF & $sName3 & @CRLF
			ConsoleWrite($sText & @LF)
			Save($ADDR1,$sText);===> Запись в 1-й файл	
			GUISetState(@SW_Hide, $LognPassDlg )
		Case $save2
			$sName1=GUICtrlRead($input4)
			$sName2=GUICtrlRead($input5)
			$sName3=GUICtrlRead($input6)
			$sText =$sName1 & @CRLF & $sName2 & @CRLF & $sName3 & @CRLF
			Save($ADDR2,$sText);===> Запись в 2-й файл	
			ConsoleWrite($sText & @LF)
			GUISetState(@SW_Hide, $LognDlg )
		Case $save3
			$sName1=GUICtrlRead($input7)
			$sName2=GUICtrlRead($input8)
			$sName3=GUICtrlRead($input9)
			$sText =$sName1 & @CRLF & $sName2 & @CRLF & $sName3 & @CRLF
			Save($ADDR3,$sText);===> Запись в 3-й файл	
			ConsoleWrite($sText & @LF)
			GUISetState(@SW_Hide, $PassDlg)
   EndSwitch
WEnd

Func  ShowWindow($hWnd)
   GUISetState(@SW_SHOW, $hWnd)
EndFunc

Func Read($sFile)
	$hFile=FileOpen($sFile,0) 
	$sText=FileRead($hFile)
	FileClose($hFile)
	$sText=StringReplace($sText,@CRLF,"|") 
	Return $sText
EndFunc 

Func Save($sFile,$sTxt)
   $hFile=FileOpen($sFile,1)
   FileWrite($hFile,$sTxt)
   FileClose($hFile)
EndFunc



Добавлено:
Сообщение автоматически объединено:

Одно пожелание :
Можно ведь проверитьпрежде чем выложить скрипт , чтобы он хотя бы запускался без ошибок
 
Автор
B

bulldog5293

Знающий
Сообщения
172
Репутация
10
gregaz спс за терпени и понимание, а ещё за предоставленный тобою скрипт, то что нада :ok: :IL_AutoIt_1: :D :laugh:просто слов нет
 
Верх