Как сохранить отдельные файлы по дням

Global $PathToFiles = @ScriptDir & '\' ; Директория, где находится Текстовый Файл и где будут созданы папки по Годам
Global $FileIn = $PathToFiles & 'Статистика 2015.txt' ; Наш текстовой файл

$sText = FileRead($FileIn)
If @error Then Exit MsgBox(16, 'Ошибка', 'Ошибка чтения из файла!')

$asStrArray = StringRegExp($sText, '((\d{2}\.\d{2}\.\d{4})\h.*)\v?', 3)
If @error Then Exit MsgBox(48, 'Отчет', 'Нет совпадений!')

Local $sDate, $iYear, $hFile, $vCRLF
For $i = 1 To UBound($asStrArray) - 1 Step 2
	Do
		Switch $sDate
			Case False
				$sDate = $asStrArray[$i]
				$iYear = StringRegExpReplace($sDate, '\d{2}\.\d{2}\.(\d{4})', '${1}')
				If Not FileExists($PathToFiles & $iYear) Then DirCreate($PathToFiles & $iYear)
				If $hFile Then FileClose($hFile)
				$hFile = FileOpen($PathToFiles & $iYear & '\Err_' & StringRegExpReplace($sDate, '(\d{2})\.(\d{2})\.(\d{4})', '${3}-${2}-${1}') & '.txt', 2)
				If $hFile = -1 Then Exit MsgBox(16, 'Ошибка', 'Произошла ошибка создания файлов статистики!')
				ContinueCase
			Case Else
				If $sDate = $asStrArray[$i] Then
					FileWrite($hFile, $vCRLF & $asStrArray[$i - 1])
					$vCRLF = @CRLF
				Else
					$sDate = False
					$vCRLF = ''
				EndIf
		EndSwitch
	Until $sDate
Next
FileClose($hFile)

Local $hFile = FileOpen("Статистика 2015.txt", 0), $sDir = "", $sFile = "", $aFile = "", $aData = ""
If $hFile = -1 Then
	MsgBox(16, @ScriptName, "При чтении файла произошла ошибка.")
	Exit(1)
EndIf

Local $oObj = ObjCreate("Scripting.Dictionary")
While 1
	$sLine = FileReadLine($hFile)
	If @error = -1 Then ExitLoop

	$sFile = StringLeft($sLine, 10)
	$sDir  = StringRight($sFile, 4)
	$iDir = DirGetSize($sDir)
	If ($iDir = -1) And (@error = 1) Then
		DirCreate($sDir)
	EndIf

	$oObj.Item(StringFormat("%s\Err_%s.txt", $sDir, $sFile)) &= $sLine & @CRLF
WEnd

FileClose($hFile)

$aFile = $oObj.Keys
$aData = $oObj.Items

For $i = 0 To UBound($aFile)-1
	Local $hFile = FileOpen($aFile[$i], 2)
	If $hFile = -1 Then
		MsgBox(16, @ScriptName, "При чтении файла произошла ошибка.")
		Exit(2)
	EndIf
	FileWrite($hFile, $aData[$i])
	FileClose($hFile)
	Sleep(5)
Next