Что нового

[Файловая система] Получение выбранных элементов в проводнике Windows

musicstashall

Знающий
Сообщения
322
Репутация
7
Всем доброго.

Для получения списка файлов или папок использую такую функцию:

Код:
Func _Selected()
    Local $hWnd = _WinAPI_GetForegroundWindow()
    $class = _WinAPI_GetClassName($hWnd)
    If $class = 'CabinetWClass' Then
        $aSelection = _WindowsExplorer_ExtractSelectedDirAndFiles($hWnd)
		ControlEnable($hWnd, '', '[CLASS:DirectUIHWND; INSTANCE:3]') ; принудительно разблокируем папку
		WinSetState(_WinAPI_GetShellWindow(), '', @SW_ENABLE) ; раб стол разблокировать не удается, нужен элемент Control на раб столе
		;_ArrayDisplay($aSelection)
		Return $aSelection
    EndIf
EndFunc   ;==>_Selected

; ===================================================================================================================
; Name...........: _WindowsExplorer_ExtractSelectedDirAndFiles
; Description....: Function to extract LocationURL and selected files from a "Windows Explorer" Window
; Syntax.........: _WindowsExplorer_ExtractSelectedDirAndFiles($hWnd)
; Parameters.....: $hWnd - Windows handle of an "Windows Explorer" Window
; AutoIt Version.: 3.3.6.1
; Return values..: Success  -   Array
;                               Array[0] = Number of files selected in right-hand Listview
;                               Array[1] = LocationURL - selected in left-hand Treeview or Window Rebar
;                               Array[2] - Array[n] = URL of selected files in right-hand Listview
;                  Failure  -   Array
;                               Array[0] = 0
;                               Array[1] = ""
;                               Sets the @error flag to non-zero.
;                               @error = 1 - $hwnd is not a valid window handle
;                               @error = 2 - $hwnd is not a window handle for an "Windows Explorer" Window
;                               @error = 3 - "Shell.Application" object could not be created
;                               @error = 4 - "$oShellApp.Windows()" object could not be created
; Author.........: Ascend4nt, KaFu, klaus.s
; ===================================================================================================================

Func _WindowsExplorer_ExtractSelectedDirAndFiles($hWnd)
    Local $aExplorerSelectedFiles[2] = [0, ""]
    If Not IsHWnd($hWnd) Then Return SetError(1, 0, $aExplorerSelectedFiles)
    Local $aWinList = WinList("[REGEXPCLASS:(Explore|Cabinet)WClass]")
    While 1
        For $i = 1 To UBound($aWinList) - 1
            If $hWnd = $aWinList[$i][1] Then ExitLoop 2
        Next
        Return SetError(2, 0, $aExplorerSelectedFiles)
    WEnd
    Local $oShellApp = ObjCreate("Shell.Application")
    If Not IsObj($oShellApp) Then Return SetError(3, 0, $aExplorerSelectedFiles)
    Local $oShellApp_Windows = $oShellApp.Windows()
    If Not IsObj($oShellApp_Windows) Then Return SetError(4, 0, $aExplorerSelectedFiles)
    For $oShellApp_Inst In $oShellApp_Windows
        If $oShellApp_Inst.hwnd = $hWnd Then ExitLoop
    Next
    Local $oShellApp_Inst_SelectedItems_Count = $oShellApp_Inst.document.SelectedItems.Count
    Local $oShellApp_Inst_LocationURL = $oShellApp_Inst.LocationURL
    Local $aHexCodes = StringRegExp($oShellApp_Inst_LocationURL, '%([[:xdigit:]]{2})', 3)
    If Not @error Then
        ; Change all the '%xx' values into ';'s (invalid path character)
        $oShellApp_Inst_LocationURL = StringRegExpReplace($oShellApp_Inst_LocationURL, '%([[:xdigit:]]{2})', ';')
        ; Then go through 1 by 1 and replace each ';' in left-to-right order (same as array order)
        For $i = 0 To UBound($aHexCodes) - 1
            $oShellApp_Inst_LocationURL = StringReplace($oShellApp_Inst_LocationURL, ';', ChrW('0x' & $aHexCodes[$i]), 1) ; only the 1st occurrence for each rep!
        Next
    EndIf
    $oShellApp_Inst_LocationURL = StringReplace($oShellApp_Inst_LocationURL, 'file:///', '')
    $aExplorerSelectedFiles[0] = $oShellApp_Inst_SelectedItems_Count
    $aExplorerSelectedFiles[1] = StringReplace($oShellApp_Inst_LocationURL, '/', '\')
    ReDim $aExplorerSelectedFiles[$aExplorerSelectedFiles[0] + 2]
    $oShellApp_Inst_SelectedItems = $oShellApp_Inst.document.SelectedItems
    Local $iCounter = 2
    For $oShellApp_Inst_SelectedItem In $oShellApp_Inst_SelectedItems
        $aExplorerSelectedFiles[$iCounter] = $oShellApp_Inst_SelectedItem.path
        $iCounter += 1
    Next
    $oShellApp = 0
    $oShellApp_Windows = 0
    Return $aExplorerSelectedFiles
EndFunc   ;==>_WindowsExplorer_ExtractSelectedDirAndFiles


Но эта функция почему то блокирует то окно, с которого считываются выбранные файлы или папки. Причем блокирует не всё окно, а только контрол, содержащий папки или файлы. Я подумал, может быть кто-то предложит что-то поновее, либо надо решить вопрос с этим побочным явлением. Спасибо.
 

InnI

AutoIT Гуру
Сообщения
4,912
Репутация
1,429
Автор
M

musicstashall

Знающий
Сообщения
322
Репутация
7
InnI сказал(а):
Все окна и их элементы доступны (не заблокированы).

Очень странно)) У меня, после выполнения функции, окно (контрол в окне) остается недоступным, как и на раб столе. Попробую новые средства... Спасибо.


Добавлено:
Сообщение автоматически объединено:

Новый метод намного лучше, супер. Снимаю шапку)
 
Автор
M

musicstashall

Знающий
Сообщения
322
Репутация
7
Кто знает, нет ли способа получать так же список выбранных элементов с рабочего стола??
 

InnI

AutoIT Гуру
Сообщения
4,912
Репутация
1,429
musicstashall
список выбранных элементов с рабочего стола
Рабочий стол - это стандартный SysListView32, с которым можно работать через
Код:
ControlListView()
Читаем в справке примечание по поводу x64.
 
Верх