Что нового

[Элементы GUI] как создать несколько несколько _IECreateEmbedded окон в одной форме

general66

Пришел увидел наследил
Сообщения
211
Репутация
3
подскажите как можно создать в ниже приведенном скрипте на каждой вкладке свое собственное окно IE ,

Код:
#include <IE.au3>
#Include <Restart.au3>
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <TabConstants.au3>
HotKeySet('{ESC}', '_Exit')
$oIE = _IECreateEmbedded()
$Form1 = GUICreate("Form1", 400, 500, 236, 0)
$GUIActiveX = GUICtrlCreateObj($oIE, 15, 35, 230, 460)
$Input1 = GUICtrlCreateInput("логин", 252, 39, 145, 21)
$Input2 = GUICtrlCreateInput("пароль", 252, 69, 145, 21)
$Button1 = GUICtrlCreateButton("пуск", 280, 101, 75, 25)
$Checkbox1 = GUICtrlCreateCheckbox("Авто вход при рестарте", 252, 136, 145, 17)
$Combo1 = GUICtrlCreateCombo("", 252, 8, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData($Combo1, '<пароль\логин>|первый|второй','<пароль\логин>')
$Tab1 = GUICtrlCreateTab(10, 10, 238, 490)
$TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
$TabSheet2 = GUICtrlCreateTabItem("TabSheet2")
$TabSheet3 = GUICtrlCreateTabItem("TabSheet3")
GUICtrlCreateTabItem("")
GUISetState(@SW_SHOW)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Combo1
            Switch GUICtrlRead($Combo1)
                Case 'первый'
                    GUICtrlSetData($Input1, 'логин1')
                    GUICtrlSetData($Input2, 'пароль1')
                Case 'второй'
                    GUICtrlSetData($Input1, 'логин2')
                    GUICtrlSetData($Input2, 'пароль2')
            EndSwitch
        Case $Button1
            _IENavigate($oIE, 'http://autoit-script.ru/autoit3_docs/libfunctions/_ienavigate.htm')
            _IELoadWait($oIE)
            _Login()
            Sleep(5000)
    EndSwitch
WEnd
Func _Login()
Sleep(100)
EndFunc

Func _Exit() ; Выход по горячей клавише
    $oIE = 0
    Exit
EndFunc


у меня или одно окно на всех вкладках или везде пуста, а хотелось бы на 1йо свое окно на второй свое, а на третей без IE. зарание благодарю за помощь
 

gregaz

AutoIT Гуру
Сообщения
1,166
Репутация
299
Вариант:
Код:
#include <GUIConstantsEx.au3>
#include <IE.au3>

$hForm = GUICreate('IE with tabs Demo', 600, 450)

$oIE1= _IECreateEmbedded ()
$oIE2= _IECreateEmbedded ()
GUISetState()

$Tab=GUICtrlCreateTab (5, 25, 590, 400)

GUICtrlCreateTabItem("http://www.autoitscript.com")
GUICtrlCreateObj($oIE1, 5, 47,590, 390)
GUICtrlCreateTabItem("")

GUICtrlCreateTabItem("http://google.Com")
GUICtrlCreateObj($oIE2, 5, 47,590, 390)
GUICtrlCreateTabItem("")

GUICtrlCreateTabItem(3)
GUICtrlCreateLabel("Дождитесь окончания загруки страниц", 10,55,300,20)
GUICtrlCreateTabItem("")

_IENavigate ($oIE1, "http://www.autoitscript.com")
_IENavigate ($oIE2, "http://google.Com")

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
Wend
 
Верх