SQLite Очень медленное добавление записей в таблицу

#include <Date.au3>

 #include <SQLite.au3>
 #include <SQLite.dll.au3>

_SQLite_Startup()
If @error Then
    MsgBox(16, "Ошибка SQLite", "Не удалось загрузить SQLite.dll")
    Exit -1
EndIf


; Запись в TXT
$StartDateTime= _NowCalc()
$hFile=FileOpen(@ScriptDir&'\test.txt',2)
For $i=1 To 1000
	FileWriteLine($hFile,$i)
Next
FileClose($hFile)
; Время работы
$EndDateTime= _NowCalc()
$TimeWork=_DateDiff("s", $StartDateTime, $EndDateTime)
MsgBox(64,'Длительность (сек)',$TimeWork)


; Запись в SQLite данных из TXT-файла
$StartDateTime= _NowCalc()
$SQLite_Data_Path=@ScriptDir&'\test.db'
; Создать Базу данных
	If FileExists($SQLite_Data_Path) Then FileDelete($SQLite_Data_Path) ; Удалить Базу данных, если она существует

	_SQLite_Open($SQLite_Data_Path) ; Создать БД
	If @error Then
		MsgBox(16, "Ошибка SQLite", "Не удалось создать базу данных")
	EndIf
	 ; Создать таблицу tList
	_SQLite_Exec(-1, "Create Table IF NOT Exists tList (ID INTEGER PRIMARY KEY AUTOINCREMENT, Num Text);")
	_SQLite_Close()

$hFile=FileOpen(@ScriptDir&'\test.txt')
While 1
	$line = FileReadLine($hFile)	; Считываем строку из файла
	IF @error = -1 Then ExitLoop
	; Запись данных в таблицу
	_SQLite_Open($SQLite_Data_Path)
	_SQLite_Exec(-1, "Insert into tList (Num) values ('"&$line&"');")
	_SQLite_Close()
WEnd
; Время работы
$EndDateTime= _NowCalc()
$TimeWork=_DateDiff("s", $StartDateTime, $EndDateTime)
MsgBox(64,'Длительность (сек)',$TimeWork)

Exit

#include <SQLite.au3>
;~  #include <SQLite.dll.au3>

Global $sFileDB = @ScriptDir & '\test.db', $hDB, $iTimer, $sExec

_SQLite_Startup()

;~ 1. очень долго (как у Вас)
$iTimer = TimerInit()
$hDB = _SQLite_Open($sFileDB)
_SQLite_Exec($hDB, 'DROP TABLE IF EXISTS TEST;CREATE TABLE TEST([NUM_TEST] INTEGER);')
_SQLite_Close($hDB)
For $i = 1 To 10000
	$hDB = _SQLite_Open($sFileDB)
	_SQLite_Exec($hDB, 'INSERT INTO TEST VALUES (' & $i & ');')
	_SQLite_Close($hDB)
Next
ConsoleWrite(StringFormat('1.\t%.2f sec\n', TimerDiff($iTimer) / 1000))

;~ 2. просто долго
$iTimer = TimerInit()
$hDB = _SQLite_Open($sFileDB)
_SQLite_Exec($hDB, 'DROP TABLE IF EXISTS TEST;CREATE TABLE TEST([NUM_TEST] INTEGER);')
For $i = 1 To 10000
	_SQLite_Exec($hDB, 'INSERT INTO TEST VALUES (' & $i & ');')
Next
_SQLite_Close($hDB)
ConsoleWrite(StringFormat('2.\t%.2f sec\n', TimerDiff($iTimer) / 1000))

;~ 3. быстро
$iTimer = TimerInit()
$hDB = _SQLite_Open($sFileDB)
_SQLite_Exec($hDB, 'BEGIN;DROP TABLE IF EXISTS TEST;CREATE TABLE TEST([NUM_TEST] INTEGER);')
For $i = 1 To 10000
	_SQLite_Exec($hDB, 'INSERT INTO TEST VALUES (' & $i & ');')
Next
_SQLite_Exec($hDB, 'COMMIT;')
_SQLite_Close($hDB)
ConsoleWrite(StringFormat('3.\t%.2f sec\n', TimerDiff($iTimer) / 1000))

;~ 4. еще быстрее
$iTimer = TimerInit()
$sExec = 'BEGIN;DROP TABLE IF EXISTS TEST;CREATE TABLE TEST([NUM_TEST] INTEGER);'
For $i = 1 To 10000
	$sExec &= 'INSERT INTO TEST VALUES (' & $i & ');'
Next
$sExec &= 'COMMIT;'
$hDB = _SQLite_Open($sFileDB)
_SQLite_Exec($hDB, $sExec)
_SQLite_Close($hDB)
ConsoleWrite(StringFormat('4.\t%.2f sec\n', TimerDiff($iTimer) / 1000))

_SQLite_Shutdown()