Что нового

Проблема с получением исходных данных после отправки формы

Gilman

Новичок
Сообщения
16
Репутация
0
Всем привет, вот уже второй день не могу заставить скрипт, работать должным образом.
Заполнить данные я понял как, а вот добыть не получается.

Код:
#include <IE.au3>
	$oIE = _IECreate ("http://www.highprogrammer.com/cgi-bin/uniqueid/mrzp")
	_IELoadWait($oIE)
	$oForm = _IEFormGetObjByName ($oIE, "realinput")

	$oQuery = _IEFormElementGetObjByName ($oForm, "givennames")
	_IEFormElementSetValue ($oQuery, "Horner")
	$oQuery = _IEFormElementGetObjByName ($oForm, "surnames")
	_IEFormElementSetValue ($oQuery, "John")


	$oQuery = _IEFormElementGetObjByName ($oForm, "passportnumber")
	_IEFormElementSetValue ($oQuery, "123456789")

	$oQuery = _IEFormElementGetObjByName ($oForm, "issuer")
	_IEFormElementOptionSelect ($oQuery, "GBR", 1)

	$oQuery = _IEFormElementGetObjByName ($oForm, "nationality")
	_IEFormElementOptionSelect ($oQuery, "GBR", 1)


	$oQuery = _IEFormElementGetObjByName ($oForm, "by")
	_IEFormElementSetValue ($oQuery, "1989")
		$oQuery = _IEFormElementGetObjByName ($oForm, "bm")
	_IEFormElementSetValue ($oQuery, "04")
		$oQuery = _IEFormElementGetObjByName ($oForm, "bd")
	_IEFormElementSetValue ($oQuery, "23")


	$oQuery = _IEFormElementGetObjByName ($oForm, "ey")
	_IEFormElementSetValue ($oQuery, "2022")
		$oQuery = _IEFormElementGetObjByName ($oForm, "em")
	_IEFormElementSetValue ($oQuery, "04")
		$oQuery = _IEFormElementGetObjByName ($oForm, "ed")
	_IEFormElementSetValue ($oQuery, "22")


	_IEFormElementRadioSelect ($oForm, "M", "sex", 1)


	_IEFormSubmit ($oForm)
	_IELoadWait($oIE)
	Sleep(1000)
	$sPropLink=_IEPropertyGet($oIE, 'outertext')
	FileWriteLine('Log.txt', $sPropLink)



Вместо исходника актуальной страницы сохраняется предыдущая. Прошу подсказать, что нужно сделать, что бы получить содержимое
Код:
<pre>...</pre>

Версия autoit 3.6.2 и IE 11
 
A

Alofa

Гость
Gilman сказал(а):
... Вместо исходника актуальной страницы сохраняется предыдущая.
Вы не правы.

Gilman сказал(а):
... Прошу подсказать, что нужно сделать, что бы получить содержимое
Код:
<pre>...</pre>
Примерно так:
Код:
#include <IE.au3>
$oIE = _IECreate("http://www.highprogrammer.com/cgi-bin/uniqueid/mrzp", 0, 0)
$oForm = _IEFormGetObjByName($oIE, "realinput")
Local $aFormElement[][2] = [['givennames', 'Horner'], ['surnames', 'John'], ['passportnumber', '123456789'], ['by', '1989'], _
		['bm', '04'], ['bd', '23'], ['ey', '2022'], ['em', '04'], ['ed', '22'], ['issuer', 'GBR'], ['nationality', 'GBR']]
For $i = 0 To UBound($aFormElement) - 1
	$oQuery = _IEFormElementGetObjByName($oForm, $aFormElement[$i][0])
	If $i > 8 Then
		_IEFormElementOptionSelect($oQuery, $aFormElement[$i][1], 1)
	Else
		_IEFormElementSetValue($oQuery, $aFormElement[$i][1])
	EndIf
Next
_IEFormElementRadioSelect($oForm, "M", "sex", 1)

_IEFormSubmit($oForm)
_IELoadWait($oIE)
Sleep(1000)

$oInput = _IETagNameGetCollection($oIE, 'pre', 0)
If Not @error Then
	FileWrite('Log.txt', _IEPropertyGet($oInput, 'outertext') & @CRLF & @CRLF)
	ShellExecute('Log.txt')
EndIf
_IEQuit($oIE)


Добавлено:
Сообщение автоматически объединено:

Gilman сказал(а):
... Версия autoit 3.6.2...
Не угадали - это версия SciTE.
 
Автор
G

Gilman

Новичок
Сообщения
16
Репутация
0
Спасибо большое, вчера перепробовал все элементы, но до этого так и не добарлся
 
Верх