Автор Тема: Найти и удалить и заменит  (Прочитано 12538 раз)

0 Пользователей и 1 Гость просматривают эту тему.

Оффлайн StarEdik [?]

  • Благодарен всем за поддержку
  • Новичок
  • *
  • Сообщений: 365
  • Репутация: 4
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.12.0
Найти и удалить и заменит
« Создано: Август 20, 2011, 18:45:49 »
Версия AutoIt: 3.3.6.1

Описание:
Привет и спасибо всем отзывающимся.
Проблема такая. Вместе со скриптом  имеется папка  DefaultData.А в этой папке имеются еше 2 папки Default1 и Default2 и в каждом из этих папок  лежит файл Version.txt. В Default1 файл без изменения а в Default2 файл с измененными настройками.
Нужен скрипт  который должен
       При запуске
1.Найти и удалить  C:\...\ initializeData.log   файл.
2.Найти и заменит C:\...\ Version.txt  на  файл (@ScriptDir & "\ DefaultData\ Default2\ Version.txt  ")

      При завершении
1.Найти и заменит C:\...\ Version.txt  на  файл  (@ScriptDir & "\  DefaultData\ Default1\ Version.txt  ")

 Примечания:

 Файлы находятся в корневом диске С:\ (точный путь не известен)

 
« Последнее редактирование: Август 20, 2011, 18:53:12 от StarEdik »
Скорблю и помню.

Знать одно, но знать и помогать не каждому дано.
ОН всегда всем помогал. Сделал добро и ушел, но остался в памяти у многих

Русское сообщество AutoIt

Найти и удалить и заменит
« Отправлен: Август 20, 2011, 18:45:49 »

Оффлайн madmasles [?]

  • Глобальный модератор
  • *
  • Сообщений: 7790
  • Репутация: 2317
  • Пол: Мужской
  • Награды За модерирование форума
    • Награды
  • Версия AutoIt: 3.3.x.x
Re: Найти и удалить и заменит
« Ответ #1, Отправлен: Август 20, 2011, 19:14:24 »
StarEdik  [?]
Цитировать
При запуске...
При завершении
1. При запуске скрипта или системы?
2. При завершении скрипта (если да, то как и когда он должен завершиться) или системы?
3. Я у себя на диске C:\ нашел три файла Version.txt. Как скрипт должен определить, какой из них менять?

Оффлайн StarEdik [?]

  • Благодарен всем за поддержку
  • Новичок
  • *
  • Сообщений: 365

  • Автор темы
  • Репутация: 4
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Найти и удалить и заменит
« Ответ #2, Отправлен: Август 20, 2011, 20:55:41 »
madmasles  [?]
Цитировать
1. При запуске скрипта или системы?
Скрипт запускаю сам.Так что - При запуске скрипта
Цитировать
2. При завершении скрипта (если да, то как и когда он должен завершиться) или системы?
Я сам звершаю выполнения скрипта
Цитировать
3. Я у себя на диске C:\ нашел три файла Version.txt. Как скрипт должен определить, какой из них менять?

Всё что найдет пусть заменяет


Оффлайн Zaramot [?]

  • AutoIt Гуру
  • *****
  • Сообщений: 1160
  • Репутация: 655
  • Пол: Мужской
  • I ♥ AutoIt
    • Награды
  • Версия AutoIt: 3.3.8.1
Re: Найти и удалить и заменит
« Ответ #3, Отправлен: Август 20, 2011, 21:17:21 »
Не знаю разберёшся ты или нет, но вот  ;D:
(нажмите для показа/скрытия)
« Последнее редактирование: Август 21, 2011, 18:57:56 от Zaramot »

Русское сообщество AutoIt

Re: Найти и удалить и заменит
« Ответ #3 Отправлен: Август 20, 2011, 21:17:21 »

Оффлайн StarEdik [?]

  • Благодарен всем за поддержку
  • Новичок
  • *
  • Сообщений: 365

  • Автор темы
  • Репутация: 4
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Найти и удалить и заменит
« Ответ #4, Отправлен: Август 20, 2011, 21:52:30 »
Zaramot  [?]
Цитировать
Не знаю разберёшся ты или нет
Спасибо Огромное.После такой доскональности Постараюсь понят.
 И вот еше.
Если  прогу  запускаю с помощью  скрипта программа  запускается с моими настройками, а так с настройками по умолчанию.Тепер скрипт  должен изменит настройки а потом запустить программу на выполнения

Оффлайн Zaramot [?]

  • AutoIt Гуру
  • *****
  • Сообщений: 1160
  • Репутация: 655
  • Пол: Мужской
  • I ♥ AutoIt
    • Награды
  • Версия AutoIt: 3.3.8.1
Re: Найти и удалить и заменит
« Ответ #5, Отправлен: Август 20, 2011, 22:01:28 »
StarEdik, что за настройки ?  :blink:

После выполнения 1 и 2 пункта он должен запустить некую программу ?

Оффлайн StarEdik [?]

  • Благодарен всем за поддержку
  • Новичок
  • *
  • Сообщений: 365

  • Автор темы
  • Репутация: 4
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Найти и удалить и заменит
« Ответ #6, Отправлен: Август 21, 2011, 11:42:50 »
Zaramot  [?]
Цитировать
После выполнения 1 и 2 пункта он должен запустить некую программу ?
Да.
И вот ,скрипт выдает ошибку
ERROR: FileDelete() [built-in] called with wrong number of args.
        FileDelete('InitializeData.log', $Search1[$i], 1)
Error:Incorrect number of parameters in function call.

При нажатии CTRL + Q для выхода скрипт не завершает свою работу
« Последнее редактирование: Август 21, 2011, 12:15:53 от StarEdik »

Оффлайн madmasles [?]

  • Глобальный модератор
  • *
  • Сообщений: 7790
  • Репутация: 2317
  • Пол: Мужской
  • Награды За модерирование форума
    • Награды
  • Версия AutoIt: 3.3.x.x
Re: Найти и удалить и заменит
« Ответ #7, Отправлен: Август 21, 2011, 12:06:13 »
StarEdik
скрипт выдает ошибку
Поменяйте
Код: AutoIt [Выделить]
FileDelete('InitializeData.log', $Search1[$i], 1);Zaramot ???
;на
FileDelete($Search1[$i])


Русское сообщество AutoIt

Re: Найти и удалить и заменит
« Ответ #7 Отправлен: Август 21, 2011, 12:06:13 »

Оффлайн StarEdik [?]

  • Благодарен всем за поддержку
  • Новичок
  • *
  • Сообщений: 365

  • Автор темы
  • Репутация: 4
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Найти и удалить и заменит
« Ответ #8, Отправлен: Август 21, 2011, 12:35:51 »
madmasles
Спасибо Получилось.
Но есть одно Но.Если я запускаю скрипт с диска С где он находится вместе с файлами  то эти файлы тоже заменяются.Думаю файлы в папке должны быть под другими именами , ну например Version_1.txt  и  Version_2.txt .А при замене должны сохранятся с именами Version.txt .Как сделать это.
И как после этой процедуры запустит прогамму DataRef.exe
А при завершение (закрытии ) программы DataRef.exe завершить работу скрипта
« Последнее редактирование: Август 21, 2011, 12:42:20 от StarEdik »

Оффлайн Zaramot [?]

  • AutoIt Гуру
  • *****
  • Сообщений: 1160
  • Репутация: 655
  • Пол: Мужской
  • I ♥ AutoIt
    • Награды
  • Версия AutoIt: 3.3.8.1
Re: Найти и удалить и заменит
« Ответ #9, Отправлен: Август 21, 2011, 12:40:58 »
Цитировать
И вот ,скрипт выдает ошибку
ERROR: FileDelete() [built-in] called with wrong number of args.
        FileDelete('InitializeData.log', $Search1[$i], 1)
Error:Incorrect number of parameters in function call.

При нажатии CTRL + Q для выхода скрипт не завершает свою работу

Исправил.

Цитировать
И как после этой процедуры запустит прогамму DataRef.exe
А при завершение (закрытии ) программы DataRef.exe завершить работу скрипта

Исправил.

P.S. А если перед пунктом 1, скопировать  Version_1.txt  и  Version_2.txt в другой диск, а по завершению скопировать обратно ?
« Последнее редактирование: Август 21, 2011, 12:50:28 от Zaramot »

Оффлайн StarEdik [?]

  • Благодарен всем за поддержку
  • Новичок
  • *
  • Сообщений: 365

  • Автор темы
  • Репутация: 4
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Найти и удалить и заменит
« Ответ #10, Отправлен: Август 21, 2011, 12:49:44 »
madmasles
Zaramot

Если я запускаю скрипт с диска С где он находится вместе с файлами  то эти файлы тоже заменяются.Думаю файлы в папке должны быть под другими именами , ну например Version_1.txt  и  Version_2.txt .А при замене должны сохранятся с именем Version.txt  .Как сделать это.
« Последнее редактирование: Август 21, 2011, 12:58:00 от StarEdik, Причина: Объединение сообщений »

Оффлайн Zaramot [?]

  • AutoIt Гуру
  • *****
  • Сообщений: 1160
  • Репутация: 655
  • Пол: Мужской
  • I ♥ AutoIt
    • Награды
  • Версия AutoIt: 3.3.8.1
Re: Найти и удалить и заменит
« Ответ #11, Отправлен: Август 21, 2011, 12:59:42 »
Цитировать
Если я запускаю скрипт с диска С где он находится вместе с файлами  то эти файлы тоже заменяются.Думаю файлы в папке должны быть под другими именами , ну например Version_1.txt  и  Version_2.txt .А при замене должны сохранятся с именем Version.txt  .Как сделать это.
Исправил. Первое что делает скрипт, это копирует папку DefaultData в диск D:\ (если что - замени). А по завершению копирует её обратно.

Можно ещё записать инфо. из файлов Version.txt в переменные, а по завершению записать их назад:
Код: AutoIt [Выделить]
HotKeySet('^q', '_OnExit');CTRL + Q для выхода

$Read1 = FileRead(@ScriptDir & '\DefaultData\Default1\Version.txt') ;Записываем текст из файла Default1\Version.txt в переменныю
$Read2 = FileRead(@ScriptDir & '\DefaultData\Default2\Version.txt') ;Записываем текст из файла Default2\Version.txt в переменныю

;1)Найти и удалить  C:\...\ initializeData.log   файл.
$Search1 = _FileSearch("C:", "InitializeData.log", 1)   ;Ищет файл initializeData.log в диске C:

If $Search1[0] = 0 Then    ;Если не найден не один файл, то...
    MsgBox(64, 'Ошибка', 'Файл не найдет')
Else    ;Если найден(ы) файл(ы), то...
    For $i = 1 To $Search1[0]
        FileDelete($Search1[$i]) ;Удаляет все найденные файлы InitializeData.log
    Next
EndIf

;2)Найти и заменит C:\...\ Version.txt  на  файл (@ScriptDir & "\ DefaultData\ Default2\ Version.txt  ")
$Search2 = _FileSearch("C:", "Version.txt", 1)   ;Ищет файл Version.txt в диске C:

If $Search2[0] = 0 Then    ;Если не найден не один файл, то...
    MsgBox(64, 'Ошибка', 'Файл не найдет')
Else    ;Если найден(ы) файл(ы), то...
    For $j = 1 To $Search2[0]
        FileCopy(@ScriptDir & "\DefaultData\Default2\Version.txt", $Search2[$j], 1) ;Заменяет все найденные файлы Version.txt на @ScriptDir & "\DefaultData\Default2\Version.txt"
    Next
EndIf

Run(@ScriptDir & '\DataRef.exe') ;Запускаем программу

While 1
    If Not ProcessExists('DataRef.exe') Then _OnExit() ;Если закрыть программу DataRef.exe
    Sleep(100)
WEnd

;3)Найти и заменит C:\...\ Version.txt  на  файл  (@ScriptDir & "\  DefaultData\ Default1\ Version.txt  ")
Func _OnExit() ;Функция для завершения
    $Search3 = _FileSearch("C:", "Version.txt", 1)   ;Ищет файл Version.txt в диске C:

    If $Search3[0] = 0 Then    ;Если не найден не один файл, то...
        MsgBox(64, 'Ошибка', 'Файл не найдет')
    Else    ;Если найден(ы) файл(ы), то...
        For $h = 1 To $Search3[0]
            FileCopy(@ScriptDir & '\DefaultData\Default1\Version.txt', $Search3[$h], 1) ;Заменяет все найденные файлы Version.txt на @ScriptDir & '\DefaultData\Default1\Version.txt'
        Next
    EndIf

    ;Удаляем файлы Version.txt из папок Default1 и Default2
    FileDelete(@ScriptDir & '\DefaultData\Default1\Version.txt')
    FileDelete(@ScriptDir & '\DefaultData\Default2\Version.txt')
   
    Sleep(100)
   
    ;Сохраняет (создаёт) файлы Version.txt в папках Default1 и Default2
    FileWrite(@ScriptDir & '\DefaultData\Default1\Version.txt', $Read1)
    FileWrite(@ScriptDir & '\DefaultData\Default2\Version.txt', $Read2)
    Exit
EndFunc

;Функция для поиска файла
Func _FileSearch($sPath, $sFileMask, $iFlag = 0)
    Local $sOutBin, $sOut, $aOut, $sRead, $hDir, $sAttrib

    Switch $iFlag
        Case 1
            $sAttrib = ' /A-D'
        Case 2
            $sAttrib = ' /AD'
        Case Else
            $sAttrib = ' /A'
    EndSwitch

    $sOut = StringToBinary('0' & @CRLF, 2)
    $aMasks = StringSplit($sFileMask, ';')

    For $i = 1 To $aMasks[0]
        $hDir = Run(@ComSpec & ' /U /C DIR "' & $sPath & '\' & $aMasks[$i] & '" /S /B' & $sAttrib, @SystemDir, @SW_HIDE, 6)

        While 1
            $sRead = StdoutRead($hDir, False, True)

            If @error Then
                ExitLoop
            EndIf

            If $sRead <> "" Then
                $sOut &= $sRead
            EndIf
        Wend
    Next

    $aOut = StringRegExp(BinaryToString($sOut, 2), '[^\r\n]+', 3)

    If @error Then
        Return SetError(1)
    EndIf

    $aOut[0] = UBound($aOut)-1

    Return $aOut
 EndFunc

« Последнее редактирование: Август 21, 2011, 13:30:13 от Zaramot »

Оффлайн madmasles [?]

  • Глобальный модератор
  • *
  • Сообщений: 7790
  • Репутация: 2317
  • Пол: Мужской
  • Награды За модерирование форума
    • Награды
  • Версия AutoIt: 3.3.x.x
Re: Найти и удалить и заменит
« Ответ #12, Отправлен: Август 21, 2011, 13:35:38 »
StarEdik,
Мой вариант:
Код: AutoIt [Выделить]
Opt('TrayMenuMode', 1)
Opt('MustDeclareVars', 1)

Global $sTitleScript = @ScriptName & '{[/@[email protected]\]}', $iPID, $sProg = @ScriptDir & '\DataRef.exe'

If WinExists($sTitleScript) Then Exit
AutoItWinSetTitle($sTitleScript)

_WinAPI_LoadKeyboardLayoutEx()
_OnStart()
HotKeySet('^q', '_OnExit');CTRL + Q для выхода
If FileExists($sProg) Then
    $iPID = Run($sProg)
EndIf
AdlibRegister('_Look', 2000)
While 1
    Sleep(500)
WEnd

Func _Look()
    If Not ProcessExists($iPID) Then
        _OnExit()
    EndIf
EndFunc   ;==>_Look

Func _OnStart()
    Local $s_Dir = @HomeDrive, $a_Search, $s_FileCopy = 'Version.txt', $s_FileDel = 'initializeData.log', _
            $s_NoSearch = @ScriptDir & '\DefaultData', _
            $s_Source = @ScriptDir & '\DefaultData\Default2\' & $s_FileCopy, $i_CountCopy = 0, $i_ErrorCopy, _
            $i_CountDel = 0, $i_ErrorDel, $s_Search, $s_Title = 'Поиск и замена Start'

    If Not FileExists($s_Source) Then
        $s_Search = $s_FileDel
        TrayTip($s_Title, 'Отсутствует файл для замены', 5, 3)
        Sleep(5000)
        TrayTip('', '', 0)
    Else
        $s_Search = $s_FileDel & ';' & $s_FileCopy
    EndIf
    $a_Search = _FileSearch($s_Dir, $s_Search, 1)
    If @error Then
        TrayTip($s_Title, 'Ошибка поиска файлов', 5, 3)
        Sleep(5000)
        TrayTip('', '', 0)
        Return
    EndIf
    If $a_Search[0] Then
        For $i = 1 To $a_Search[0]
            If StringInStr($a_Search[$i], $s_FileDel) Then
                If FileDelete($a_Search[$i]) Then
                    $i_CountDel += 1
                Else
                    $i_ErrorDel += 1
                EndIf
            Else
                If Not StringInStr($a_Search[$i], $s_NoSearch) Then
                    If FileCopy($s_Source, $a_Search[$i], 1) Then
                        $i_CountCopy += 1
                    Else
                        $i_ErrorCopy += 1
                    EndIf
                EndIf
            EndIf
        Next
    EndIf
    If $i_ErrorDel Or $i_ErrorCopy Then
        TrayTip($s_Title, 'Заменено файлов ' & $s_FileCopy & ': ' & $i_CountCopy & @LF & _
                'Не удалось заменить файлов ' & $s_FileCopy & ': ' & $i_ErrorCopy & _
                'Удалено файлов ' & $s_FileDel & ': ' & $i_CountDel & @LF & _
                'Не удалось удалить файлов ' & $s_FileDel & ': ' & $i_ErrorDel, 5, 2)
    Else
        If $i_CountCopy Or $i_CountDel Then
            TrayTip($s_Title, 'Заменено файлов ' & $s_FileCopy & ': ' & $i_CountCopy & @LF & _
                    'Удалено файлов ' & $s_FileDel & ': ' & $i_CountDel, 5, 1)
        Else
            TrayTip($s_Title, 'Не найдены файлы для замены и удаления', 5, 3)
        EndIf
    EndIf
    Sleep(5000)
    TrayTip('', '', 0)
    Return
EndFunc   ;==>_OnStart

Func _OnExit()
    Local $s_Dir = @HomeDrive, $a_Search, $s_File = 'Version.txt', _
            $s_NoSearch = @ScriptDir & '\DefaultData', _
            $s_Source = @ScriptDir & '\DefaultData\Default1\' & $s_File, $i_Count, $i_Error, _
            $s_Title = 'Поиск и замена Exit'

    AdlibUnRegister('_Look')
    If Not FileExists($s_Source) Then
        TrayTip($s_Title, 'Отсутствует файл для замены', 5, 3)
        Sleep(5000)
        Exit
    EndIf
    $a_Search = _FileSearch($s_Dir, $s_File, 1)
    If @error Then
        TrayTip($s_Title, 'Ошибка поиска файлов ' & $s_File, 5, 3)
        Sleep(5000)
        Exit
    EndIf
    If $a_Search[0] Then
        For $i = 1 To $a_Search[0]
            If Not StringInStr($a_Search[$i], $s_NoSearch) Then
                If FileCopy($s_Source, $a_Search[$i], 1) Then
                    $i_Count += 1
                Else
                    $i_Error += 1
                EndIf
            EndIf
        Next
    EndIf
    If $i_Error Then
        TrayTip($s_Title, 'Заменено файлов ' & $s_File & ': ' & $i_Count & @LF & _
                'Не удалось заменить файлов ' & $s_File & ': ' & $i_Error, 5, 2)
    Else
        If $i_Count Then
            TrayTip($s_Title, 'Заменено файлов ' & $s_File & ': ' & $i_Count, 5, 1)
        Else
            TrayTip($s_Title, 'Не найдены файлы для замены', 5, 3)
        EndIf
    EndIf
    Sleep(5000)
    Exit
EndFunc   ;==>_OnExit

Func _FileSearch($s_Path_Search, $s_File_Mask = '*', $i_Flag = 0, $i_SubDir = 1)
    ;фильтры для поиска нужно указывать через ;
    ;$i_Flag = 0 - Файлы и папки (по умолчанию)
    ;$i_Flag = 1 - Только файлы
    ;$i_Flag = 2 - Только папки (если ищем конкретную папку, то надо добавлять к имени * в начало  или в конец)
    ;$i_SubDir = 1 - Искать во всех подкаталогах (по умолчанию). Возвращает полные пути.
    ;$i_SubDir = 0 - Искать только в самой папке. Возвращает только имена файлов(папок).
    Local $s_Out, $a_Out, $s_Read, $h_Dir, $s_Attrib, $s_Subdir, $a_Masks

    If StringRight($s_Path_Search, 1) == '\' Then ;нужно, если $s_Path_Search - диск (например C:\)
        $s_Path_Search = StringTrimRight($s_Path_Search, 1)
    EndIf
    If $i_SubDir Then
        $s_Subdir = ' /S /B'
    Else
        $s_Subdir = ' /B'
    EndIf
    Switch $i_Flag
        Case 1
            $s_Attrib = ' /A-D'
        Case 2
            $s_Attrib = ' /AD'
        Case Else
            $s_Attrib = ' /A'
    EndSwitch
    $s_Out = StringToBinary('0' & @CRLF, 2)
    $a_Masks = StringSplit($s_File_Mask, ';')
    For $i = 1 To $a_Masks[0]
        $h_Dir = Run(@ComSpec & ' /U /C DIR "' & $s_Path_Search & '\' & $a_Masks[$i] & '"' & $s_Subdir & $s_Attrib, @SystemDir, @SW_HIDE, 6)
        If Not $h_Dir Then Return SetError(1)
        While 1
            $s_Read = StdoutRead($h_Dir, False, True)
            If @error Then
                ExitLoop
            EndIf
            If $s_Read Then
                $s_Out &= $s_Read
            EndIf
            Sleep(10)
        WEnd
    Next
    $a_Out = StringRegExp(BinaryToString($s_Out, 2), '[^\r\n]+', 3)
    If @error Then Return SetError(1)
    $a_Out[0] = UBound($a_Out) - 1
    Return $a_Out
EndFunc   ;==>_FileSearch

Func _WinAPI_LoadKeyboardLayoutEx($sLayoutID = 0x0409, $hWnd = 0)
    ;CreatoR, http://autoit-script.ru/index.php/topic,5745.0.html
    Local Const $WM_INPUTLANGCHANGEREQUEST = 0x50
    Local $aRet = DllCall('user32.dll', 'long', 'LoadKeyboardLayoutW', 'wstr', Hex($sLayoutID, 8), 'int', 0)
    If Not @error And $aRet[0] Then
        If $hWnd = 0 Then
            $hWnd = WinGetHandle(AutoItWinGetTitle())
        EndIf
        DllCall('user32.dll', 'ptr', 'SendMessage', 'hwnd', $hWnd, 'int', $WM_INPUTLANGCHANGEREQUEST, 'int', 1, 'int', $aRet[0])
        Return 1
    EndIf
    Return SetError(1)
EndFunc   ;==>_WinAPI_LoadKeyboardLayoutEx

« Последнее редактирование: Август 21, 2011, 18:37:43 от madmasles »

Оффлайн StarEdik [?]

  • Благодарен всем за поддержку
  • Новичок
  • *
  • Сообщений: 365

  • Автор темы
  • Репутация: 4
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Найти и удалить и заменит
« Ответ #13, Отправлен: Август 21, 2011, 17:51:17 »
madmasles
Zaramot

Просто нет слов.Ну очень впечатлительно. :)Большое и огромное вам спасибо.Сейчас проверю скрипт .А на последок хотелось бы узнать.
Как то можно папку DefaultData с субпапками и файлами вшить  в скрипт (в ехе).Если да то в скрипте будут какие ни будь изменения



Добавлено: Август 21, 2011, 18:31:15
madmasles
скрипт файл InitializeData.log не удалил и завершил свою работу не заменяя файл Version.txt

Zaramot
Копирование  папки DefaultData в локальный диск D не происходить.
« Последнее редактирование: Август 21, 2011, 18:31:15 от StarEdik, Причина: Объединение сообщений »

Оффлайн madmasles [?]

  • Глобальный модератор
  • *
  • Сообщений: 7790
  • Репутация: 2317
  • Пол: Мужской
  • Награды За модерирование форума
    • Награды
  • Версия AutoIt: 3.3.x.x
Re: Найти и удалить и заменит
« Ответ #14, Отправлен: Август 21, 2011, 18:39:46 »
StarEdik  [?]
Цитировать
скрипт файл InitializeData.log не удалил и завершил свою работу не заменяя файл Version.txt
Значит Вы не все говорите, я свой скрипт тестрировал.

Русское сообщество AutoIt

Re: Найти и удалить и заменит
« Ответ #14 Отправлен: Август 21, 2011, 18:39:46 »

 

Похожие темы

  Тема / Автор Ответов Последний ответ
18 Ответов
12039 Просмотров
Последний ответ Март 03, 2011, 01:10:17
от Kaster
14 Ответов
15394 Просмотров
Последний ответ Март 03, 2011, 15:04:44
от berkut9737
5 Ответов
3796 Просмотров
Последний ответ Январь 25, 2012, 15:52:37
от CreatoR
5 Ответов
3089 Просмотров
Последний ответ Апрель 19, 2012, 00:34:43
от madmasles
14 Ответов
5937 Просмотров
Последний ответ Август 04, 2012, 09:44:56
от CreatoR
6 Ответов
3756 Просмотров
Последний ответ Август 04, 2012, 10:41:35
от joiner
2 Ответов
2600 Просмотров
Последний ответ Март 12, 2013, 21:10:48
от StarEdik
5 Ответов
3226 Просмотров
Последний ответ Февраль 09, 2014, 07:25:06
от gregaz
4 Ответов
1243 Просмотров
Последний ответ Февраль 28, 2016, 16:18:36
от dr.room
3 Ответов
1052 Просмотров
Последний ответ Март 16, 2016, 23:18:20
от InnI