Помогите настроить так,чтобы по часам в скрипте происходило нажатие на клавишу

#include <GUIConstantsEx.au3> ; Включение указанного файла внутрь текущего сценария.
  ;- Окно ------------------------------
  GUICreate("Часы", 155, 111, 192, 114)
  GUISetState()
  ;-------------------------------------
  ;- Часы -------------------------------------------------------------
  AdlibRegister("MainScript", 10) ; Обновление часов
  $Clock = GUICtrlCreateLabel(@HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC, 50, 20)
  ;--------------------------------------------------------------------
  ;- Настройки ---------------------
  While 1
      $nMsg = GUIGetMsg()
      Switch $nMsg
          Case $GUI_EVENT_CLOSE
              Exit
      EndSwitch
  WEnd
  ;---------------------------------
  ;- Сверка часов с компьютером -----------------------------
  Func MainScript()
      GUICtrlSetData($Clock, @HOUR & ":" & @MIN & ":" & @SEC& ":" & @MSEC)
   EndFunc
  ;------------------------------------------------------------

sleep(5000)
While 1
   if (@HOUR = 13) and  (@MIN= 00) and  (@SEC= 59)  Then   
   Sleep(1000)  
   Send("{PRINTSCREEN}")
   Sleep(1000)
   Endif
   Sleep(10)
WEnd

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <ScreenCapture.au3>
#include <Array.au3>
#include <Date.au3>

Global $sNTP = 'ntp1.stratum2.ru' ; Сервер NTP
Global $iTimeInterval = 300 ; Интервал обновления времени в миллисекундах
Global $vDateTime = '2016/07/29 20:46:10' ; Время создания скриншотА (формат ГГГ/MM/ДД чч:мм:сс:мсс)
Global $sDir = @ScriptDir ; Папка для скриншотов
Global $iTimePrev, $iScrTime

$aDT = StringRegExp($vDateTime, '(\d{4})/(\d{2})/(\d{2})\h(\d{2}):(\d{2}):(\d{2})', 3)
If @error Or UBound($aDT) <> 6 Then Exit MsgBox(4096+16, 'Ошибка!', 'Задайте правильно время создания скриншота.')
$vDateTime = Number(_ArrayToString($aDT, ''))

Global $hGui = GUICreate("Часы", 155, 111, -1, -1, -1, $WS_EX_TOPMOST)
AdlibRegister("MainScript", $iTimeInterval) ; Обновление часов
$Clock = GUICtrlCreateLabel(@HOUR & ":" & @MIN & ":" & @SEC, 50, 20)
GUISetState()

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
	If $iScrTime >= $vDateTime Then
		_ScreenCapture_CaptureWnd($sDir & '\My_Screen[' & $iScrTime & '].jpg', $hGui)
		$vDateTime *= 2
	EndIf
WEnd

Func MainScript()
	Local $aFT, $sTime, $tFT = _NTP_FT($sNTP)
	If Not @error Then
		$aFT = _Date_Time_FileTimeToArray($tFT)
		If UBound($aFT) >= 6 Then
			$sTime = StringFormat('%02d:%02d:%02d', $aFT[3], $aFT[4], $aFT[5])
			If $sTime <> $iTimePrev Then
				GUICtrlSetData($Clock, $sTime)
				$iTimePrev = $sTime
			EndIf
			$iScrTime = Number(StringFormat('%04d%02d%02d%02d%02d%02d', $aFT[2], $aFT[0], $aFT[1], $aFT[3], $aFT[4], $aFT[5]))
		EndIf
	EndIf
EndFunc   ;==>MainScript

Func _NTP_FT($sServer, $fLocal = True) ; Параметр $fLocal:	True - возвращается локальное время
;~															False - возвращается время UTC
	
;~ 	Тема: http://autoit-script.ru/index.php?topic=20487.0
;~ 	Справка: http://book.itep.ru/4/44/sntp4416.htm

	Local $tNTP = DllStructCreate('byte Header[4];byte RootDelay[4];byte RootDispersion[4];byte ReferenceIdentifier[4];byte ReferenceTimestamp[8];byte OriginateTimestamp[8];byte ReceiveTimestamp[8];byte TransmitTimestamp[8];byte KeyIdentifier[4];byte MessageDigest[16]')
	Local $tPacket = DllStructCreate('byte Packet[68]', DllStructGetPtr($tNTP))
	Local $bPacket = 0, $tFT, $tQW, $aSocket, $aResult

	$tNTP.Header = Binary('0x1B000000')
	UDPStartup()
	If @error Then Return SetError(1, 0, 0)

	$aSocket = UDPOpen(TCPNameToIP($sServer), 123)
	If Not @error Then
		UDPSend($aSocket, $tPacket.Packet)
		If Not @error Then
			While 1
				$bPacket = UDPRecv($aSocket, 68, 1)
				If (@error) Or ($bPacket) Then ExitLoop
				Sleep(100)
			WEnd
		EndIf
	EndIf
	
	UDPCloseSocket($aSocket)
	UDPShutdown()
	If Not $bPacket Then Return SetError(2, 0, 0)

	$tFT = DllStructCreate($tagFILETIME)
	$tQW = ($fLocal ? DllStructCreate('uint64 Timestamp') : DllStructCreate('uint64 Timestamp', DllStructGetPtr($tFT)))
	
	$tPacket.Packet = $bPacket
;~  $tQW.Timestamp = _WinAPI_SwapDWord(DllStructGetData(DllStructCreate('uint', DllStructGetPtr($tNTP, 'TransmitTimestamp')), 1)) * 10000000 + 94354848000000000
	$tQW.Timestamp = Dec(StringMid(DllStructGetData($tNTP, 'TransmitTimestamp'), 3, 8), 2) * 10000000 + 94354848000000000
	If $fLocal Then
		$aResult = DllCall('kernel32.dll', 'bool', 'FileTimeToLocalFileTime', 'struct*', $tQW, "struct*", $tFT)
		If (@error) Or (Not $aResult[0]) Then Return SetError(3, 0, 0)
	EndIf
	Return $tFT
EndFunc   ;==>_NTP_FT

_ScreenCapture_CaptureWnd($sDir & '\My_Screen[' & $iScrTime & '].jpg', $hGui)

$hWnd = WinGetHandle('[ACTIVE]')
_ScreenCapture_CaptureWnd($sDir & '\My_Screen[' & $iScrTime & '].jpg', $hWnd)

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

Local $sNTP = 'ntp1.stratum2.ru' ; Сервер NTP
Local $vDateTime = '23:32:20:333' ; Время нажатия "Enter" (формат чч:мм:сс:мсс)

$aDT = StringRegExp($vDateTime, '(\d{2}):(\d{2}):(\d{2}):(\d{3})', 3)
If @error Or UBound($aDT) <> 4 Then Exit MsgBox(4096 + 16, 'Ошибка!', 'Задайте правильно время.')
$vDateTime = Number(_ArrayToString($aDT, ''))

Local $hGui = GUICreate("Часы", 155, 111, -1, -1, -1, $WS_EX_TOPMOST)
Local $Clock = GUICtrlCreateLabel(@HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC, 50, 20)
GUISetState()

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
	
	If $vDateTime Then
		$iScrTime = Number(@HOUR & @MIN & @SEC & @MSEC)
		GUICtrlSetData($Clock, @HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC)
		If $vDateTime < $iScrTime Then
			Send('{ENTER}')
			GUICtrlSetColor($Clock, 0xFF0004)
			SoundPlay(@WindowsDir & '\media\tada.wav')
			$vDateTime = False
		EndIf
	Else
		Sleep(20)
	EndIf
WEnd

#include <GUIConstants.au3>
#include <DateTimeConstants.au3>

Opt('TrayMenuMode', 3)

Local $sTimeText, $sSleepText, $iTrigger = False
Local $hGui, $hTime, $hSleep, $Button_1, $Button_2, $hTrayItem_1, $hTrayItem_2

$hGui = GUICreate('', 189, 222)

GUICtrlCreateLabel('Время', 64, 16, 37, 17)
GUICtrlCreateLabel('Задержка', 64, 80, 55, 17)
$hTime = GUICtrlCreateDate('', 45, 40, 95, 25, $DTS_TIMEFORMAT)
GUICtrlSetFont(-1, 11)
$hSleep = GUICtrlCreateInput('800', 45, 104, 95, 25, $ES_CENTER)
GUICtrlSetFont(-1, 11)
$Button_1 = GUICtrlCreateButton('Запуск', 56, 136, 75, 25, 0)
$Button_2 = GUICtrlCreateButton('Скрыть окно', 56, 176, 75, 25, 0)

$hTrayItem_1 = TrayCreateItem('Скрыть/Восстановить окно')
$hTrayItem_2 = TrayCreateItem('Выход')
GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button_2
            GUISetState(@SW_HIDE)
        Case $Button_1
            If GUICtrlRead($Button_1) == 'Запуск' Then
                _Button_1('Отмена', $GUI_DISABLE)
            Else
                _Button_1('Запуск', $GUI_ENABLE)
            EndIf
    EndSwitch

    Switch TrayGetMsg()
        Case $hTrayItem_1
            If BitAND(WinGetState($hGui), 2) Then
                GUISetState(@SW_HIDE)
            Else
                GUISetState(@SW_SHOW)
            EndIf
        Case $hTrayItem_2
            Exit
    EndSwitch

    If $iTrigger And @HOUR & @MIN & @SEC = $sTimeText Then ExitLoop
WEnd

;MsgBox(64, 'Отчет', 'Будильник сработал!' & @LF & 'Текущее время: ' & @HOUR & ':' & @MIN & ':' & @SEC)
Sleep($sSleepText)
Send('{Enter}')
GUIDelete($hGui)



Func _Button_1($sText, $iState)
    If Not $iTrigger Then
        $sSleepText = GUICtrlRead($hSleep)
        $sTimeText = GUICtrlRead($hTime)
        $sTimeText = StringReplace($sTimeText, ':', '')
        $sTimeText = StringFormat("%06s", $sTimeText)
    EndIf
    $iTrigger = Not $iTrigger

    GUICtrlSetData($Button_1, $sText)
    GUICtrlSetState($hTime, $iState)
    GUICtrlSetState($hSleep, $iState)
EndFunc