[Файловая система] Выбор папки из директории по дате последнего изменения

[Oleg-lamer [?]]

Версия AutoIt: 3.3.14.2

Описание:
Есть некая папка Dir
В ней лежит еще несколько папок с разными названиями (цифры, буквы)\
Задача выбрать из этих папок ту над которой производились последние изменения и передать ее имя в переменную
$Version
 
Т.е. у меня есть команда на запуск файла:

Код: [Выделить]

run (@ProgramFilesDir & "\1cv8\" & $Version & "\bin\chdbfl.exe","", @SW_HIDE,7)
И соответственно вместо Version должно быть имя папки с версией программы в духе "8.3.2056" и периодически в паке 1cv8 будут появлятся новые папки с новыми версиями проги, и мне нужно чтобы скрипт всегда запускал файл из последней созданной папки в расположении 1cv8.

Примечания:
я находил различные виды решения но для поиска файлов в папках, и они были очень громоздкие, я не мог понять как их переделать под поиск папок, ибо как понятно из ник-нейма, я еще совсем недавно (первая неделя) как начал работать с autoit.

Если напишите код с коментариями буду прям ну очень признателен, ибо хочу потихоньку разобратся как все это работает.

[ra4o [?]]

Так, вроде-бы проще всего :

(нажмите для показа/скрытия)

Код: AutoIt [Выделить]

#include <File.au3>
$MyDir = @ScriptDir ;Папка , где искать
;Получение массива с именами папок в указанной дирректории
$AllFile = _FileListToArray($MyDir, Default, 2)
If IsArray($AllFile) Then ;Если массив создан
    ;Для начала предполагаем, что первая папка и есть последняя модифицированная
    $LastFile = $AllFile[1]
    $LastFileDate = FileGetTime($MyDir & '\' & $AllFile[1], 0, 1)
    ;Если найдено больше, чем одна папка
    If $AllFile[0] > 1 Then
        ;Сравниваем дату модификации каждой из папок
        For $i = 2 To $AllFile[0]
            If FileGetTime($MyDir & '\' & $AllFile[$i], 0, 1) > $LastFileDate Then
                $LastFile = $AllFile[$i]
                $LastFileDate = FileGetTime($MyDir & '\' & $AllFile[$i], 0, 1)
            EndIf
        Next
    EndIf
EndIf

MsgBox(0, '','Файл '& $LastFile & @CR &'Путь к файлу  '& $MyDir & '\' & $LastFile & @CR&'Модифицирован '& $LastFileDate)
 

[Oleg-lamer [?]]

Отлично! Работает! Огромное спасибо, и отдельное за комменты. не сразу сообразил какую из переменных вытаскивать, для получения имени папки, но через пару минут вкурил)

[Garrett [?]]

На форуме принято помечать тему решенной после получения ответа на свой вопрос!
Вверху или внизу темы нажмите на ссылку такого вида:
Тема не решена

[Oleg-lamer [?]]

Понимаю что где то туплю но не пойму как так, вот этот код переделанный под мои нужды у меня работал без вопросов, но вдруг стал ругатся что обращается к не заведенной переменной. Раньше я отсюда брал $LastFile и вставлял его в нужные места, но теперь он этого не дает сделать и я прям потерялся - а какая переменная в результате работы этой функции будет искомым обьектом? Я не могу понять куда передается результат.

Код: AutoIt [Выделить]

Global $MyDir = (@ProgramFilesDir & "\1cv8\") ;Папка , где искать
;Получение массива с именами папок в указанной дирректории
$AllFile = _FileListToArray($MyDir, Default, 2)
If IsArray($AllFile) Then ;Если массив создан
    ;Для начала предполагаем, что первая папка и есть последняя модифицированная
    $LastFile = $AllFile[1]
    $LastFileDate = FileGetTime($MyDir & '\' & $AllFile[1], 0, 1)
    ;Если найдено больше, чем одна папка
    If $AllFile[0] > 1 Then
        ;Сравниваем дату модификации каждой из папок
        For $i = 2 To $AllFile[0]
            If FileGetTime($MyDir & '\' & $AllFile[$i], 0, 1) > $LastFileDate Then
                $LastFile = $AllFile[$i]
                $LastFileDate = FileGetTime($MyDir & '\' & $AllFile[$i], 0, 1)
            EndIf
        Next
    EndIf
 EndIf
 

[Alofa [?]]

... но вдруг стал ругатся...

А первую строку-то скрипта от ra4o где потеряли?

[Oleg-lamer [?]]

не инклюд у меня в коде на месте. я в комент его не добавил только. в общем коде оно вообще вот так выглядит

Код: AutoIt [Выделить]

#include <GUIConstantsEx.au3>

#include <File.au3>

#include <Date.au3>

#include <Inet.au3>

Global $MyDir = (@ProgramFilesDir & "\1cv8") ;Папка , где искать
;Получение массива с именами папок в указанной дирректории
$AllFile = _FileListToArray($MyDir, Default, 2)
If IsArray($AllFile) Then ;Если массив создан
    ;Для начала предполагаем, что первая папка и есть последняя модифицированная
    $LastFile = $AllFile[1]
    $LastFileDate = FileGetTime($MyDir & '\' & $AllFile[1], 0, 1)
    ;Если найдено больше, чем одна папка
    If $AllFile[0] > 1 Then
        ;Сравниваем дату модификации каждой из папок
        For $i = 2 To $AllFile[0]
            If FileGetTime($MyDir & '\' & $AllFile[$i], 0, 1) > $LastFileDate Then
                $LastFile = $AllFile[$i]
                $LastFileDate = FileGetTime($MyDir & '\' & $AllFile[$i], 0, 1)
            EndIf
        Next
    EndIf
 EndIf

 

[Alofa [?]]

Пробуйте:

(нажмите для показа/скрытия)

Код: AutoIt [Выделить]

#include <GUIConstantsEx.au3>
#include <File.au3>
#include <Date.au3>
#include <Inet.au3>

Global $LastFile, $MyDir = (@ProgramFilesDir & "\1cv8") ;Папка , где искать
;Получение массива с именами папок в указанной дирректории
$AllFile = _FileListToArray($MyDir, Default, 2)
If @error Then
    Local $aErrors[4] = ['Путь не найден или неисправный', 'Неверный параметр $sFilter', 'Неверный параметр $iFlag', 'Файл(ы) не найдены']
    MsgBox(262144+16, 'Ошибка!', $aErrors[@error - 1])
Else ;Если массив создан
    ;Для начала предполагаем, что первая папка и есть последняя модифицированная
    $LastFile = $AllFile[1]
    $LastFileDate = FileGetTime($MyDir & '\' & $AllFile[1], 0, 1)
    ;Если найдено больше, чем одна папка
    If $AllFile[0] > 1 Then
        ;Сравниваем дату модификации каждой из папок
        For $i = 2 To $AllFile[0]
            If FileGetTime($MyDir & '\' & $AllFile[$i], 0, 1) > $LastFileDate Then
                $LastFile = $AllFile[$i]
                $LastFileDate = FileGetTime($MyDir & '\' & $AllFile[$i], 0, 1)
            EndIf
        Next
    EndIf
EndIf

[Oleg-lamer [?]]

Помогло спасибо!)