Что нового

Построчное накапливание значений в текстовом файле

perven1

Новичок
Сообщения
57
Репутация
0
Доброе утро, знатоки Autoit.
Помогите разобраться.

Есть скрипт, срабатывающий от нажатия определенной кнопки джойстика.
В момент нажатия на кнопку - скрипт добавляет "1" в первую текстовую строку текстового файла 1.txt.
То есть - работает как счетчик.

Как заставить этот скрипт - вместо выполнения арифметической операции сложения - просто записывать текст "Fire" (вместо единицы) - в нижнюю строку, если верхняя строка заполнена каким-то содержимым ?

То есть при каждом нажатии - будет появляться новая строка с записью "Fire" и получится растущий при нажатии кнопки столбец:
"Fire"
"Fire"
"Fire"

Код:
;____________________________________________________________________
;       Original program by Ejoc                                    ;
;       Improved by Adam1213 (autoit 3.2 compatiblity + improved labels         ;
;____________________________________________________________________

#include <GUIConstants.au3>

;_________________ SETUP_____________________________________
Local $joy, $coor, $h, $s, $msg
$joy = _JoyInit()

Local $iClicks = 0, $sFile = @ScriptDir  & '\1.txt'
Local $aArr, $sFile_Text = FileRead($sFile)
If $sFile_Text Then ; Читаем "1.txt" и сохраняем число в $iClicks
    $aArr = StringRegExp($sFile_Text, '\d+', 1)
    If Not @error Then $iClicks = Number($aArr[0])
EndIf

Dim $labels_text[8] = ['X', 'Y', 'Z', 'R', 'U', 'V', 'POV', 'Buttons']
Dim $labels_no = UBound($labels_text)
Dim $labels[$labels_no]
Dim $labels_value[$labels_no]
;__________ CONFIG ____________________________________________
;---------- Find the max length of the longest label --------------
$label_len = 0
For $text In $labels_text
    $len = StringLen($text)
    If $len > $label_len Then
        $label_len = $len
    EndIf
Next
$label_len *= 6
;_____________ GUI _______________________________________________
GUICreate('Joystick Test', 200, 200)
GUICtrlCreateLabel('Joystick', 40, 20, 100, 20)

For $i = 0 To $labels_no - 1
    GUICtrlCreateLabel($labels_text[$i] & ':', 10, 60 + $i * 12, $label_len, 12)
    $labels[$i] = GUICtrlCreateLabel('', 10 + $label_len, 60 + $i * 12, 70, 12)
    $labels_value[$i] = ''
Next
GUISetState()
;_____________________________________________________________________

While 1
    $coord = _GetJoy($joy, 0)
    For $i = 0 To UBound($coord) - 1
        If $coord[$i] <> $labels_value[$i] Then
            GUICtrlSetData($labels[$i], $coord[$i])
            $labels_value[$i] = $coord[$i]
            If $labels[$i] = $labels[7] And $coord[$i] = '2' Then _WriteClick() ; Записываем новое число в "1.txt"
        EndIf
    Next
    Sleep(100)
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

Func _WriteClick()
    $iClicks += 1
    Local $hFile = FileOpen($sFile, 2)
    If $hFile = -1 Then Return
    FileWrite($hFile, $iClicks)
    FileClose($hFile)
EndFunc


$lpJoy = 0 ; Joyclose

;======================================
;   _JoyInit()
;======================================
Func _JoyInit()
    Local $joy
    Global $JOYINFOEX_struct = "dword[13]"

    $joy = DllStructCreate($JOYINFOEX_struct)
    If @error Then Return 0
    DllStructSetData($joy, 1, DllStructGetSize($joy), 1);dwSize = sizeof(struct)
    DllStructSetData($joy, 1, 255, 2) ;dwFlags = GetAll
    Return $joy
EndFunc   ;==>_JoyInit

;======================================
;   _GetJoy($lpJoy,$iJoy)
;   $lpJoy  Return from _JoyInit()
;   $iJoy   Joystick # 0-15
;   Return  Array containing X-Pos, Y-Pos, Z-Pos, R-Pos, U-Pos, V-Pos,POV
;           Buttons down
;
;           *POV This is a digital game pad, not analog joystick
;           65535   = Not pressed
;           0       = U
;           4500    = UR
;           9000    = R
;           Goes around clockwise increasing 4500 for each position
;======================================
Func _GetJoy($lpJoy, $iJoy)
    Local $coor, $ret

    Dim $coor[8]
    DllCall("Winmm.dll", "int", "joyGetPosEx", _
            "int", $iJoy, _
            "ptr", DllStructGetPtr($lpJoy))

    If Not @error Then
        $coor[0] = DllStructGetData($lpJoy, 1, 3)
        $coor[1] = DllStructGetData($lpJoy, 1, 4)
        $coor[2] = DllStructGetData($lpJoy, 1, 5)
        $coor[3] = DllStructGetData($lpJoy, 1, 6)
        $coor[4] = DllStructGetData($lpJoy, 1, 7)
        $coor[5] = DllStructGetData($lpJoy, 1, 8)
        $coor[6] = DllStructGetData($lpJoy, 1, 11)
        $coor[7] = DllStructGetData($lpJoy, 1, 9)
    EndIf

    Return $coor
EndFunc   ;==>_GetJoy
 

Вложения

  • 1.rar
    1.5 КБ · Просмотры: 0

hedji

Продвинутый
Сообщения
409
Репутация
94
Код:
Func _WriteClick()    
    FileWriteLine($sFile, "Fire!")
EndFunc
 
Автор
P

perven1

Новичок
Сообщения
57
Репутация
0
hedji, тут вроде какая-то ошибка.

Почему-то этот скрипт - пытается первую запись - вести не с новой строки, а с конца предыдущей строки.
То есть в непустом файле - получается запись:

32Fire!
Fire!
Fire!
Fire!

тогда как должно вроде получится :

Fire!
Fire!
Fire!
Fire!
 

Вложения

  • 1.rar
    1.5 КБ · Просмотры: 1

hedji

Продвинутый
Сообщения
409
Репутация
94
Просто строка в файле не заканчивается переводом каретки.
Если это критично, то можно так:
Код:
Func _WriteClick()    
    FileWrite($sFile, @CRLF & "Fire!")
EndFunc
 
Автор
P

perven1

Новичок
Сообщения
57
Репутация
0
А вот теперь - все заработало.
Спасибо большое.
 
Верх