[Автоматизация] Excell Перенос строк в другую программу с эмуляцией хоткеев

#include <Excel.au3>
;~ #include <Array.au3>

Global Const $xlUp = -4162

Global $sFileExcel = @ScriptDir & '\Образец.xlsx', _;путь к файлу Excel
		$oObjEr, _;обработчик COM ошибок
		$iVisible = 1, _; Открывать файл Excel в открытом ($iVisible = 0 скрытом) режиме
		$vSheet = 'Лист1', _;имя листа, на котором берем данные (можно номер $vSheet = 1)
		$vStartRow = 1, _ ;номер (или адрес $vStartRow = 'A1') первой ячейки, начиная с которой получаем данные
		$vColumn = 1, _;номер колонки (или буква $vColumn = 'A'), из которой получаем данные
		$oExcel, _; объект Excel
		$oSheet, _;объект Лист
		$iLastRow, _;последняя заполненная ячейка в колонке $vColumn на листе $oSheet
		$oRange, _;объект Range ($vColumn на листе $oSheet ячейки с $vStartRow по $iLastRow
		$aData, _ ;массив с данными
		$sText, _; для получения текста из массива $aData
		$sFileTxt = @ScriptDir & '\Excel.txt', _;;путь к файлу Txt
		$hFile;дескриптор файла $sFileTxt

$oObjEr = ObjEvent('AutoIt.Error', '_Obj_Error')
$oExcel = _ExcelBookOpen($sFileExcel, $iVisible)
If @error Then Exit 1
$oSheet = $oExcel.Sheets($vSheet)
$vStartRow = StringRegExpReplace($vStartRow, '[^\d]', '')
$iLastRow = $oSheet.Cells($oSheet.Rows.Count, $vColumn).End($xlUp).Row;получаем последнюю заполненную ячейку в колонке $vColumn
If $iLastRow - $vStartRow <= 0 Then
	_ExcelBookClose($oExcel)
	Exit 2
EndIf
$oRange = $oSheet.Range($oSheet.Cells($vStartRow, $vColumn), $oSheet.Cells($iLastRow, $vColumn))
$aData = $oExcel.WorksheetFunction.Transpose($oRange.Value);получаем массив значений
_ExcelBookClose($oExcel)
;~ _ArrayDisplay($aData)
;~ для примера сохраняем полученные данные в файл:
For $i = 0 To UBound($aData) - 1
	If StringIsDigit($aData[$i]) Then;забираем только числа
		$sText &= $aData[$i] & @CRLF
	EndIf
Next
$sText = StringTrimRight($sText, 2);убираем перенос строки в конце текста
$hFile = FileOpen($sFileTxt, 2)
FileWrite($hFile, $sText)
FileClose($hFile)

Func _Obj_Error()
	ConsoleWrite('Object error: ' & $oObjEr.number & @TAB & 'Scriptline :' & $oObjEr.scriptline & @LF)
	If IsObj($oExcel) Then _ExcelBookClose($oExcel)
	Exit 13
EndFunc   ;==>_Obj_Error