[Автоматизация] Обновить веб страницу с onlineTv каналом в случае остановки трансляции

#include <IE.au3>

Opt('PixelCoordMode', 2)
Opt('MouseCoordMode', 2)
Opt('MustDeclareVars', 1)
Opt('TrayMenuMode', 1)

Global Const $tagMIB_IFROW = 'wchar Name[256];dword Index;dword Type;dword Mtu;dword Speed;dword PhysAddrLen;byte PhysAddr[8];dword AdminStatus;dword OperStatus;dword LastChange;dword InOctets;dword InUcastPkts;dword InNUcastPkts;dword InDiscards;dword InErrors;dword InUnknownProtos;dword OutOctets;dword OutUcastPkts;dword OutNUcastPkts;dword OutDiscards;dword OutErrors;dword OutQLen;dword DescrLen;char Descr[256]'

Global $iGetKB_1, $iGetKB_2, $iDifference, $bPause = False, $aGetKB_1, $aGetKB_2

HotKeySet('{F10}', '_MyPause') ;F10 - пауза
HotKeySet('{ESC}', '_MyExit') ;Esc - выход

If Not Ping('www.ontvtime.ru') Then
	ToolTip('Сайт www.ontvtime.ru не доступен.', 0, 0, '', 3, 1)
	Sleep(3000)
	Exit
EndIf

While 1
	If $bPause Then
		$iGetKB_1 = Round(_WinAPI_GetIfEntry() / 1024, 2)
		Sleep(2000)
		$iGetKB_2 = Round(_WinAPI_GetIfEntry() / 1024, 2)
		$iDifference = $iGetKB_2 - $iGetKB_1
		ToolTip(Round($iDifference, 2) & @CRLF & 'F10-пауза' & @CRLF & 'Esc-выход', 0, 0, '', 0, 1)
		If $iDifference < 10 Then
			_Give_Me_My_TV()
		EndIf
	Else
		ToolTip('F10-начать(продолжить) работу', 0, 0, '', 0, 1)
	EndIf
	Sleep(2)
WEnd

Func _Give_Me_My_TV()
	Local $hHandle, $oIE, $aWinPos, $timeout, $aPos, $checksum
	Local $aIE_List = WinList('[Class:IEFrame]')
	If Not $aIE_List[0][0] Then Return

	For $i = 1 To $aIE_List[0][0]
		If StringInStr($aIE_List[$i][0], 'Онлайн ТВ') Then
			$hHandle = $aIE_List[$i][1]
			ExitLoop
		EndIf
	Next
	If Not IsHWnd($hHandle) Then Return
	$oIE = _IEAttach($hHandle, 'HWND')
	If Not IsObj($oIE) Then Return
	_IEAction($oIE, 'refresh')
	_IELoadWait($oIE)

	$aWinPos = WinGetPos($hHandle)
	If Not IsArray($aWinPos) Then Return
	$timeout = TimerInit()
	While 1
		$aPos = ControlGetPos($hHandle, '', '[CLASS:WMPVideoWindow; INSTANCE:1]')
		If IsArray($aPos) Then ExitLoop
		Sleep(500)
		If TimerDiff($timeout) >= 10000 Then Return
	WEnd

	$checksum = PixelChecksum($aPos[0] + $aPos[2] - 50, $aPos[1] + $aPos[3], $aPos[0] + $aPos[2], $aPos[1] + $aPos[3] + 100, 1, $hHandle)
	While $checksum = PixelChecksum($aPos[0] + $aPos[2] - 50, $aPos[1] + $aPos[3], $aPos[0] + $aPos[2], $aPos[1] + $aPos[3] + 100, 1, $hHandle)
		Sleep(100)
	WEnd
	MouseClick('primary', $aPos[0] + $aWinPos[0] + $aPos[2] / 2, $aPos[1] + $aWinPos[1] + $aPos[3] / 2, 2, 1)

	Return
EndFunc   ;==>_Give_Me_My_TV


Func _MyPause()
	$bPause = Not $bPause
EndFunc   ;==>_MyPause

Func _MyExit()
	Exit
EndFunc   ;==>_MyExit

Func _WinAPI_GetIfEntry($iIndex = 1, $Dll = -1)

	Local $Ret, $Data, $sResult
	Local $tMIB_IFROW

	If $Dll < 0 Then
		$Dll = 'IPHlpApi.dll'
	EndIf

	$tMIB_IFROW = DllStructCreate($tagMIB_IFROW)
	DllStructSetData($tMIB_IFROW, 2, $iIndex)
	$Ret = DllCall($Dll, 'dword', 'GetIfEntry', 'ptr', DllStructGetPtr($tMIB_IFROW))
	If (@error) Or ($Ret[0]) Then
		Return SetError($Ret[0], 0, 0)
	EndIf
	$sResult = DllStructGetData($tMIB_IFROW, 'InOctets')
	Return $sResult
EndFunc   ;==>_WinAPI_GetIfEntry