Автор Тема: Добавление текста на кнопки с рисунком  (Прочитано 6264 раз)

0 Пользователей и 1 Гость просматривают эту тему.

Эта тема содержит сообщение, помеченное как лучший ответ. Кликните здесь для перехода к этому сообщению.

Оффлайн avtoIT [?]

  • Новичок
  • *
  • Сообщений: 94
  • Репутация: 0
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.14.0
В этой теме http://autoit-script.ru/index.php?topic=21707.0, Yashied  предложил вариант решения этой проблемы, но я не смог разобраться.

Почему? Берите текст из .ini и рисуйте его на пустой кнопке с помощью GDI или GDI+. Затем обновляйте изображения кнопок.



У меня было что-то наподобие этого:
Код: AutoIt [Выделить]
_GDIPlus_Startup ()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($Form1)
_GDIPlus_GraphicsDrawString($hGraphic, "Hello world", 140, 110)


но текст нигде не показывается, или нужно в $hGraphic складывать дескриптор кнопки?

Русское сообщество AutoIt

Добавление текста на кнопки с рисунком
« Отправлен: Февраль 02, 2016, 14:06:10 »

Оффлайн joiner [?]

  • Расмус-бродяга
  • AutoIt Гуру
  • *****
  • Сообщений: 2695
  • Репутация: 457
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Добавление текста на кнопки с рисунком
« Ответ #1, Отправлен: Февраль 02, 2016, 15:48:08 »
avtoIT
что есть на данный момент?
можно увидеть весь код? иначе это будет долго
Были времена, когда солнце было ярче, трава зеленее, а водка сорокоградуснее

Оффлайн avtoIT [?]

  • Новичок
  • *
  • Сообщений: 94

  • Автор темы
  • Репутация: 0
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.14.0
Re: Добавление текста на кнопки с рисунком
« Ответ #2, Отправлен: Февраль 02, 2016, 16:25:49 »
Код: AutoIt [Выделить]
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <Skin.au3>
#include <StaticConstants.au3>
#include <GDIPlus.au3>
#include <WinAPIMisc.au3>

Global $Form1, $Button1, $Skin = True

$Form1 = GUICreate("Form1", 300, 180, -1, -1, $WS_BORDER + $WS_POPUP, 0);, $WS_EX_CONTROLPARENT)
GUICtrlCreatePic (@ScriptDir & '\bck.bmp.png', 0, 0, 300, 180)
GUICtrlSetState(-1, $GUI_DISABLE)
$Button1 = _Skin_AddButton(90, 90, 120, 42, '1.png', '2.png', '3.png', '3.png', '3.png', 1)

$Combo1 = GUICtrlCreateCombo('English', 80, 55, 140, 25, $CBS_DROPDOWNLIST + $WS_VSCROLL)
GUICtrlSetData (-1, 'Русский')
GUICtrlSetFont(-1, 10, 400, 0, 'Arial')
;_Skin_EnableFocus(1)
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
GUIRegisterMsg($WM_NCHITTEST, 'WM_NCHITTEST')
GUISetState(@SW_SHOW)

While 1
    If $Skin Then
        _Skin_Helper($Form1)
    EndIf
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            ;SoundPlay ("zvyuk.wav")
            ;_WinAPI_PlaySound ("zvvv.wav", $SND_ASYNC + $SND_NOWAIT)
            MsgBox (0, 0, GUICtrlRead($Combo1))
    EndSwitch
WEnd

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    Local $Msg = BitShift($wParam, 16)

    Switch $hWnd
        Case $Form1
            Switch BitAND($wParam, 0xFFFF)
                Case $Combo1
                    Switch $Msg
                        Case $CBN_CLOSEUP
                            $Skin = 1
                        Case $CBN_DROPDOWN
                            $Skin = 0
                        Case Else

                    EndSwitch
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func WM_NCHITTEST($hWnd, $iMsg, $wParam, $lParam)
    Switch $hWnd
        Case $Form1
            If $skData[0][3] > 0 Then
                Return $GUI_RUNDEFMSG
            EndIf
            Local $Info = GUIGetCursorInfo($Form1)
            If Not @Error Then
                Switch $Info[4]
                    Case $Button1
                        ; Nothing
                    Case Else
                        Return $HTCAPTION
                EndSwitch
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NCHITTEST


Текст на кнопку нужен был в основном для того, чтобы поддерживать разные языки, получается, что нельзя будет использовать простой .ini файл с фразами?
Почему? Берите текст из .ini и рисуйте его на пустой кнопке с помощью GDI или GDI+. Затем обновляйте изображения кнопок.

Я просто не понимаю, как на кнопке из Skin.au3 нарисовать строку=(
« Последнее редактирование: Февраль 02, 2016, 20:43:11 от avtoIT »

Оффлайн Alofa [?]

  • AutoIt Гуру
  • *****
  • Сообщений: 1420
  • Репутация: 207
  • Пол: Мужской
  • Windows 7 /10 [x64]
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Добавление текста на кнопки с рисунком
« Ответ #3, Отправлен: Февраль 02, 2016, 22:57:32 »
... Я просто не понимаю, как на кнопке из Skin.au3 нарисовать строку=(
К примеру так:
Код: AutoIt [Выделить]
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <Skin.au3>
#include <StaticConstants.au3>
#include <GDIPlus.au3>
#include <WinAPIMisc.au3>

Global $Form1, $Button1, $Skin = True

$Form1 = GUICreate("Form1", 300, 180, -1, -1, $WS_BORDER + $WS_POPUP, 0);, $WS_EX_CONTROLPARENT)
GUICtrlCreatePic (@ScriptDir & '\bck.bmp.png', 0, 0, 300, 180)
GUICtrlSetState(-1, $GUI_DISABLE)
$Button1 = _Skin_AddButton(90, 90, 120, 42, '1.png', '2.png', '3.png', '3.png', '3.png', 1)


$Combo1 = GUICtrlCreateCombo('English', 80, 55, 140, 25, $CBS_DROPDOWNLIST + $WS_VSCROLL)
GUICtrlSetData (-1, 'Русский')
GUICtrlSetFont(-1, 10, 400, 0, 'Arial')
;_Skin_EnableFocus(1)
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
GUIRegisterMsg($WM_NCHITTEST, 'WM_NCHITTEST')
GUISetState(@SW_SHOW)

_GDIPlus_Startup()
_DrawText('Мой текст')

While 1
    If $Skin Then
        _Skin_Helper($Form1)
    EndIf
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            ;SoundPlay ("zvyuk.wav")
            ;_WinAPI_PlaySound ("zvvv.wav", $SND_ASYNC + $SND_NOWAIT)
            MsgBox (0, 0, GUICtrlRead($Combo1))
    EndSwitch
WEnd


Func _DrawText($sString)
    ; Пример взят из http://autoit-script.ru/autoit3_docs/libfunctions/_gdiplus_graphicsdrawstringex.htm

    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($Form1)
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF00007F)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate("Arial")
    $hFont = _GDIPlus_FontCreate($hFamily, 12, 2)
    $tLayout = _GDIPlus_RectFCreate(100, 100, 0, 0)
    $aInfo = _GDIPlus_GraphicsMeasureString($hGraphic, $sString, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDrawStringEx($hGraphic, $sString, $hFont, $aInfo[0], $hFormat, $hBrush)
   
    _GDIPlus_FontDispose($hFont) ;          -|
    _GDIPlus_FontFamilyDispose($hFamily) ;   | Блок освобождает объекты и закрывает GDI+
    _GDIPlus_StringFormatDispose($hFormat) ; | - его можно задействовать в конце работы скрипта,
    _GDIPlus_BrushDispose($hBrush) ;         | когда отображения текста уже не требуется.
    _GDIPlus_GraphicsDispose($hGraphic) ;    |
    _GDIPlus_Shutdown() ;                   -|
EndFunc
 


Русское сообщество AutoIt

Re: Добавление текста на кнопки с рисунком
« Ответ #3 Отправлен: Февраль 02, 2016, 22:57:32 »

Оффлайн avtoIT [?]

  • Новичок
  • *
  • Сообщений: 94

  • Автор темы
  • Репутация: 0
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.14.0
Re: Добавление текста на кнопки с рисунком
« Ответ #4, Отправлен: Февраль 02, 2016, 23:21:43 »
Уже продвижение, но при первом же наведении на кнопку, текст исчезает (проваливается под нее) :think:

Оффлайн Alofa [?]

  • AutoIt Гуру
  • *****
  • Сообщений: 1420
  • Репутация: 207
  • Пол: Мужской
  • Windows 7 /10 [x64]
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Добавление текста на кнопки с рисунком
« Ответ #5, Отправлен: Февраль 03, 2016, 00:01:03 »
А на что вам в скрипте:
Код: AutoIt [Выделить]
Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
; ...
EndFunc
; И
Func WM_NCHITTEST($hWnd, $iMsg, $wParam, $lParam)
; ...
EndFunc


Оффлайн avtoIT [?]

  • Новичок
  • *
  • Сообщений: 94

  • Автор темы
  • Репутация: 0
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.14.0
Re: Добавление текста на кнопки с рисунком
« Ответ #6, Отправлен: Февраль 03, 2016, 00:09:34 »
Это писал Yashied, без них нельзя заблокировать кнопку во время выборов вариантов в комболисте (кликая по варианту из комбо, одновременно кликаешь и по кнопке), а другая команда для перетаскивания окна за клиентскую часть (если ставить стандартный стиль, то кнопка срабатывает только при двойном клике)

Оффлайн joiner [?]

  • Расмус-бродяга
  • AutoIt Гуру
  • *****
  • Сообщений: 2695
  • Репутация: 457
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Добавление текста на кнопки с рисунком
« Ответ #7, Отправлен: Февраль 03, 2016, 00:48:00 »
любое обновление элемента нужно сопровождать прорисовкой текста. то есть повторять
функцию
Код: AutoIt [Выделить]
_DrawText($sString)

навели на кнопку, кнопка обновилась и перерисовываем текст

Русское сообщество AutoIt

Re: Добавление текста на кнопки с рисунком
« Ответ #7 Отправлен: Февраль 03, 2016, 00:48:00 »

Помечен как лучший ответ пользователем avtoIT Отправлен Февраль 03, 2016, 13:59:17

Оффлайн Yashied [?]

  • AutoIt MVP
  • Глобальный модератор
  • *
  • Сообщений: 5379
  • Репутация: 2695
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.x.x
Re: Добавление текста на кнопки с рисунком
« Ответ #8, Отправлен: Февраль 03, 2016, 09:13:05 »
Код: AutoIt [Выделить]
#include <APIConstants.au3>
#include <GUIConstants.au3>
#include <GUIComboBox.au3>
#include <GDIPlus.au3>
#include <WinAPIEx.au3>

#include "Skin.au3"

_GDIPlus_Startup()

Global $hPng[3] = [_GDIPlus_BitmapCreateFromFile('1.png'), _GDIPlus_BitmapCreateFromFile('2.png'), _GDIPlus_BitmapCreateFromFile('3.png')]
Global $Form1, $Button1, $Combo1, $nMsg, $Skin = True

$Form1 = GUICreate('Form1', 300, 180, -1, -1, BitOR($WS_BORDER, $WS_POPUP))
GUICtrlCreatePic('bck.bmp.png', 0, 0, 300, 180)
GUICtrlSetState(-1, $GUI_DISABLE)
$Combo1 = GUICtrlCreateCombo('English', 80, 55, 140, 25, BitOR($CBS_DROPDOWNLIST, $WS_VSCROLL))
GUICtrlSetData(-1, 'Русский')
GUICtrlSetFont(-1, 9.8, $FW_NORMAL, $GUI_FONTNORMAL, 'Arial')
$Button1 = _Skin_AddButtonEx(90, 90, 120, 42, $hPng[0], $hPng[1], $hPng[2], '', $hPng[2], 1)
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
GUIRegisterMsg($WM_NCHITTEST, 'WM_NCHITTEST')
_Update()
GUISetState()

While 1
    If $Skin Then
        _Skin_Helper($Form1)
    EndIf
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Combo1
            _Update()
        Case $Button1

    EndSwitch
WEnd

Func _Update()

    Local $hBitmap[3], $hGraphic, $hFamily, $hFont, $hFormat, $hBrush, $tLayout, $aData, $Text

    Switch _GUICtrlComboBox_GetCurSel($Combo1)
        Case 0 ; English
            $Text = 'Button'
        Case 1 ; Русский
            $Text = 'Кнопка'
        Case Else
            $Text = ''
    EndSwitch
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hPng[0])
    $hFamily = _GDIPlus_FontFamilyCreate('Segoe UI')
    $hFont = _GDIPlus_FontCreate($hFamily, 14, 0, 2)
    $tLayout = _GDIPlus_RectFCreate(5, 5, 110, 31)
    $hFormat = _GDIPlus_StringFormatCreate()
    $aData = _GDIPlus_GraphicsMeasureString($hGraphic, $Text, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDispose($hGraphic)
    DllStructSetData($aData[0], 1, 5 + (110 - DllStructGetData($aData[0], 3)) / 2)
    DllStructSetData($aData[0], 2, 5 + (31 - DllStructGetData($aData[0], 4)) / 2)
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF000000)
    For $i = 0 To 2
        $hBitmap[$i] = _GDIPlus_ImageClone($hPng[$i])
        $hGraphic = _GDIPlus_ImageGetGraphicsContext($hBitmap[$i])
        _GDIPlus_GraphicsSetTextRenderingHint($hGraphic, 5)
        _GDIPlus_GraphicsDrawStringEx($hGraphic, $Text, $hFont, $aData[0], $hFormat, $hBrush)
        _GDIPlus_GraphicsDispose($hGraphic)
    Next
    _Skin_SetButtonEx($Button1, $hBitmap[0], $hBitmap[1], $hBitmap[2], 0, $hBitmap[2], 1, 1)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_BrushDispose($hBrush)
EndFunc   ;==>_Update

Func _GDIPlus_ImageClone($hImage)
    Local $aResult = DllCall($__g_hGDIPDll, "int", "GdipCloneImage", "handle", $hImage, "handle*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)
    Return $aResult[2]
EndFunc   ;==>_GDIPlus_ImageClone

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    Local $Msg = BitShift($wParam, 16)

    Switch $hWnd
        Case $Form1
            Switch BitAND($wParam, 0xFFFF)
                Case $Combo1
                    Switch $Msg
                        Case $CBN_CLOSEUP
                            $Skin = 1
                        Case $CBN_DROPDOWN
                            $Skin = 0
                        Case Else

                    EndSwitch
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func WM_NCHITTEST($hWnd, $iMsg, $wParam, $lParam)
    Switch $hWnd
        Case $Form1
            If $skData[0][3] > 0 Then
                Return $GUI_RUNDEFMSG
            EndIf
            Local $Info = GUIGetCursorInfo($Form1)
            If Not @error Then
                Switch $Info[4]
                    Case $Button1
                        ; Nothing
                    Case Else
                        Return $HTCAPTION
                EndSwitch
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NCHITTEST



Думай, прежде чем говорить.

Оффлайн Alofa [?]

  • AutoIt Гуру
  • *****
  • Сообщений: 1420
  • Репутация: 207
  • Пол: Мужской
  • Windows 7 /10 [x64]
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Добавление текста на кнопки с рисунком
« Ответ #9, Отправлен: Февраль 03, 2016, 11:27:34 »
OffTopicYashied
Эх, не выдержала душа поэта  :)

Оффлайн avtoIT [?]

  • Новичок
  • *
  • Сообщений: 94

  • Автор темы
  • Репутация: 0
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.14.0
Re: Добавление текста на кнопки с рисунком
« Ответ #10, Отправлен: Февраль 03, 2016, 13:57:17 »
Alofa, joiner, Yashied, большое спасибо, надеюсь, что более по этой теме от меня постов вы не увидите:)

Оффлайн avtoIT [?]

  • Новичок
  • *
  • Сообщений: 94

  • Автор темы
  • Репутация: 0
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.14.0
Re: Добавление текста на кнопки с рисунком
« Ответ #11, Отправлен: Февраль 05, 2016, 21:22:51 »
Хм... Интересно, попробовал изменить текст кнопки с "Вперед" на "Далее" и у меня вылазит ошибка (Прекращена работа программы...)
Не подскажите из-за чего это может случаться?

Оффлайн Yashied [?]

  • AutoIt MVP
  • Глобальный модератор
  • *
  • Сообщений: 5379
  • Репутация: 2695
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.x.x
Re: Добавление текста на кнопки с рисунком
« Ответ #12, Отправлен: Февраль 05, 2016, 23:22:04 »
avtoIT, вы уже не первый день на форуме. Хотите получить квалифицированный ответ, выкладывайте пример, демонстрирующий данную ошибку. В следующий раз я буду подобные посты удалять.

Оффлайн avtoIT [?]

  • Новичок
  • *
  • Сообщений: 94

  • Автор темы
  • Репутация: 0
  • Пол: Мужской
    • Награды
  • Версия AutoIt: 3.3.14.0
Re: Добавление текста на кнопки с рисунком
« Ответ #13, Отправлен: Февраль 06, 2016, 21:16:01 »
Код: AutoIt [Выделить]
#include <APIConstants.au3>
#include <GUIConstants.au3>
#include <GDIPlus.au3>
#include <WinAPIEx.au3>

#include "Skin.au3"



_GDIPlus_Startup()

Global $hPng[3] = [_GDIPlus_BitmapCreateFromFile('butc1.png'), _GDIPlus_BitmapCreateFromFile('butc2.png'), _GDIPlus_BitmapCreateFromFile('butc3.png')]
Global $Form1, $Button1, $nMsg, $Skin = True

$Form1 = GUICreate('Form1', 350, 200, -1, -1, BitOR($WS_BORDER, $WS_POPUP))
GUICtrlCreatePic('bck.bmp', 0, 0, 350, 200)
GUICtrlSetState(-1, $GUI_DISABLE)

$Button1 = _Skin_AddButtonEx(234, 162, 120, 42, $hPng[0], $hPng[1], $hPng[2], '', $hPng[2], 1)

GUIRegisterMsg($WM_NCHITTEST, 'WM_NCHITTEST')
_Update($Button1, 'Далее')
GUISetState()

While 1
    If $Skin Then
        _Skin_Helper($Form1)
    EndIf
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1

    EndSwitch
WEnd

Func _Update($buttonthatwillbetexted, $textthatwillbeonbuttontexted)

    Local $hBitmap[3], $hGraphic, $hFamily, $hFont, $hFormat, $hBrush, $tLayout, $aData




    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hPng[0])
    $hFamily = _GDIPlus_FontFamilyCreate('Segoe UI')
    $hFont = _GDIPlus_FontCreate($hFamily, 14, 0, 2)
    $tLayout = _GDIPlus_RectFCreate(5, 5, 110, 31)
    $hFormat = _GDIPlus_StringFormatCreate()
    $aData = _GDIPlus_GraphicsMeasureString($hGraphic, $textthatwillbeonbuttontexted, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDispose($hGraphic)
    DllStructSetData($aData[0], 1, 5 + (110 - DllStructGetData($aData[0], 3)) / 2)
    DllStructSetData($aData[0], 2, 5 + (31 - DllStructGetData($aData[0], 4)) / 2)
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF000000)
    For $i = 0 To 2
        $hBitmap[$i] = _GDIPlus_ImageClone($hPng[$i])
        $hGraphic = _GDIPlus_ImageGetGraphicsContext($hBitmap[$i])
        _GDIPlus_GraphicsSetTextRenderingHint($hGraphic, 5)
        _GDIPlus_GraphicsDrawStringEx($hGraphic, $textthatwillbeonbuttontexted, $hFont, $aData[0], $hFormat, $hBrush)
        _GDIPlus_GraphicsDispose($hGraphic)
    Next
    _Skin_SetButtonEx($buttonthatwillbetexted, $hBitmap[0], $hBitmap[1], $hBitmap[2], 0, $hBitmap[2], 1, 1)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_BrushDispose($hBrush)
EndFunc   ;==>_Update

Func _GDIPlus_ImageClone($hImage)
    Local $aResult = DllCall($__g_hGDIPDll, "int", "GdipCloneImage", "handle", $hImage, "handle*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)
    Return $aResult[2]
EndFunc   ;==>_GDIPlus_ImageClone



Func WM_NCHITTEST($hWnd, $iMsg, $wParam, $lParam)
    Switch $hWnd
        Case $Form1
            If $skData[0][3] > 0 Then
                Return $GUI_RUNDEFMSG
            EndIf
            Local $Info = GUIGetCursorInfo($Form1)
            If Not @error Then
                Switch $Info[4]
                    Case $Button1
                        ; Nothing
                    Case Else
                        Return $HTCAPTION
                EndSwitch
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NCHITTEST
 


P.s. прошу прощения за супер-классные имена переменных
« Последнее редактирование: Февраль 06, 2016, 21:25:42 от avtoIT »

Оффлайн Alofa [?]

  • AutoIt Гуру
  • *****
  • Сообщений: 1420
  • Репутация: 207
  • Пол: Мужской
  • Windows 7 /10 [x64]
    • Награды
  • Версия AutoIt: 3.3.12.0
Re: Добавление текста на кнопки с рисунком
« Ответ #14, Отправлен: Февраль 06, 2016, 22:45:22 »
Хм... Интересно, попробовал изменить текст кнопки ...
... или изменили названия рисунков?
Пример вполне рабочий.


Добавлено: Февраль 06, 2016, 23:00:41
... прошу прощения за супер-классные имена переменных
Не надо просить прощения - почитайте ка это:
(нажмите для показа/скрытия)
« Последнее редактирование: Февраль 06, 2016, 23:13:12 от Alofa »

Русское сообщество AutoIt

Re: Добавление текста на кнопки с рисунком
« Ответ #14 Отправлен: Февраль 06, 2016, 22:45:22 »

 

Похожие темы

  Тема / Автор Ответов Последний ответ
4 Ответов
2794 Просмотров
Последний ответ Март 10, 2011, 16:28:33
от madmasles
3 Ответов
5138 Просмотров
Последний ответ Декабрь 28, 2011, 20:55:38
от vadimkou
4 Ответов
5369 Просмотров
Последний ответ Декабрь 06, 2012, 15:56:48
от vaf
0 Ответов
1723 Просмотров
Последний ответ Декабрь 06, 2012, 16:07:56
от madmasles
3 Ответов
2238 Просмотров
Последний ответ Май 16, 2013, 00:58:54
от AZJIO
1 Ответов
1708 Просмотров
Последний ответ Февраль 11, 2014, 11:56:02
от WSWR
1 Ответов
1729 Просмотров
Последний ответ Апрель 25, 2014, 09:06:06
от madmasles
4 Ответов
2269 Просмотров
Последний ответ Апрель 27, 2014, 20:48:50
от alex33
0 Ответов
634 Просмотров
Последний ответ Июнь 06, 2015, 23:13:40
от EasyEasy
16 Ответов
685 Просмотров
Последний ответ Апрель 18, 2018, 11:28:35
от Serega1383