Что нового

Прошу помощи в написании скрипта (CheckBox)

AlexNewman

Новичок
Сообщения
15
Репутация
0
Уважаемые участники форума, обращаюсь за помощью, совсем недавно приступил к изучению AutoIT. Есть задача написать интерфейс со списком ЧекБоксов, и кнопкой "Применить" (к примеру). То есть выбираем некоторые галки, за каждой какое то значение, по кнопке применить, выполняются отмеченные операции (допустим значения в реестре меняются). +хотелось бы прикрутить выбор шаблонов выбранных галок, хотя бы на выпадающем меню.
 

Makrut

Новичок
Сообщения
44
Репутация
2
Код:
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 303, 160, 192, 124)

Global $CheckBoxes[4], $check = 0

$CheckBoxes[0]  = GUICtrlCreateCheckbox("Номер 1", 16, 16, 97, 17)
$CheckBoxes[1]  = GUICtrlCreateCheckbox("Номер 2", 16, 40, 97, 17)
$CheckBoxes[2]  = GUICtrlCreateCheckbox("Номер 3", 16, 64, 97, 17)
$CheckBoxes[3]  = GUICtrlCreateCheckbox("Номер 4", 16, 88, 97, 17)
$Button1 = GUICtrlCreateButton("Button1", 136, 32, 121, 65)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit

		Case $Button1
			For $i = 0 To 3
				If GUICtrlRead($CheckBoxes[$i]) = $GUI_CHECKED Then
					MsgBox(0, 'Уведомление', 'Номер ' & $i + 1 & ' активен.')
					$check = 1
				EndIf
			Next
			If $check = 0 Then
				MsgBox(0, 'Уведомление', 'Ничего не выбрано.')
			EndIf
 $check = 0
	EndSwitch
WEnd
 

ra4o

AutoIT Гуру
Сообщения
1,165
Репутация
246
Вариантов создания скрипта под вашу задачу масса, например так :
Код:
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 190, 150, 300, 150)

Dim $CheckBox[3];Устанавливаем количество Checkbox
$ComboBox = $CheckBox ;Combo столько-же, сколько и Checkbox
;Перечисляем в массиве все необходимые пункты для Combo
Dim $ItemCombo[5] = ['Пункт 1', 'Пункт 2', 'Пункт 3', 'Пункт 4', 'Пункт 5']

;Создаём строку для записи в Combo
$Items=''
For $i = 0 To Ubound($ItemCombo)-1
    $Items &= $ItemCombo[$i] & '|'
Next
$Items = StringTrimRight($Items, 1)

;В цикле создаём все Checkbox и Combo, а так-же устанавливаем пункты Combo
For $i = 0 To UBound($CheckBox) - 1
	$CheckBox[$i] = GUICtrlCreateCheckbox('', 5, 22 * $i + 10, 15, 15)
	$ComboBox[$i] = GUICtrlCreateCombo('', 22, 22 * $i + 7, 150, 15)
    GUICtrlSetData(-1, $Items , $ItemCombo[$i])
Next

$Button1 = GUICtrlCreateButton("Применить", 8, 96, 163, 33)
GUISetState(@SW_SHOW)

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			_DoIt()
	EndSwitch
WEnd

;Функция проверки состояний Checkbox и Чтение соответствующего пункта Combo
Func _DoIt()
  For $i=0 to Ubound($CheckBox)-1
     If  GUICtrlRead($CheckBox[$i])=$GUI_CHECKED Then
		 MsgBox(48,'CheckBox '&$i+1,'Установлен Чекбокс '&$i+1&@CR&'Выбран пункт меню '&GuiCtrlRead($ComboBox[$i]))
	 EndIf
  Next
EndFunc   ;==>_DoIt
 
Автор
A

AlexNewman

Новичок
Сообщения
15
Репутация
0
Спасибо, эти примеры изучил, разобрался, но не пойму как разделить операции, а не зацикливаться на одном. То есть Галка1 установлена = создаётся настройка1 (реестр ковырять этой программой хочу), галка1 откл = удаляется настройка1, переход к следующей, галка2 вкл = создать настройку2, выкл = удалить настройку2

неужели писать свой цикл для каждой галки?
 

ra4o

AutoIT Гуру
Сообщения
1,165
Репутация
246
Так ?
Код:
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 590, 150)

Dim $CheckBox[3];Устанавливаем количество Checkbox
$ComboBox = $CheckBox ;Combo столько-же, сколько и Checkbox
;Перечисляем в массиве все необходимые пункты для Combo
Dim $ItemCombo[5]
$ItemCombo[0] = 'HKEY_CURRENT_USER\Software\Test,TestKey1,REG_SZ,Значение1'
$ItemCombo[1] = 'HKEY_CURRENT_USER\Software\Test,TestKey2,REG_SZ,Значение2'
$ItemCombo[2] = 'HKEY_CURRENT_USER\Software\Test,TestKey3,REG_SZ,Значение3'
$ItemCombo[3] = 'HKEY_CURRENT_USER\Software\Test,TestKey4,REG_SZ,Значение4'
$ItemCombo[4] = 'HKEY_CURRENT_USER\Software\Test,TestKey5,REG_SZ,Значение5'

;Создаём строку для записи в Combo
$Items = ''
For $i = 0 To UBound($ItemCombo) - 1
	$Items &= $ItemCombo[$i] & '|'
Next
$Items = StringTrimRight($Items, 1)

;В цикле создаём все Checkbox и Combo, а так-же устанавливаем пункты Combo
For $i = 0 To UBound($CheckBox) - 1
	$CheckBox[$i] = GUICtrlCreateCheckbox('', 5, 22 * $i + 10, 15, 15)
	$ComboBox[$i] = GUICtrlCreateCombo('', 22, 22 * $i + 7, 550, 15)
	GUICtrlSetData(-1, $Items, $ItemCombo[$i])
Next

$Button1 = GUICtrlCreateButton("Применить", 8, 96, 163, 33)
GUISetState(@SW_SHOW)

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			ConsoleWrite('-------------------------------------------------------------------' & @CR)
			For $i = 0 To UBound($CheckBox) - 1
				If GUICtrlRead($CheckBox[$i]) = $GUI_CHECKED Then
					$part = StringSplit(GUICtrlRead($ComboBox[$i]), ',')
					RegWrite($part[1], $part[2], $part[3], $part[4])
					If Not @error Then
						ConsoleWrite(GUICtrlRead($ComboBox[$i]) & '  установлено' & @CR)
					Else
						ConsoleWrite('Ошибка записи ' & @error & ' в ' & GUICtrlRead($ComboBox[$i]) & @CR)
					EndIf

				Else
					$part = StringSplit(GUICtrlRead($ComboBox[$i]), ',')
					RegDelete($part[1], $part[2])
					If Not @error Then
						ConsoleWrite($part[1] & ' значение ' & $part[2] & ' удалено' & @CR)
					Else
						ConsoleWrite('Ошибка удаления ' & @error & ' значения' & $part[4])
					EndIf
				EndIf

			Next
	EndSwitch
WEnd
 
Автор
A

AlexNewman

Новичок
Сообщения
15
Репутация
0
ra4o, благодарю дружище :IL_AutoIt_1: это то что нужно, с оформлением уже разберусь )
 
Автор
A

AlexNewman

Новичок
Сообщения
15
Репутация
0
ra4o сказал(а):
Так ?
Код:
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 590, 150)

Dim $CheckBox[3];Устанавливаем количество Checkbox
$ComboBox = $CheckBox ;Combo столько-же, сколько и Checkbox
;Перечисляем в массиве все необходимые пункты для Combo
Dim $ItemCombo[5]
$ItemCombo[0] = 'HKEY_CURRENT_USER\Software\Test,TestKey1,REG_SZ,Значение1'
$ItemCombo[1] = 'HKEY_CURRENT_USER\Software\Test,TestKey2,REG_SZ,Значение2'
$ItemCombo[2] = 'HKEY_CURRENT_USER\Software\Test,TestKey3,REG_SZ,Значение3'
$ItemCombo[3] = 'HKEY_CURRENT_USER\Software\Test,TestKey4,REG_SZ,Значение4'
$ItemCombo[4] = 'HKEY_CURRENT_USER\Software\Test,TestKey5,REG_SZ,Значение5'

;Создаём строку для записи в Combo
$Items = ''
For $i = 0 To UBound($ItemCombo) - 1
	$Items &= $ItemCombo[$i] & '|'
Next
$Items = StringTrimRight($Items, 1)

;В цикле создаём все Checkbox и Combo, а так-же устанавливаем пункты Combo
For $i = 0 To UBound($CheckBox) - 1
	$CheckBox[$i] = GUICtrlCreateCheckbox('', 5, 22 * $i + 10, 15, 15)
	$ComboBox[$i] = GUICtrlCreateCombo('', 22, 22 * $i + 7, 550, 15)
	GUICtrlSetData(-1, $Items, $ItemCombo[$i])
Next

$Button1 = GUICtrlCreateButton("Применить", 8, 96, 163, 33)
GUISetState(@SW_SHOW)

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			ConsoleWrite('-------------------------------------------------------------------' & @CR)
			For $i = 0 To UBound($CheckBox) - 1
				If GUICtrlRead($CheckBox[$i]) = $GUI_CHECKED Then
					$part = StringSplit(GUICtrlRead($ComboBox[$i]), ',')
					RegWrite($part[1], $part[2], $part[3], $part[4])
					If Not @error Then
						ConsoleWrite(GUICtrlRead($ComboBox[$i]) & '  установлено' & @CR)
					Else
						ConsoleWrite('Ошибка записи ' & @error & ' в ' & GUICtrlRead($ComboBox[$i]) & @CR)
					EndIf

				Else
					$part = StringSplit(GUICtrlRead($ComboBox[$i]), ',')
					RegDelete($part[1], $part[2])
					If Not @error Then
						ConsoleWrite($part[1] & ' значение ' & $part[2] & ' удалено' & @CR)
					Else
						ConsoleWrite('Ошибка удаления ' & @error & ' значения' & $part[4])
					EndIf
				EndIf

			Next
	EndSwitch
WEnd

Все же пишу софтину на чекбоксах, а не комбо. Пытаюсь переделать, вот что получилось, где то ошибка, помогите найти?

Код:
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 590, 150)

Dim $CheckBox1, $CheckBox2, $CheckBox3, $Items

$CheckBox1 = GUICtrlCreateCheckbox ("Пункт1", 22, 10, 550, 20)
$CheckBox2 = GUICtrlCreateCheckbox ("Пункт2", 22, 30, 550, 20)
$CheckBox3 = GUICtrlCreateCheckbox ("Пункт3", 22, 50, 550, 20)

Dim $CheckBoxItem[3]
$CheckBoxItem[0] = 'HKEY_CURRENT_USER\Software\Test,TestKey1,REG_SZ,Значение1'
$CheckBoxItem[1] = 'HKEY_CURRENT_USER\Software\Test,TestKey2,REG_SZ,Значение2'
$CheckBoxItem[2] = 'HKEY_CURRENT_USER\Software\Test,TestKey3,REG_SZ,Значение3'

$Button1 = GUICtrlCreateButton("Применить", 8, 96, 163, 33)
GUISetState(@SW_SHOW)

Local $CheckBox[3];, $CheckBox2, $CheckBox3
While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $Button1
	  ConsoleWrite('---------------------------------' & @CR)
	  For $i = 0 To UBound($CheckBox[$i]) - 1
			If GUICtrlRead($CheckBox[$i]) = $GUI_CHECKED Then
			   $part = StringSplit(GUICtrlRead($CheckBox[$i]), ',')
			   RegWrite($CheckBoxItem[$i])
			   ;RegWrite($part[1], $part[2], $part[3], $part[4])
			   If Not @error Then
                        ConsoleWrite(GUICtrlRead($CheckBox[$i]) & '  установлено' & @CR)
                    Else
                        ConsoleWrite('Ошибка записи ' & @error & ' в ' & GUICtrlRead($CheckBox[$i]) & @CR)
                    EndIf

                Else
                    $part = StringSplit(GUICtrlRead($CheckBox[$i]), ',')
                    RegDelete($part[1], $part[2])
                    If Not @error Then
                        ConsoleWrite($part[1] & ' значение ' & $part[2] & ' удалено' & @CR)
                    Else
                        ConsoleWrite('Ошибка удаления ' & @error & ' значения' & $part[4])
                    EndIf
                EndIf

            Next
    EndSwitch
WEnd

Проще говоря, значение ключа реестра должно быть присвоено одному чекбоксу, Галка вкл - значение записывается по кнопке применить, галка выкл - значение удаляется
 

ra4o

AutoIT Гуру
Сообщения
1,165
Репутация
246
Ввела в заблуждение эта фраза :
хотелось бы прикрутить выбор шаблонов выбранных галок, хотя бы на выпадающем меню
Так нужно ?
Код:
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 360, 150)

Dim $CheckBox[3]

For $i = 0 To UBound($CheckBox) - 1
	$CheckBox[$i] = GUICtrlCreateCheckbox('Пункт ' & $i + 1, 5, 22 * $i + 10, 250, 15)
Next


#cs
	$CheckBox1 = GUICtrlCreateCheckbox("Пункт1", 22, 10, 250, 20)
	$CheckBox2 = GUICtrlCreateCheckbox("Пункт2", 22, 30, 250, 20)
	$CheckBox3 = GUICtrlCreateCheckbox("Пункт3", 22, 50, 250, 20)
#ce
Dim $CheckBoxItem[3]
$CheckBoxItem[0] = 'HKEY_CURRENT_USER\Software\Test,TestKey1,REG_SZ,Значение1'
$CheckBoxItem[1] = 'HKEY_CURRENT_USER\Software\Test,TestKey2,REG_SZ,Значение2'
$CheckBoxItem[2] = 'HKEY_CURRENT_USER\Software\Test,TestKey3,REG_SZ,Значение3'

$Button1 = GUICtrlCreateButton("Применить", 8, 96, 163, 33)
GUISetState(@SW_SHOW)

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			ConsoleWrite('---------------------------------' & @CR)
			For $i = 0 To UBound($CheckBox) - 1
				If GUICtrlRead($CheckBox[$i]) = $GUI_CHECKED Then
					$part = StringSplit(($CheckBoxItem[$i]), ',')
					RegWrite($part[1], $part[2], $part[3], $part[4])
					If Not @error Then
						ConsoleWrite(GUICtrlRead($CheckBox[$i]) & '  установлено' & @CR)
					Else
						ConsoleWrite('Ошибка записи ' & @error & ' в ' & GUICtrlRead($CheckBox[$i]) & @CR)
					EndIf

				Else
					$part = StringSplit($CheckBoxItem[$i], ',')
					RegDelete($part[1], $part[2])
					If Not @error Then
						ConsoleWrite($part[1] & ' значение ' & $part[2] & ' удалено' & @CR)
					Else
						ConsoleWrite('Ошибка удаления ' & @error & ' значения' & $part[4])
					EndIf
				EndIf

			Next
	EndSwitch
WEnd
 
Автор
A

AlexNewman

Новичок
Сообщения
15
Репутация
0
Ребят, помогите найти ошибку, 2й день бьюсь.
По нажатию "применить", скрипт выдаёт Array variable has incorrect number of subscripts or subscript dimension range exceeded.
Перевёл, прочитал, нашёл советы что с этим делать, но всё равно не получается, чего не хватает?
Код:
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <TabConstants.au3>

;описание переменных
;===================================================================================================
Local $tab0, $tab1, $tab2, $tab3, $tab4, $tab5
Local $tab0input, $tab1input
;===================================================================================================
GUICreate("LOCK", 740, 480)	;заголовок окна
GUISetState ()

;===================================================================================================
;создание поля с вкладками
$tab0 = GUICtrlCreateTab(10, 10, 520, 400, $TCS_TABS + $TCS_RIGHTJUSTIFY + $TCS_MULTILINE, $WS_EX_CLIENTEDGE) ;, $WS_VSCROLL)	;создание поля с вкладками

Dim $CheckBox[3]

;ВКЛАДКА (DEMO)          ==========================================================================================================================
$tab5 = GUICtrlCreateTabItem("Демонстрация")
;Dim $CheckBox[3]
$CheckBox[0] = GUICtrlCreateCheckbox('Добавить пункт меню "!_пункт1"', 20, 50, 400, 20)
$CheckBox[1] = GUICtrlCreateCheckbox('Добавить пункт меню "!!__пункт2"', 20, 70, 400, 20)
$CheckBox[2] = GUICtrlCreateCheckbox('Добавить пункт меню "!!!___пункт3"', 20, 90, 400, 20)

GUICtrlCreateTabItem("") ; определяет конец вкладок

;Кнопка ПРИМЕНИТЬ ====================================================================================
Local $CTRL_btn3 = GUICtrlCreateButton("Применить", 570, 100, 80, 29)

GUISetState() ;Показывает созданное окно

Dim $CheckBoxItem[3]
;=================================Вкладка ДЕМО
$CheckBoxItem[0] = 'HKEY_CURRENT_USER\Software\Test,TestKey2,REG_SZ,Значение2'
$CheckBoxItem[1] = 'HKEY_CLASSES_ROOT\DesktopBackground\Shell\!!__Пункт2'
$CheckBoxItem[2] = 'HKEY_CLASSES_ROOT\DesktopBackground\Shell\!!!__Пункт3'

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $CTRL_btn3
            ConsoleWrite('---------------------------------' & @CR)
            For $i = 0 To UBound($CheckBoxItem) - 1
                If GUICtrlRead($CheckBox[$i]) = $GUI_CHECKED Then
                    $part = StringSplit(($CheckBoxItem[$i]), ',')
                    RegWrite($part[1], $part[2], $part[3], $part[4])
                    If Not @error Then
                        ConsoleWrite(GUICtrlRead($CheckBox[$i]) & '  установлено' & @CR)
                    Else
                        ConsoleWrite('Ошибка записи ' & @error & ' в ' & GUICtrlRead($CheckBox[$i]) & @CR)
                    EndIf

                Else
                    $part = StringSplit($CheckBoxItem[$i], ',')
                    RegDelete($part[1], $part[2])
                    If Not @error Then
                        ConsoleWrite($part[1] & ' значение ' & $part[2] & ' удалено' & @CR)
                    Else
                        ConsoleWrite('Ошибка удаления ' & @error & ' значения' & $part[4])
                    EndIf
                EndIf

            Next
    EndSwitch

 WEnd
[/quote]


Добавлено:
Сообщение автоматически объединено:

и ещё вопрос, как прикрутить к одной галке несколько записей в реестр, ведь 1чекбокс=1строка реестра, если добавить, то собъются массивы, как это можно реализовать? т.е. например от одного чекбокса должно добавиться 4 строки реестра, под какой то 2 строки, но всё равно константа. Для понимания - пишу твикер для винды, каждый чекбокс отвечает за какую то настройку, для какой то настройки достаточно 1 строки в реестре, для какой то нужно дописать ещё несколько, чтобы настройка работала. Спасибо за отзывы
 

ra4o

AutoIT Гуру
Сообщения
1,165
Репутация
246
Можно в одну строку записывать несколько значений реестра, разделяя их, например знаком "|", в таком случае скрипт можно доработать так :
Код:
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <TabConstants.au3>

;описание переменных
;===================================================================================================
Local $tab0, $tab1, $tab2, $tab3, $tab4, $tab5
Local $tab0input, $tab1input
;===================================================================================================
GUICreate("LOCK", 740, 480) ;заголовок окна
GUISetState()

;===================================================================================================
;создание поля с вкладками
$tab0 = GUICtrlCreateTab(10, 10, 520, 400, $TCS_TABS + $TCS_RIGHTJUSTIFY + $TCS_MULTILINE, $WS_EX_CLIENTEDGE) ;, $WS_VSCROLL)   ;создание поля с вкладками

Dim $CheckBox[3]

;ВКЛАДКА (DEMO)          ==========================================================================================================================
$tab5 = GUICtrlCreateTabItem("Демонстрация")
;Dim $CheckBox[3]
$CheckBox[0] = GUICtrlCreateCheckbox('Добавить пункт меню "!_пункт1"', 20, 50, 400, 20)
$CheckBox[1] = GUICtrlCreateCheckbox('Добавить пункт меню "!!__пункт2"', 20, 70, 400, 20)
$CheckBox[2] = GUICtrlCreateCheckbox('Добавить пункт меню "!!!___пункт3"', 20, 90, 400, 20)

GUICtrlCreateTabItem("") ; определяет конец вкладок

;Кнопка ПРИМЕНИТЬ ====================================================================================
Local $CTRL_btn3 = GUICtrlCreateButton("Применить", 570, 100, 80, 29)

GUISetState() ;Показывает созданное окно

Dim $CheckBoxItem[3]
;=================================Вкладка ДЕМО
$CheckBoxItem[0] = 'HKEY_CURRENT_USER\Software\Test,TestKey1,REG_SZ,Значение1|'& _
				   'HKEY_CURRENT_USER\Software\Test,TestKey2,REG_SZ,Значение2|'& _
				   'HKEY_CURRENT_USER\Software\Test,TestKey3,REG_SZ,Значение3'
$CheckBoxItem[1] = 'HKEY_CURRENT_USER\Software\Test,TestKey11,REG_SZ,Значение11|'& _
				   'HKEY_CURRENT_USER\Software\Test,TestKey12,REG_SZ,Значение12'
$CheckBoxItem[2] = 'HKEY_CURRENT_USER\Software\Test,TestKey21,REG_SZ,Значение21'

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $CTRL_btn3
			ConsoleWrite('---------------------------------' & @CR)
			For $i = 0 To UBound($CheckBoxItem) - 1
				If GUICtrlRead($CheckBox[$i]) = $GUI_CHECKED Then
					$Value = StringSplit($CheckBoxItem[$i], '|')
					For $j = 1 To $Value[0]
						$part = StringSplit($Value[$j], ',')
						RegWrite($part[1], $part[2], $part[3], $part[4])
						If Not @error Then
							ConsoleWrite($Value[$j] & '  установлено' & @CR)
						Else
							ConsoleWrite('Ошибка записи ' & @error & ' в ' & GUICtrlRead($CheckBox[$i]) & @CR)
						EndIf
					Next
				Else
					$Value = StringSplit($CheckBoxItem[$i], '|')
					For $j = 1 To $Value[0]
						$part = StringSplit($Value[$j], ',')
						RegDelete($part[1], $part[2])
						If Not @error Then
							ConsoleWrite($part[1] & ' значение ' & $part[2] & ' удалено' & @CR)
						Else
							ConsoleWrite('Ошибка удаления ' & @error & ' значения' & $part[4])
						EndIf
					Next
				EndIf

			Next
	EndSwitch

WEnd
 
Верх