Автор Тема: Щелчки по кнопкам и выбор в списке  (Прочитано 379 раз)

0 Пользователей и 1 Гость просматривают эту тему.

Оффлайн Василиса Лукьянчикова [?]

  • Новичок
  • *
  • Сообщений: 22
  • Репутация: 0
    • Награды
  • Версия AutoIt: 3.3.14.0
Версия AutoIt: 3.3.14.2

Описание:
Всем привет, помогите пожалуйста выполнить следующую операцию:

В окне - с заголовком  "Печать" - в меню списка ComboBox1 выбрать пункт начинающийся со слова SmartDraw  и нажать кнопку Button11.         
Затем в появившемся окошке "Сохранить как" ввести в поле Edit1 - адрес G:\печать документа\1.pdf    и  нажать кнопку Button2 

Примечания:

Русское сообщество AutoIt

Щелчки по кнопкам и выбор в списке
« Отправлен: Февраль 03, 2018, 23:15:40 »

Помечен как лучший ответ пользователем Василиса Лукьянчикова Отправлен Февраль 04, 2018, 22:59:31

Оффлайн Tempo [?]

  • Продвинутый
  • ***
  • Сообщений: 403
  • Репутация: 92
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.14.0
Re: Щелчки по кнопкам и выбор в списке
« Ответ #1, Отправлен: Февраль 04, 2018, 12:16:04 »
Код: AutoIt [Выделить]
#RequireAdmin
#include <MsgBoxConstants.au3>

_Example()

Func _Example()
    Local $hWnd, $hSaveWnd, $hControl, $sTitle1 = "Печать", $sTitle2 = "Сохранить как", $sItem = "SmartDraw"
    Local $sCombo = "ComboBox1", $sEdit = "Edit1", $sButton1 = "Button11", $sButton2 = "Button2"

    $hWnd = WinWait($sTitle1, Null, 5)
    If Not $hWnd Then Exit _Error('Не удалось найти окно "' & $sTitle1 & '"')

    $hControl = _ControlWait($hWnd, Null, $sCombo, 5)
    If @error Then _Error('Не удалось получить дескриптор элемента управления "' & $sCombo & '"')

    ControlCommand($hWnd, Null, $hControl, "SelectString", $sItem)
    If @error Then _Error('Не удалось найти пункт "' & $sItem & '"')

    $hControl = _ControlWait($hWnd, Null, $sButton1, 5)
    If @error Then _Error('Не удалось получить дескриптор элемента управления "' & $sButton1 & '"')
    ControlClick($hWnd, Null, $hControl)

    $hSaveWnd = WinWait($sTitle2, Null, 5)
    If Not $hSaveWnd Then _Error('Не удалось найти окно "' & $sTitle2 & '"')

    $hControl = _ControlWait($hSaveWnd, Null, $sEdit, 5)
    If @error Then _Error('Не удалось получить дескриптор элемента управления "' & $sEdit & '"')
    ControlSetText($hSaveWnd, Null, $hControl, "G:\печать документа\1.pdf")

    $hControl = _ControlWait($hSaveWnd, Null, $sButton2, 5)
    If @error Then _Error('Не удалось получить дескриптор элемента управления "' & $sButton2 & '"')
    ControlClick($hSaveWnd, Null, $hControl)
EndFunc   ;==>_Example

Func _ControlWait($vWnd, $sText, $sControl, $iTimeout = 0)
    If $iTimeout = Default Then $iTimeout = 0
    Local $hControl, $iWait = Opt("WinWaitDelay"), $hTimer = TimerInit()
    $iTimeout *= 1000
    Do
        Sleep($iWait)
        $hControl = ControlGetHandle($vWnd, $sText, $sControl)
        If $iTimeout And TimerDiff($hTimer) >= $iTimeout Then Return SetError(1, 0, 0)
    Until $hControl
    Return SetError(0, 0, $hControl)
EndFunc   ;==>_ControlWait

Func _Error($sText)
    Exit MsgBox($MB_ICONERROR + $MB_TOPMOST, "Ошибка", $sText)
EndFunc   ;==>_Error


Оффлайн Василиса Лукьянчикова [?]

  • Новичок
  • *
  • Сообщений: 22

  • Автор темы
  • Репутация: 0
    • Награды
  • Версия AutoIt: 3.3.14.0
Re: Щелчки по кнопкам и выбор в списке
« Ответ #2, Отправлен: Февраль 04, 2018, 22:59:27 »
Спасибо

Русское сообщество AutoIt

Re: Щелчки по кнопкам и выбор в списке
« Ответ #2 Отправлен: Февраль 04, 2018, 22:59:27 »

 

Похожие темы

  Тема / Автор Ответов Последний ответ
20 Ответов
8735 Просмотров
Последний ответ Декабрь 25, 2010, 17:05:24
от SyDr
8 Ответов
5020 Просмотров
Последний ответ Январь 22, 2011, 17:13:09
от madmasles
10 Ответов
6517 Просмотров
Последний ответ Февраль 11, 2011, 16:08:47
от `p r o x y
6 Ответов
3529 Просмотров
Последний ответ Апрель 05, 2011, 15:55:34
от madmasles
0 Ответов
2623 Просмотров
Последний ответ Март 26, 2012, 20:04:58
от erlik
1 Ответов
2577 Просмотров
Последний ответ Май 09, 2013, 09:32:12
от madmasles
2 Ответов
2694 Просмотров
Последний ответ Август 17, 2013, 00:10:04
от Naisho
3 Ответов
2319 Просмотров
Последний ответ Сентябрь 05, 2013, 23:48:34
от PACHOM
5 Ответов
2760 Просмотров
Последний ответ Февраль 23, 2014, 13:54:16
от Garrett
0 Ответов
1007 Просмотров
Последний ответ Февраль 28, 2016, 12:46:56
от Suppir