Что нового

Edit вытаскивать по строке, пока не закончатся строки

black1

C++,Pic
Сообщения
39
Репутация
0
Есть GUI Edit с параметром $ES_MULTILINE
Код:
$Edit1 = GUICtrlCreateEdit("", 5, 5, 400, 390, BitOR($ES_MULTILINE,$ES_AUTOHSCROLL,$WS_HSCROLL,$WS_VSCROLL,$ES_WANTRETURN))

нужно что то похожее
While 'пока не кончатся строки'
$stroka = строка($Edit1) ;первый заход бирет 1 строку,2 заход 2 строку и тд.. до конца
......
WEnd



Добавлено:
Сообщение автоматически объединено:

омг)
Код:
$nOffset = 1
While 1
    $array = StringRegExp( $TextEdit1, '.*\n', 1, $nOffset)
    
    If @error = 0 Then
       $nOffset = @extended
	 Else
        ExitLoop
	 
     EndIf
	 
	 for $i = 0 to UBound($array) - 1
     msgbox(0, "RegExp Test with Option 1 - " & $i, $array[$i])
Next

WEnd

омг 2
указатели библиотечных функций _GUICtrlEditGetLine
 

madmasles

Модератор
Глобальный модератор
Сообщения
7,790
Репутация
2,322
black1,
Код:
#include <GuiEdit.au3>
#include <GuiConstantsEx.au3>

$iRand = Random(10, 30, 1)
$sText = ''
For $i = 1 To $iRand
	$sText &= 'String number ' & $i & @CRLF
Next
$hGui = GUICreate('Test', 250, 265)
$nEdit = GUICtrlCreateEdit('', 2, 2, 246, 220)
$hEdit = GUICtrlGetHandle($nEdit)
$nButton = GUICtrlCreateButton('Click me', 75, 230, 100, 25)
GUISetState()
_GUICtrlEdit_SetText($hEdit, StringTrimRight($sText, 2))
$sText = ''
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $nButton
			$iCount = _GUICtrlEdit_GetLineCount($hEdit)
			For $i = 0 To $iCount - 1
				MsgBox(64, $i + 1 & '(' & $iCount & ')', _GUICtrlEdit_GetLine($hEdit, $i), 0, $hGui)
			Next
	EndSwitch
WEnd

Или так.
Код:
#include <GuiConstantsEx.au3>

$iRand = Random(10, 30, 1)
$sText = ''
For $i = 1 To $iRand
	$sText &= 'String number ' & $i & @CRLF
Next
$hGui = GUICreate('Test', 250, 265)
$nEdit = GUICtrlCreateEdit('', 2, 2, 246, 220)
$nButton = GUICtrlCreateButton('Click me', 75, 230, 100, 25)
GUISetState()
GUICtrlSetData($nEdit, StringTrimRight($sText, 2))
$sText = ''
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $nButton
			$sText = GUICtrlRead($nEdit)
			If Not $sText Then ContinueLoop
			$aText = StringSplit(StringStripCR($sText), @LF)
			For $i = 1 To $aText[0]
				MsgBox(64, $i & '(' & $aText[0] & ')', $aText[$i], 0, $hGui)
			Next
			$aText = 0
			$sText = ''
	EndSwitch
WEnd
 
Верх