[Автоматизация] Как быстро установить множество шрифтов?

Const $FONTS   = 0x14

$oShell   = ObjCreate("Shell.Application")
$oWinFonts   = $oShell.Namespace($FONTS)

; шрифты должны быть в директории скрипта
$sFirstFile = FileFindFirstFile("*.*")

If $sFirstFile = -1 Then
    Exit
EndIf

While 1
    Local $sFile = FileFindNextFile($sFirstFile)
    If @error Then ExitLoop
    Switch StringRight($sFile, 3)
    Case 'ttf', 'otf', 'pfm', 'fon'
        $sWinFontsPath = @WindowsDir & '\Fonts\' & $sFile
        $sLocFontsPath = @ScriptDir & '\' & $sFile
        If NOT FileExists($sWinFontsPath) Then
            $oWinFonts.CopyHere($sLocFontsPath)
        Else
            MsgBox(262144, $sFile, 'Файл уже установлен', 1)
        EndIf
    EndSwitch
WEnd

Const $FONTS = 0x14

$oShell = ObjCreate("Shell.Application")
$oWinFonts = $oShell.Namespace($FONTS)

; Fonts must be in the same directory
$sFirstFile = FileFindFirstFile("*.*")

If $sFirstFile = -1 Then
	Exit
EndIf

While 1
	Local $sFile = FileFindNextFile($sFirstFile)
	If @error Then ExitLoop
	Switch StringRight($sFile, 3)
		Case 'ttf', 'otf', 'pfm', 'fon'
			$sWinFontsPath = @WindowsDir & '\Fonts\' & $sFile
			$sLocFontsPath = @ScriptDir & '\' & $sFile
			If Not FileExists($sWinFontsPath) Then
				$oWinFonts.CopyHere($sLocFontsPath)
				$FontTitle = "Install Font"
				If WinExists("$FontTitle") Then
					WinActivate($FontTitle)
					WinWaitActive($FontTitle)
					ControlClick($FontTitle, "", "Button1")
				EndIf
			Else
				MsgBox(262144, $sFile, 'The font is already installed', 1)
			EndIf
	EndSwitch
WEnd

$FontTitle = "Install Font"
				If WinExists("$FontTitle") Then
					WinActivate($FontTitle)
					WinWaitActive($FontTitle)
					ControlClick($FontTitle, "", "Button1")

;...
If WinExists($FontTitle) Then
;...

If WinWait($FontTitle, "", 1) <> 0 Then

;...
$hWin = WinWait('Install Font', '', 3); change 1 or 2 sec.
If $hWin Then
	ControlClick($hWin, '', 'Button1')
EndIf
;...

FileCopy(@ScriptDir & '\Fonts\*.ttf', @WindowsDir & '\Fonts')

#include <GuiMenu.au3>
#include <SendMessage.au3>

$Folder = "D:\Шрифты"
Run("explorer.exe " & $Folder)
WinWaitActive("[class:CabinetWClass]")
Send("^a")
Send("{APPSKEY}")
WinWait("[class:#32768]")
$PopUp = _SendMessage(WinGetHandle("[class:#32768]"), 0x01E1, 0, 0) ;MN_GETHMENU
$MenuItem = _GUICtrlMenu_FindItem($PopUp, "Установить", True)
Do
  If _GUICtrlMenu_GetItemHighlighted($PopUp, $MenuItem) Then ExitLoop
  Send("{DOWN}")
Until 0
Send("{ENTER}")
$wnd = WinWait("Установка шрифтов")
Do
  If WinExists("Установка шрифта") Then
    WinActivate("Установка шрифта")
    Send("{TAB}{SPACE}")
    ControlClick("Установка шрифта", "", "Button1") ; заменить
   ;ControlClick("Установка шрифта", "", "Button2") ; не заменять
    WinWaitClose("Установка шрифта")
  EndIf
Until Not WinExists($wnd)
Send("!{F4}")

#RequireAdmin

#Include <APIConstants.au3>
#Include <WinAPIEx.au3>

Global Const $sSrc = @ScriptDir & '\Fonts'
Global Const $sDst = _WinAPI_ShellGetSpecialFolderPath($CSIDL_FONTS)

$hSearch = FileFindFirstFile($sSrc & '\*.ttf')
If $hSearch = -1 Then
    Exit
EndIf

$Count = 0

While 1
    $File = FileFindNextFile($hSearch)
    If @Error Then
		ExitLoop
	EndIf
	$Name = _WinAPI_GetFontResourceInfo($sSrc & '\' & $File, 1)
    If @Error Then
		ContinueLoop
	EndIf
	If Not FileCopy($sSrc & '\' & $File, $sDst & '\') Then
		ContinueLoop
	EndIf
	If Not RegWrite('HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts', $Name & ' (TrueType)', 'REG_SZ', $sDst & '\' & $File) Then
		ContinueLoop
	EndIf
	If Not _WinAPI_AddFontResourceEx($sDst & '\' & $File) Then
		RegDelete('HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts', $Name & ' (TrueType)')
		ContinueLoop
	EndIf
	$Count += 1
WEnd

FileClose($hSearch)

If $Count Then
	_WinAPI_BroadcastSystemMessage($WM_FONTCHANGE, 0, 0, $BSF_IGNORECURRENTTASK)
EndIf

#include <GuiMenu.au3>
#include <SendMessage.au3>

If @MUILang = "0419" Then
  $ItemText = "Установить"
  $WndInstallText = "Установка шрифтов"
  $WndConfirmText = "Установка шрифта"
Else
  $ItemText = "Install"
  $WndInstallText = "Installing Fonts"
  $WndConfirmText = "Install Font"
EndIf

$Folder = "D:\FontFiles"

Run("explorer.exe " & $Folder)
WinWaitActive("[class:CabinetWClass]")
Send("^a")
Send("{APPSKEY}")
WinWait("[class:#32768]")
$PopUp = _SendMessage(WinGetHandle("[class:#32768]"), 0x01E1, 0, 0) ;MN_GETHMENU
$MenuItem = _GUICtrlMenu_FindItem($PopUp, $ItemText, True)
Do
  If _GUICtrlMenu_GetItemHighlighted($PopUp, $MenuItem) Then ExitLoop
  Send("{DOWN}")
Until 0
Send("{ENTER}")
$wnd = WinWait($WndInstallText)
Do
  If WinExists($WndConfirmText) Then
    WinActivate($WndConfirmText)
    Send("{TAB}{SPACE}")
    ControlClick($WndConfirmText, "", "Button1") ; заменить/replace
   ;ControlClick($WndConfirmText, "", "Button2") ; не заменять/no replace
    WinWaitClose($WndConfirmText)
  EndIf
Until Not WinExists($wnd)
Send("!{F4}")