Что нового
Автор:
Фильтры

Проблема с использованием ресурса "шрифт"

S

saraconor

Новичок
Сообщения
404
Репутация
3
Попытка использовать данный пример http://autoit-script.ru/index.php?topic=2849.0#post_15 ни к чему не приводит. Шрифт не устанавливается почему-то, и текст остается Arial.
Что может быть не так?
Порывшись в справке вижу что функция _WinAPI_AddFontMemResourceEx использует MemFont.au3 - которого в Include найти не удалось. Может быть в этом проблема? Если так, то выложите пожалуйста сюда.
 
joiner

joiner

Модератор
Локальный модератор
Сообщения
3,556
Репутация
628
Код: 
#Region
#AutoIt3Wrapper_Res_File_Add=Still Time Cyr.ttf, 8, My_font
#EndRegion

#include <WinAPIEx.au3>
Local $hInstance = _WinAPI_LoadLibraryEx(@ScriptFullPath, $LOAD_LIBRARY_AS_DATAFILE)
_LoadResourceFont($hInstance, 8, 'My_font')
GUICreate('MyProg', 280, 100)
GUICtrlCreateLabel('qerty', 38, 23, 204, 54)
GUICtrlSetFont(-1, 30, 800, 0, 'Still Time Cyr');точное имя шрифта(обязательно)
GUICtrlSetColor(-1, 0xE00000)
GUISetState()

Do
Until GUIGetMsg() = -3

Func _LoadResourceFont($hInstance, $sResType, $sResName, $iResLanguage = 0)
	Local $hInfo, $hData, $pData, $iSize, $hFont
	If $iResLanguage Then
		$hInfo = _WinAPI_FindResourceEx($hInstance, $sResType, $sResName, $iResLanguage)
	Else
		$hInfo = _WinAPI_FindResource($hInstance, $sResType, $sResName)
	EndIf
	$hData = _WinAPI_LoadResource($hInstance, $hInfo)
	$iSize = _WinAPI_SizeOfResource($hInstance, $hInfo)
	$pData = _WinAPI_LockResource($hData)
	If @error Then
		Return SetError(1, 0, 0)
	EndIf
	$hFont = _WinAPI_AddFontMemResourceEx($pData, $iSize)
	If @error Then
		_WinAPI_FreeLibrary($hInstance)
		Return SetError(1, 0, 0)
	EndIf
	_WinAPI_FreeLibrary($hInstance)
	Return $hFont
EndFunc   ;==>_LoadResourceFont
 
joiner

joiner

Модератор
Локальный модератор
Сообщения
3,556
Репутация
628
это работа с ресурсами. а значит, код нужно компилировать
 

Вложения

  • Безымянный.jpg
    Безымянный.jpg
    10.2 КБ · Просмотры: 3
Автор
S

saraconor

Новичок
Сообщения
404
Репутация
3

Тоже самое в скомпилированном виде. В общем причина найдена: сделовало удалить символы _ из названия файла шрифта.
 
joiner

joiner

Модератор
Локальный модератор
Сообщения
3,556
Репутация
628
как можно без компиляции делать
Код: 
#Region
#AutoIt3Wrapper_Res_File_Add=Still Time Cyr.ttf, 8, My_font
#EndRegion

#include <WinAPIEx.au3>
Local $hInstance
If @Compiled Then
	$hInstance = _WinAPI_LoadLibraryEx(@ScriptFullPath, $LOAD_LIBRARY_AS_DATAFILE)
	_LoadResourceFont($hInstance, 8, 'My_font')
Else
	_WinAPI_AddFontResourceEx(@ScriptDir & '\Still Time Cyr.ttf', $FR_PRIVATE)
EndIf

GUICreate('MyProg', 280, 100)
GUICtrlCreateLabel('Привет всем', 38, 23, 204, 54)
GUICtrlSetFont(-1, 30, 800, 0, 'Still Time Cyr');точное имя шрифта(обязательно)
GUICtrlSetColor(-1, 0xE00000)
GUISetState()

Do
Until GUIGetMsg() = -3

Func _LoadResourceFont($hInstance, $sResType, $sResName, $iResLanguage = 0)
	Local $hInfo, $hData, $pData, $iSize, $hFont
	If $iResLanguage Then
		$hInfo = _WinAPI_FindResourceEx($hInstance, $sResType, $sResName, $iResLanguage)
	Else
		$hInfo = _WinAPI_FindResource($hInstance, $sResType, $sResName)
	EndIf
	$hData = _WinAPI_LoadResource($hInstance, $hInfo)
	$iSize = _WinAPI_SizeOfResource($hInstance, $hInfo)
	$pData = _WinAPI_LockResource($hData)
	If @error Then
		Return SetError(1, 0, 0)
	EndIf
	$hFont = _WinAPI_AddFontMemResourceEx($pData, $iSize)
	If @error Then
		Return SetError(1, 0, 0)
	EndIf
	Return $hFont
EndFunc   ;==>_LoadResourceFont
 
Вам необходимо войти или зарегистрироваться, чтобы здесь отвечать.
Автор темы Похожие темы Форум Ответы Дата
H Проблема при запуске скрипта - IPD.HELU.AutoIt11 Общие вопросы по AutoIt 2
M Проблема с активным окном Общие вопросы по AutoIt 2
R Мышь, клавиатура Проблема с использованием ^w в качестве горячей клавиши Общие вопросы по AutoIt 2
R [Файловая система] Проблема с использованием _FileWriteFromArray Общие вопросы по AutoIt 3
G [Perfect World] Проблема в написании бота с использованием PWGTM и PWmp. Боты для игр 9
Похожие темы
Проблема при запуске скрипта - IPD.HELU.AutoIt11
Проблема с активным окном
Мышь, клавиатура Проблема с использованием ^w в качестве горячей клавиши
[Файловая система] Проблема с использованием _FileWriteFromArray
[Perfect World] Проблема в написании бота с использованием PWGTM и PWmp.
Верх