Что нового

[Сеть, интернет] Отправка запроса POST

CreatiK

Новичок
Сообщения
93
Репутация
4
помогите сократить код autoit
Код:
Header = "Content-Type: application/x-www-form-urlencoded"
$Host = "109.234.155.196"
$File = "/prison/universal.php?office"
$URL = "http://" & $Host & $File
$PostData = "sig=a2c4397152d04569f6cd2d1002db7648&key=f91bca177f94e848e4d763332fbfd836&getidea=1&user=57292995&method=office"


Func QuickOutput($Filename, $Output, $Mode)
	Local $File = FileOpen($Filename, $Mode)
	FileWriteLine($File, $Output)
	FileClose($File)
EndFunc


;~ ;http://msdn.microsoft.com/library/default.asp?url=/library/en-us/wininet/wininet/http_sessions.asp
$Internet = _InternetOpen("AutoIT3")
$InternetConnection = _InternetConnect($Internet, $Host)
$Request = _HttpOpenRequest($InternetConnection, "POST", $File)
_HttpSendRequest($Request, $Header, StringLen($Header), $PostData, StringLen($PostData))
$Response = _InternetRead($Request)
QuickOutput("Response.html", $Response, 2)
_InternetCloseHandle($Internet)


Func _InternetOpen($s_Agent, $l_AccessType = 1, $s_ProxyName = '', $s_ProxyBypass = '', $l_Flags = 0)

	Local $ai_InternetOpen = DllCall('wininet.dll', 'long', 'InternetOpen', 'str', $s_Agent, 'long', $l_AccessType, 'str', $s_ProxyName, 'str', $s_ProxyBypass, 'long', $l_Flags)
	If @error Or $ai_InternetOpen[0] = 0 Then
		SetError(-1)
		Return 0
	EndIf

	Return $ai_InternetOpen[0]

EndFunc

Func _InternetConnect($l_InternetSession, $s_ServerName)

	Local $ai_InternetConnect = DllCall('wininet.dll', 'long', 'InternetConnect', 'long', $l_InternetSession, 'str', $s_ServerName, 'int', 80, 'int', 0, 'int', 0, 'long', 3, 'long', 0, 'long', 0)
	If @error Or $ai_InternetConnect[0] = 0 Then
		SetError(-1)
		Return 0
	EndIf

	Return $ai_InternetConnect[0]

EndFunc

Func _HttpOpenRequest($l_InternetConnection, $s_Verb, $s_File)
	Local $ai_HttpOpenRequest = DllCall('wininet.dll', 'long', 'HttpOpenRequest', 'long', $l_InternetConnection, 'str', $s_Verb, 'str', $s_File, 'int', 0, 'int', 0, 'int', 0, 'int', 0, 'int', 0)
	If @error Or $ai_HttpOpenRequest[0] = 0 Then
		SetError(-1)
		Return 0
	EndIf

	Return $ai_HttpOpenRequest[0]

EndFunc

Func _HttpSendRequest($l_Request, $s_Headers, $l_HeadersLength, $s_Data, $l_DataLength)
	Local $ai_HttpSendRequest = DllCall('wininet.dll', 'long', 'HttpSendRequest', 'long', $l_Request, 'str', $s_Headers, 'long', $l_HeadersLength, 'str', $s_Data, 'long', $l_DataLength)
	If @error Or $ai_HttpSendRequest[0] = 0 Then
		SetError(-1)
		Return 0
	EndIf

	Return $ai_HttpSendRequest[0]

EndFunc

Func _InternetRead($l_Request)
	Local $ai_IRF, $s_Buf = ''
	Local $v_Struct = DllStructCreate('udword')
	DllStructSetData($v_Struct, 1, 1)
	
	While DllStructGetData($v_Struct, 1) <> 0
		$ai_IRF = DllCall('wininet.dll', 'int', 'InternetReadFile', 'long', $l_Request, 'str', '', 'int', 256, 'ptr', DllStructGetPtr($v_Struct))        
		$s_Buf &= StringLeft($ai_IRF[2], DllStructGetData($v_Struct, 1))
	WEnd
	Return $s_Buf
EndFunc
Func _InternetCloseHandle($l_InternetSession)

	Local $ai_InternetCloseHandle = DllCall('wininet.dll', 'int', 'InternetCloseHandle', 'long', $l_InternetSession)
	If @error Or $ai_InternetCloseHandle[0] = 0 Then
		SetError(-1)
		Return 0
	EndIf

	Return $ai_InternetCloseHandle[0]

EndFunc



до минимальных размеров.
и создать GUI чтобы можно было водить эти значение
Код:
$PostData = "sig=a2c4397152d04569f6cd2d1002db7648&key=f91bca177f94e848e4d763332fbfd836[/b]&getidea=1&user=57292995&method=office"
в Edit и при отправке они вводились в код
 

r35p3ct

Продвинутый
Сообщения
228
Репутация
60
Наверно так:
Код:
$Host = "109.234.155.196"
$File = "/prison/universal.php?office"
$URL = "http://" & $Host & $File
$PostData = "sig=a2c4397152d04569f6cd2d1002db7648&key=f91bca177f94e848e4d763332fbfd836[/b]&getidea=1&user=57292995&method=office"
$oHTTP = ObjCreate("WinHttp.WinHttpRequest.5.1")
$oHTTP.Open("POST", $URL)
$oHTTP.SetRequestHeader("Content-Type","application/x-www-form-urlencoded")
$oHTTP.Send($PostData)
$oHTTP.WaitForResponse
$Response = $oHTTP.ResponseText


ЗЫ Почему не хотите использовать поиск? Эти вопросы уже не раз обсуждались.
 
Автор
C

CreatiK

Новичок
Сообщения
93
Репутация
4
А как создать GUI при вводе в Edit например вот этот
Код:
&user=57292995
он вставлялся автоматически в эти параметры
$PostData = "sig=a2c4397152d04569f6cd2d1002db7648&key=f91bca177f94e848e4d763332fbfd836&getidea=1&user=57292995&method=office"
 

Redline

AutoIT Гуру
Сообщения
506
Репутация
375
CreatiK [?]
А как создать GUI при вводе в Edit например вот этот
Код:
$sUser = InputBox('ID пользователя', 'Введите ID пользователя', '57292995', '', 360, 120)
$PostData  = "sig=a2c4397152d04569f6cd2d1002db7648&key=f91bca177f94e848e4d763332fbfd836&getidea=1&user=" & $sUser & "&method=office"
 
Автор
C

CreatiK

Новичок
Сообщения
93
Репутация
4
Кто может сделать что бы в GUI окне выводилась информация об сигаретах? из этой игры http://vkontakte.ru/app1979194.
Например чтобы сколько в даный момент времени сигарет у меня находятся
 
Автор
C

CreatiK

Новичок
Сообщения
93
Репутация
4
когда отправляем запрос то нам приходит Response
Код:
<?xml version="1.0" encoding="UTF-8"?>
<data>
	<user>
		<name>%3EC%D1%83%7D%7Bo%D0%99%3C</name>
		<helpevents>1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,1,1,1,1,1,1,1,1,1,1</helpevents>
		<money>10</money>
		<rating>4093</rating>
		<diamond>10</diamond>
		<booster_price>15</booster_price>
		<already_spin>0</already_spin>
		<currentBackground>0</currentBackground>
		<vote_points_count>20</vote_points_count>
		<energy>10</energy>
		<energy_ttu>154</energy_ttu>
		<energyForVote>0</energyForVote>
		<maxEnergyForVote>300</maxEnergyForVote>
		<friends_invited>0</friends_invited>
		<popularity>69</popularity>
		<duel_price>50</duel_price>
		<duel_reward>7</duel_reward>
	</user>
как можно сделать чтобы <money>10</money>
выводилась в GUI окне
 

madmasles

Модератор
Глобальный модератор
Сообщения
7,790
Репутация
2,322
CreatiK
Попробуйте так:
Код:
$sMessage = StringRegExpReplace($sResponse, '(?s).*?<money>(\d+)</money>?.*', '\1')
GUICtrlSetData($Control, $sMessage)
 
Автор
C

CreatiK

Новичок
Сообщения
93
Репутация
4
можешь пример мне привести вот запрос
Код:
$Host = "109.234.155.196"
$File = "/prison/universal.php?getInfo"
$URL = "http://" & $Host & $File
$PostData = "sig=5064ea55b0c410563fe3bd4dd23cd5c8&key=f91bca177f94e848e4d763332fbfd836&user=57292995&method=getInfo"
$oHTTP = ObjCreate("WinHttp.WinHttpRequest.5.1")
$oHTTP.Open("POST", $URL)
$oHTTP.SetRequestHeader("Content-Type","application/x-www-form-urlencoded")
$oHTTP.Send($PostData)
$oHTTP.WaitForResponse
$Response = $oHTTP.ResponseText

что бы выводилась в GUI при запуске скрипта
 

madmasles

Модератор
Глобальный модератор
Сообщения
7,790
Репутация
2,322
CreatiK
Можно так попробовать:
Код:
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>

Opt('MustDeclareVars', 1)
Opt('TrayIconDebug', 1)

Global $hGUI, $Input, $Button, $nMsg, $sMoney

$hGUI = GUICreate('My money', 200, 90, -1, -1)
GUICtrlCreateLabel('Значение money', 40, 5, 120, 20, $SS_CENTER)
$Input = GUICtrlCreateInput('', 60, 20, 80, 20, BitOR($ES_READONLY, $ES_CENTER))
$Button = GUICtrlCreateButton('Получить', 50, 50, 100, 25)
GUISetState()

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button
			GUISetState(@SW_DISABLE)
			GUICtrlSetData($Input, '')
			$sMoney = _My_Func()
			If $sMoney <> -1 Then
				GUICtrlSetData($Input, $sMoney)
			Else
				GUICtrlSetData($Input, 'Ошибка')
			EndIf
			GUISetState(@SW_ENABLE)
	EndSwitch
WEnd

Func _My_Func()
	Local $Response, $sMessage
	Local $Host = '109.234.155.196'
	If Not Ping($Host) Then Return -1
	Local $File = '/prison/universal.php?getInfo'
	Local $URL = 'http://' & $Host & $File
	Local $PostData = 'sig=5064ea55b0c410563fe3bd4dd23cd5c8&key=f91bca177f94e848e4d763332fbfd836&user=57292995&method=getInfo'
	Local $oHTTP = ObjCreate('WinHttp.WinHttpRequest.5.1')
	$oHTTP.Open('POST', $URL)
	$oHTTP.setTimeouts(5000, 5000, 10000, 10000)
	$oHTTP.SetRequestHeader('Content-Type', 'application/x-www-form-urlencoded')
	Execute('$oHTTP.Send($PostData)')
	If (@error) Or ($oHTTP.Status <> 200) Then
		Return -1
	Else
		$oHTTP.WaitForResponse
		$Response = $oHTTP.ResponseText
		If Not $Response Then Return -1
	EndIf
	$sMessage = StringRegExpReplace($Response, '(?s).*?<money>(\d+)</money>?.*', '\1')
	If Not $sMessage Then Return -1
	Return $sMessage
EndFunc   ;==>_My_Func
 
Автор
C

CreatiK

Новичок
Сообщения
93
Репутация
4
Столкнулся с такой проблемой как можно сделать чтобы запрос выполнялся через пять минут каждый раз
И в коде Response есть такой
Код:
<name>%3EC%D1%83%7D%7Bo%D0%99%3C</name>
Как чтобы он выводился рускими буквами и как записать
Код:
$sMessage = StringRegExpReplace($Response, '(?s).*?<money>(\d+)</money>?.*', '\1')
 

Sp01LeR

Знающий
Сообщения
45
Репутация
12
чтобы запрос выполнялся через пять минут каждый раз

Код:
AdlibRegister("Имя_Функции_Отправки",  300000)


Как чтобы он выводился рускими буквами и как записать
Код:
Func _Encoding_URIDecode($sString)
	Local $oSC = ObjCreate("ScriptControl")
	$oSC.Language = "JavaScript"
	Local $Encode_URI = $oSC.Eval("decodeURI('" & $sString & "');")

	$oSC = 0

	Return $Encode_URI
EndFunc   ;==>_Encoding_URIDecode
$URLdec = StringRegExpReplace($Response, '<name>(.+?)</name>', '\1')
$name = _Encoding_URIDecode($URLdec)
 
Автор
C

CreatiK

Новичок
Сообщения
93
Репутация
4
Sp01LeR у меня выдало ошибку покажи на примере вот код в помощь
Код:
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>

Opt('MustDeclareVars', 1)
Opt('TrayIconDebug', 1)

Global $hGUI, $Input, $Button, $nMsg, $sMoney

$hGUI = GUICreate('My имя', 200, 90, -1, -1)
GUICtrlCreateLabel('Имя', 40, 5, 120, 20, $SS_CENTER)
$Input = GUICtrlCreateInput('', 60, 20, 80, 20, BitOR($ES_READONLY, $ES_CENTER))
$Button = GUICtrlCreateButton('Получить', 50, 50, 100, 25)
GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button
            GUISetState(@SW_DISABLE)
            GUICtrlSetData($Input, '')
            $sMoney = _My_Func()
            If $sMoney <> -1 Then
                GUICtrlSetData($Input, $sMoney)
            Else
                GUICtrlSetData($Input, 'Ошибка')
            EndIf
            GUISetState(@SW_ENABLE)
    EndSwitch
WEnd

Func _My_Func()
    Local $Response, $sMessage
    Local $Host = '109.234.155.196'
    If Not Ping($Host) Then Return -1
    Local $File = '/prison/universal.php?getInfo'
    Local $URL = 'http://' & $Host & $File
    Local $PostData = 'sig=5064ea55b0c410563fe3bd4dd23cd5c8&key=f91bca177f94e848e4d763332fbfd836&user=57292995&method=getInfo'
    Local $oHTTP = ObjCreate('WinHttp.WinHttpRequest.5.1')
    $oHTTP.Open('POST', $URL)
    $oHTTP.setTimeouts(5000, 5000, 10000, 10000)
    $oHTTP.SetRequestHeader('Content-Type', 'application/x-www-form-urlencoded')
    Execute('$oHTTP.Send($PostData)')
    If (@error) Or ($oHTTP.Status <> 200) Then
        Return -1
    Else
        $oHTTP.WaitForResponse
        $Response = $oHTTP.ResponseText
        If Not $Response Then Return -1
    EndIf
   $sMessage = StringRegExpReplace($Response, '<name>(.+?)</name>', '\1')
    If Not $sMessage Then Return -1
    Return $sMessage
EndFunc   ;==>_My_Func
 

Sp01LeR

Знающий
Сообщения
45
Репутация
12
Какую ошибку? Я не сижу в контакте и наврядли я пройду авторизу по твоим кукам...
 
Автор
C

CreatiK

Новичок
Сообщения
93
Репутация
4
Sp01LeR сказал(а):
Какую ошибку? Я не сижу в контакте и наврядли я пройду авторизу по твоим кукам...

тебе не надо авторизацию просто используй мой код если ты правельно составишь то у тебя получится моё имя в игре
 

Sp01LeR

Знающий
Сообщения
45
Репутация
12
Хм, эти обьекты такие обьекты...
Вроде это серв тупит, видать не только ты один его дидосишь ;D
Я там поставил уведомление в трей с номером ответа:
Код:
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>

Opt('MustDeclareVars', 1)
Opt('TrayIconDebug', 1)

Global $hGUI, $Input, $Button, $nMsg, $sMoney

$hGUI = GUICreate('My имя', 200, 90, -1, -1)
GUICtrlCreateLabel('Имя', 40, 5, 120, 20, $SS_CENTER)
$Input = GUICtrlCreateInput('', 60, 20, 80, 20, BitOR($ES_READONLY, $ES_CENTER))
$Button = GUICtrlCreateButton('Получить', 50, 50, 100, 25)
GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button
            GUISetState(@SW_DISABLE)
            GUICtrlSetData($Input, '')
            $sMoney = _My_Func()
            If $sMoney <> -1 Then
                GUICtrlSetData($Input, $sMoney)
            Else
                GUICtrlSetData($Input, 'Ошибка')
            EndIf
            GUISetState(@SW_ENABLE)
    EndSwitch
WEnd

Func _URLdecode_UTF($sData)
    ; Prog@ndy
    Local $aData = StringSplit(StringReplace($sData,"+"," ",0,1),"%")
    $sData = ""
    For $i = 2 To $aData[0]
        $aData[1] &= Chr(Dec(StringLeft($aData[$i],2))) & StringTrimLeft($aData[$i],2)
    Next
    Return BinaryToString(StringToBinary($aData[1],1),4)
EndFunc

Func _My_Func()
    Local $Response, $sMessage, $httprcode
    Local $Host = '109.234.155.196'
    If Not Ping($Host) Then Return -1
    Local $File = '/prison/universal.php?getInfo'
    Local $URL = 'http://' & $Host & $File
    Local $PostData = 'sig=5064ea55b0c410563fe3bd4dd23cd5c8&key=f91bca177f94e848e4d763332fbfd836&user=57292995&method=getInfo'
    Local $oHTTP = ObjCreate('WinHttp.WinHttpRequest.5.1')
    $oHTTP.Open('POST', $URL)
    $oHTTP.setTimeouts(5000, 5000, 10000, 10000)
    $oHTTP.SetRequestHeader('Content-Type', 'application/x-www-form-urlencoded')
    Execute('$oHTTP.Send($PostData)')
	 If (@error) Or ($oHTTP.Status <> 200) Then
        $httprcode=Execute('$oHTTP.Status')
		  TrayTip("Ошибка","Ответ сервера: "&$httprcode, 25, 3)
		  Return -1
    Else
        $oHTTP.WaitForResponse
        $Response = $oHTTP.ResponseText
        If Not $Response Then Return -1
    EndIf
	 ;MsgBox(0,"",$Response)
   $sMessage = StringRegExpReplace($Response, '(?s).+?<name>(.+?)</name>.+', '\1')
	 If Not $sMessage Then Return -1
    Return _URLdecode_UTF($sMessage)
EndFunc   ;==>_My_Func
 
Автор
C

CreatiK

Новичок
Сообщения
93
Репутация
4
А кто подскажет как сохранять Response в фаил Ini? возможо или нет
 
Автор
C

CreatiK

Новичок
Сообщения
93
Репутация
4
можешь по подробней вот запрос
Код:
$Host = "109.234.155.196"
$File = "/prison/universal.php?getInfo"
$URL = "http://" & $Host & $File
$PostData = "sig=5064ea55b0c410563fe3bd4dd23cd5c8&key=f91bca177f94e848e4d763332fbfd836&user=57292995&method=getInfo"
$oHTTP = ObjCreate("WinHttp.WinHttpRequest.5.1")
$oHTTP.Open("POST", $URL)
$oHTTP.SetRequestHeader("Content-Type","application/x-www-form-urlencoded")
$oHTTP.Send($PostData)
$oHTTP.WaitForResponse
$Response = $oHTTP.ResponseText
 

madmasles

Модератор
Глобальный модератор
Сообщения
7,790
Репутация
2,322
CreatiK
Попробуйте так:
Код:
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>

Opt('MustDeclareVars', 1)
Opt('TrayMenuMode', 1)

Global $hGUI, $Input, $Button1, $Button2, $nMsg, $sMessage, $iY = 18, _
		$iTime = 30 ;время в минутах между запросами.

Dim $aInfo[17][3] = [[16],['name'],['money'],['rating'],['diamond'],['booster_price'],['already_spin'], _
		['currentBackground'],['vote_points_count'],['energy'],['energy_ttu'],['energyForVote'], _
		['maxEnergyForVote'],['friends_invited'],['popularity'],['duel_price'],['duel_reward']]

$hGUI = GUICreate('My Info', 200, ($aInfo[0][0] + 1) * ($iY + 2) * 2, -1, -1)

For $i = 1 To $aInfo[0][0]
	GUICtrlCreateLabel('Значение ' & $aInfo[$i][0], 5, 10 + ($i - 1) * ($iY + 2) * 2, 190, $iY, $SS_CENTER)
	$aInfo[$i][1] = GUICtrlCreateInput('', 60, 25 + ($i - 1) * ($iY + 2) * 2, 80, $iY, BitOR($ES_READONLY, $ES_CENTER))
Next

$Button1 = GUICtrlCreateButton('Получить', 20, 10 + ($aInfo[0][0]) * ($iY + 2) * 2, 70, $iY + 2)
$Button2 = GUICtrlCreateButton('Сохранить', 110, 10 + ($aInfo[0][0]) * ($iY + 2) * 2, 70, $iY + 2)
GUISetState()

AdlibRegister('_My_Adlib', ($iTime * 60000))

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			AdlibUnRegister('_My_Adlib')
			GUISetState(@SW_DISABLE)
			$sMessage = _My_POST()
			If $sMessage <> -1 Then
				For $i = 1 To $aInfo[0][0]
					$aInfo[$i][2] = _My_StringRegExpReplace($sMessage, $aInfo[$i][0])
					If $aInfo[$i][2] Then
						GUICtrlSetData($aInfo[$i][1], $aInfo[$i][2])
					Else
						GUICtrlSetData($aInfo[$i][1], 'Ошибка')
					EndIf
				Next
			Else
				TrayTip('Запрос', 'Ошибка получения данных с сайта.', 10, 3)
			EndIf
			GUISetState(@SW_ENABLE)
			AdlibRegister('_My_Adlib', ($iTime * 60000))
		Case $Button2
			_My_Save()
	EndSwitch
WEnd

Func _My_POST()
	Local $Response
	Local $Host = '109.234.155.196'
	If Not Ping($Host) Then Return -1
	Local $File = '/prison/universal.php?getInfo'
	Local $URL = 'http://' & $Host & $File
	Local $PostData = 'sig=5064ea55b0c410563fe3bd4dd23cd5c8&key=f91bca177f94e848e4d763332fbfd836&user=57292995&method=getInfo'
	Local $oHTTP = ObjCreate('WinHttp.WinHttpRequest.5.1')
	$oHTTP.Open('POST', $URL)
	$oHTTP.setTimeouts(5000, 5000, 10000, 10000)
	$oHTTP.SetRequestHeader('Content-Type', 'application/x-www-form-urlencoded')
	Execute('$oHTTP.Send($PostData)')
	If (@error) Or ($oHTTP.Status <> 200) Then
		Return -1
	Else
		$oHTTP.WaitForResponse
		$Response = $oHTTP.ResponseText
		If Not $Response Then Return -1
	EndIf
	Return $Response
EndFunc   ;==>_My_POST

Func _URLdecode_UTF($sData)
	; Prog@ndy
	Local $aData = StringSplit(StringReplace($sData, "+", " ", 0, 1), "%")
	$sData = ""
	For $i = 2 To $aData[0]
		$aData[1] &= Chr(Dec(StringLeft($aData[$i], 2))) & StringTrimLeft($aData[$i], 2)
	Next
	Return BinaryToString(StringToBinary($aData[1], 1), 4)
EndFunc   ;==>_URLdecode_UTF

Func _My_StringRegExpReplace($sText, $sBetween)
	Local $sPattern, $sReturn, $iCheck
	If Not $sText Then Return 0
	If Not $sBetween Then Return 0
	Switch $sBetween
		Case 'name'
			$iCheck = 1
			$sPattern = '(?s).*?<' & $sBetween & '>(.*?)</' & $sBetween & '>?.*'
		Case Else
			$iCheck = 0
			$sPattern = '(?s).*?<' & $sBetween & '>(\d+)</' & $sBetween & '>?.*'
	EndSwitch
	$sReturn = StringRegExpReplace($sText, $sPattern, '\1')
	If Not $sReturn Then Return 0
	If $iCheck Then
		$sReturn = _URLdecode_UTF($sReturn)
	EndIf
	Return $sReturn
EndFunc   ;==>_My_StringRegExpReplace

Func _My_Save()
	Local $sINI_File = @ScriptDir & '\My.ini'
	Local $sSection = @MDAY & '_' & @MON & '_' & @YEAR & '-' & @HOUR & ':' & @MIN
	For $i = 1 To $aInfo[0][0]
		If Not IniWrite($sINI_File, $sSection, $aInfo[$i][0], $aInfo[$i][2]) Then
			Return 0
		EndIf
	Next
	Return 1
EndFunc   ;==>_My_Save

Func _My_Adlib()
	GUISetState(@SW_DISABLE)
	Local $sMes = _My_POST()
	If $sMes <> -1 Then
		For $i = 1 To $aInfo[0][0]
			$aInfo[$i][2] = _My_StringRegExpReplace($sMessage, $aInfo[$i][0])
			If $aInfo[$i][2] Then
				GUICtrlSetData($aInfo[$i][1], $aInfo[$i][2])
			Else
				GUICtrlSetData($aInfo[$i][1], 'Ошибка')
			EndIf
		Next
		_My_Save()
	EndIf
	GUISetState(@SW_ENABLE)
EndFunc   ;==>_My_Adlib
 
Верх