Что нового

[Автоматизация] Открытие Интернет-страницы

0pupentium

Новичок
Сообщения
5
Репутация
0
Здравствуйте.
Подскажите пожалуйста, как можно выполнить операцию приведенную ниже с помощью цикла.
Если не удастся загрузить Интернет-страницу, пытаться загрузить ее снова 4 раза, а в случае неудачи вывести сообщение с ошибкой.

Код:
#include<IE.au3>

$Page = 'http://google.ru'

$IE = _IECreate($Page, 1)
If Not (_IEPropertyGet($IE, 'title') == 'Google') Then
	_IENavigate($IE, $Page)
	If Not (_IEPropertyGet($IE, 'title') == 'Google') Then
		_IENavigate($IE, $Page)
		If Not (_IEPropertyGet($IE, 'title') == 'Google') Then
			_IENavigate($IE, $Page)
			If Not (_IEPropertyGet($IE, 'title') == 'Google') Then
				_IENavigate($IE, $Page)
				If Not (_IEPropertyGet($IE, 'title') == 'Google') Then
					MsgBox(4096, 'Ошибка', 'Не удалось загрузить Интернет-страницу.')
				EndIf
			EndIf
		EndIf
	EndIf
EndIf
 

CreatoR

Must AutoIt!
Команда форума
Администратор
Сообщения
8,671
Репутация
2,481
Код:
#include <IE.au3>

$sPage = 'http://google.ru'

$oIE = _IECreate($sPage, 1)
$iAlert = 1

For $i = 1 To 4
	If _IEPropertyGet($oIE, 'title') == 'Google' Then
		$iAlert = 0
		ExitLoop
	EndIf
	
	_IENavigate($oIE, $sPage)
Next

If $iAlert Then
	MsgBox(4096, 'Ошибка', 'Не удалось загрузить Интернет-страницу.')
EndIf
 
Автор
0

0pupentium

Новичок
Сообщения
5
Репутация
0
CreatoR, спасибо за ответ.
У меня возник еще один вопрос по теме. Что нужно добавить, если вместо "MsgBox(4096, "", "")" использовать "MsgBox(5, "", "")" (Повтор и Отмена)?
 

CreatoR

Must AutoIt!
Команда форума
Администратор
Сообщения
8,671
Репутация
2,481
0pupentium [?]
Что нужно добавить, если вместо "MsgBox(4096, "", "")" использовать "MsgBox(5, "", "")" (Повтор и Отмена)?
При повторе цикл должен начаться заново?

Код:
#include <IE.au3>

$sPage = 'http://google.ru'

$oIE = _IECreate($sPage, 1)

While 1
	For $i = 1 To 4
		If _IEPropertyGet($oIE, 'title') == 'Google' Then
			ExitLoop 2
		EndIf
		
		_IENavigate($oIE, $sPage)
	Next

	If MsgBox(5, 'Ошибка', 'Не удалось загрузить Интернет-страницу.') <> 4 Then
		ExitLoop
	EndIf
WEnd

;Загрузка удалась


как то так.
 
Верх