Перевод кода работы с памятью с PureBasic на AutoIt

EnableExplicit 

Global NewList VA() 

Procedure ScanMemory(hWnd.i, FindString$, Method=#PB_Ascii, Address.i=0, MaxAddress.i=$7FFFFFFF) 
  Define.i PID, hProcess, Buffer_Len, Result, BytesRead, RES, I 
  Define *Str_Buffer, *Region_Buff 
  Define MBI.MEMORY_BASIC_INFORMATION 
  
  ;Узнали PID процесса 
  GetWindowThreadProcessId_(hWnd, @PID) 
  If PID 
    
    ;Открыли процесс для полного доступа (НЕ ВСЕГДА МОЖНО) 
    hProcess = OpenProcess_(#PROCESS_ALL_ACCESS|#PROCESS_VM_WRITE|#PROCESS_VM_OPERATION, #False, PID) 
    If hProcess 
      
      ;Преобразовали строку в нужный формат 
      Buffer_Len=StringByteLength(FindString$,Method) 
      Debug Buffer_Len
      *Str_Buffer=AllocateMemory(Buffer_Len) 
      PokeS(*Str_Buffer,FindString$,-1, Method) 
      
      ;Сканируем память 
      Repeat 
        Result=VirtualQueryEx_(hProcess, Address, @MBI.MEMORY_BASIC_INFORMATION, SizeOf(MEMORY_BASIC_INFORMATION)) 
        If Result 
          If MBI\State = #MEM_COMMIT 
            ;Перечисляем доступ, чтобы нам не выдавало адреса которые мы не сможем править потом 
            If MBI\Protect <> #PAGE_READONLY And MBI\Protect <> #PAGE_EXECUTE_READ And MBI\Protect <> #PAGE_GUARD And MBI\Protect <> #PAGE_NOACCESS 
              *Region_Buff=AllocateMemory(MBI\RegionSize) 
              RES=ReadProcessMemory_(hProcess, Address, *Region_Buff, MBI\RegionSize, @BytesRead) 
              If BytesRead > 0 
                For I = 0 To BytesRead 
                  If CompareMemory(*Region_Buff + I, *Str_Buffer, Buffer_Len) 
                    AddElement(VA()) 
                    VA() = MBI\BaseAddress+I 
                  EndIf 
                Next 
              EndIf 
              FreeMemory(*Region_Buff) 
            EndIf 
          EndIf 
          Address=MBI\BaseAddress+MBI\RegionSize 
        Else 
          Break 
        EndIf 
      Until  Address >= MaxAddress 
      FreeMemory(*Str_Buffer) 
      CloseHandle_(hProcess) 
    Else 
      MessageRequester("Error","Не удалось открыть процесс") 
    EndIf 
  Else 
    MessageRequester("Error","Не удалось получить PID") 
  EndIf 
EndProcedure 

ProcedureDLL.s MemoryScan(Title.s, Text.s)
  Define Result.s = ""
  Define hWnd=FindWindow_(#Null, Title) 
  If hWnd 
    ScanMemory(hWnd,Text,#PB_Unicode) 
    ForEach VA()
      Result = Result + Hex(VA(),#PB_Integer) + "|"
    Next  
  EndIf 
  ProcedureReturn Result
EndProcedure  

Debug MemoryScan("Текстовый документ (2) - Блокнот", "Hello")