Что нового

От чего может расти файл подкачки?

Viktor1703

AutoIT Гуру
Сообщения
1,535
Репутация
413
Имеется 2 скрипта, один снимает screenshot с активного окна, а другой принимает и отображает на форме, при включении 2х скриптов в локальном режиме, на ЦП 60% нагрузка, но не в этом дело, при работе на 2х разных ПК ЦП не грузит, но я не знаю как ведёт себя индикатор выделения памяти (файл подкачки) на передающем ПК, в тестовом локальном режиме он постоянно растёт, от ~ 844 мб до 2.4 Гб, в обоих скриптах вроде везде память очищается, не могу понять почему так растёт, а самое главное чтоб этого не происходило на стороннем ПК?!

Receive
Код:
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <Memory.au3>
#include <WinAPIEx.au3>

TCPStartup()
$Main = TCPListen(@IPAddress1, 8080)
If @error Then
	Exit
EndIf

$hForm = GUICreate("", -1, -1, 0, 0, $WS_POPUP, $WS_EX_LAYERED)
GUISetState()

Do
	$Socket = TCPAccept($Main)
Until $Socket <> -1

Global $tHeader = DllStructCreate('byte[4]')
Global $pHeader = DllStructGetPtr($tHeader)
Global $bData = 0, $Count = 0

_GDIPlus_Startup()

While 1
	If Not IsBinary($bData) Then
		$bData = TCPRecv($Socket, 16800, 1)
		If @error Then
			Do
				$Socket = TCPAccept($Main)
			Until $Socket <> -1
		EndIf
	EndIf
	If IsBinary($bData) Then
		If Not $Count Then
			DllStructSetData($tHeader, 1, $bData)
			$tData = DllStructCreate('dword', $pHeader)
			$Size = DllStructGetData($tData, 1)
			$tData = DllStructCreate('byte[' & $Size & ']')
			$pData = DllStructGetPtr($tData)
		EndIf
		$Lenght = BinaryLen($bData)
		$Sum = $Count + $Lenght
		If $Sum > $Size Then
			$dL = $Size - $Count
			$tPart = DllStructCreate('byte[' & $dL & ']', $pData + $Count)
			DllStructSetData($tPart, 1, $bData)
			$tByte = DllStructCreate('byte[' & $Lenght & ']')
			$tRecv = DllStructCreate('byte[' & ($Lenght - $dL) & ']', DllStructGetPtr($tByte) + $dL)
			DllStructSetData($tByte, 1, $bData)
			$bData = DllStructGetData($tRecv, 1)
			$Sum = $Size
		Else
			$tPart = DllStructCreate('byte[' & $Lenght & ']', $pData + $Count)
			DllStructSetData($tPart, 1, $bData)
			$Count = $Sum
			$bData = 0
		EndIf
		If $Sum = $Size Then
			SetScreenshot($hForm, $tData)
			$Count = 0
		EndIf
	EndIf
	Sleep(10)
WEnd

_GDIPlus_Shutdown()
TCPCloseSocket($Socket)
TCPShutdown()

Func SetScreenshot($hWin, ByRef $tData)

	Local $hBitmap, $hPrev, $hScreen, $hMemory, $pMemory, $pStream, $pData, $iSize

	$pData = DllStructGetPtr($tData)
	$iSize = DllStructGetData(DllStructCreate('dword', $pData + 4), 1)
	$hMemory = _MemGlobalAlloc($iSize, $GMEM_MOVEABLE)
	$pMemory = _MemGlobalLock($hMemory)
	_MemMoveMemory($pData + 8, $pMemory, $iSize)
	_MemGlobalUnlock($hMemory)
	$pStream = _WinAPI_CreateStreamOnHGlobal($hMemory)
	$hBitmap = _GDIPlus_BitmapCreateFromStream($pStream)
	$hScreen = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
	_GDIPlus_BitmapDispose($hBitmap)
	_MemGlobalFree($hMemory)
	_WinAPI_UpdateLayeredWindowEx($hWin, 0, 0, $hScreen, 255, 1)
	_WinAPI_DeleteObject($hScreen)
	_WinAPI_ReleaseStream($pStream)
EndFunc

Func _GDIPlus_BitmapCreateFromStream($pStream)
	Local $Ret = DllCall($ghGDIPDll, 'uint', 'GdipCreateBitmapFromStream', 'ptr', $pStream, 'ptr*', 0)
	If (@error) Or ($Ret[0]) Then
		Return SetError(@error, @extended, 0)
	EndIf
	Return $Ret[2]
EndFunc

Send
Код:
#include <APIConstants.au3>
#include <GDIPlus.au3>
#include <Memory.au3>
#include <WinAPIEx.au3>

TCPStartup()
$Socket = TCPConnect(@IPAddress1, 8080)

_GDIPlus_Startup()
Global $tEncoder, $pEncoder, $tParams, $pParams, $tQuality
$tEncoder = _WinAPI_GUIDFromString(_GDIPlus_EncodersGetCLSID("jpg"))
$pEncoder = DllStructGetPtr($tEncoder)
$tParams = _GDIPlus_ParamInit(1)
$pParams = DllStructGetPtr($tParams)
$tQuality = DllStructCreate("int")
DllStructSetData($tQuality, 1, 75)
_GDIPlus_ParamAdd($tParams, $GDIP_EPGQUALITY, 1, $GDIP_EPTLONG, DllStructGetPtr($tQuality))

While 1
	$hWnd = _WinAPI_GetForegroundWindow()
    If $hWnd Then
        Local $iSize = _WinAPI_GetPosFromRect(_WinAPI_GetClientRect($hWnd))
	    TCPSend($Socket, GetScreenshot($hWnd, 0, 0, $iSize[2], $iSize[3], 600))
	    If @error Then
		    $Socket = TCPConnect(@IPAddress1, 8080)
	    EndIf
	EndIf
	Sleep(10)
WEnd

_GDIPlus_Shutdown()
TCPCloseSocket($Socket)
TCPShutdown()

Func GetScreenshot($hWnd, $iX, $iY, $iWidth, $iHeight, $iCombine = 0)
	Local $hSrcDC, $hDstDC, $hDstSv, $hBitmap, $hDesktop, $hScreen, $hMemory, $pMemory, $pStream, $tOut, $pOut, $iSize

	$hSrcDC = _WinAPI_GetDC($hWnd)
	$hScreen = _WinAPI_CreateCompatibleBitmap($hSrcDC, $iWidth, $iHeight)
	$hDstDC = _WinAPI_CreateCompatibleDC($hSrcDC)
	$hDstSv = _WinAPI_SelectObject($hDstDC, $hScreen)
	_WinAPI_BitBlt($hDstDC, $iX, $iY, $iWidth, $iHeight, $hSrcDC, $iX, $iY, $SRCCOPY)
    $tPoint = _WinAPI_GetMousePos(True, $hWnd)
	_WinAPI_DrawSight($hDstDC, $tPoint)
	_WinAPI_SelectObject($hDstDC, $hDstSv)
	_WinAPI_DeleteDC($hDstDC)

	$hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hScreen)
	If $iCombine Then
	    If ($iWidth > $iCombine) Then
            $hBitmap = _GDIPlus_GetImageThumbnail($hBitmap, $iCombine, (($iHeight * $iCombine) / $iWidth))
		ElseIf ($iHeight > $iCombine) Then
		    $hBitmap = _GDIPlus_GetImageThumbnail($hBitmap, (($iWidth * $iCombine) / $iHeight), $iCombine)
	    EndIf
	EndIf

	_WinAPI_DeleteObject($hScreen)
	$pStream = _WinAPI_CreateStreamOnHGlobal(0)
	_GDIPlus_ImageSaveToStream($hBitmap, $pStream, $pEncoder, $pParams)
	_GDIPlus_BitmapDispose($hBitmap)
	$hMemory = _WinAPI_GetHGlobalFromStream($pStream)
	$pMemory = _MemGlobalLock($hMemory)
	$iSize = _MemGlobalSize($hMemory)
	$tOut = DllStructCreate("dword;dword;byte[" & ($iSize - Mod($iSize, 2) + 4) & "]")
	$pOut = DllStructGetPtr($tOut)
	DllStructSetData($tOut, 1, DllStructGetSize($tOut))
	DllStructSetData($tOut, 2, $iSize)
	_MemMoveMemory($pMemory, $pOut + 8, $iSize)
	_MemGlobalFree($hMemory)
	_WinAPI_StrFormatByteSize($iSize)
	_WinAPI_ReleaseStream($pStream)
	Return DllStructGetData(DllStructCreate("byte[" & DllStructGetSize($tOut) & "]", DllStructGetPtr($tOut)), 1)
EndFunc

Func _WinAPI_DrawSight($hDC, $tPoint, $iSize = 1, $Width = 8, $iColor = 0xFF)
	Local $iX = DllStructGetData($tPoint, 1)
	Local $iY = DllStructGetData($tPoint, 2)
	Local $hPen = _WinAPI_CreatePen($Width, $Width, $iColor)
	Local $PenObj = _WinAPI_SelectObject($hDC, $hPen)
	_WinAPI_DrawLine($hDC, $iX, $iY + $iSize, $iX, $iY)
	_WinAPI_DrawLine($hDC, $iX + $iSize, $iY, $iX, $iY)
	_WinAPI_DrawLine($hDC, $iX, $iY - $iSize, $iX, $iY)
	_WinAPI_DrawLine($hDC, $iX - $iSize, $iY, $iX, $iY)
	_WinAPI_SelectObject($hDC, $PenObj)
	_WinAPI_DeleteObject($hPen)
EndFunc

Func _GDIPlus_ImageSaveToStream($hImage, $pStream, $pEncoder, $pParams = 0)
    Local $Ret = DllCall($ghGDIPDll, 'uint', 'GdipSaveImageToStream', 'ptr', $hImage, 'ptr', $pStream, 'ptr', $pEncoder, 'ptr', $pParams)
    If (@error) Or ($Ret[0]) Then
        Return SetError(@error, @extended, 0)
    EndIf
    Return 1
EndFunc

Func _GDIPlus_GetImageThumbnail($hImage, $iWidth, $iHeight)
    Local $Ret = DllCall($ghGDIPDll, 'int', 'GdipGetImageThumbnail', 'ptr', $hImage, 'int', $iWidth, 'int', $iHeight, 'ptr*', 0, 'ptr', 0, 'ptr', 0)
    If (@error) Or ($Ret[0]) Then
        Return SetError(1, 0, 0)
    EndIf
    Return $Ret[4]
EndFunc
 
Автор
V

Viktor1703

AutoIT Гуру
Сообщения
1,535
Репутация
413
Дошло наконец то до меня, я не очещал память созданную функцией _GDIPlus_GetImageThumbnail(), постоянно путаю _GDIPlus_BitmapDispose() и _GDIPlus_ImageDispose() в функции стояла _GDIPlus_BitmapDispose(), а очищать нужно _GDIPlus_ImageDispose()
 

Yashied

Модератор
Команда форума
Глобальный модератор
Сообщения
5,379
Репутация
2,724
;D

Найдите хоть одно отличие.

Код:
Func _GDIPlus_BitmapDispose($hBitmap)
	Local $aResult = DllCall($ghGDIPDll, "int", "GdipDisposeImage", "handle", $hBitmap)
	If @error Then Return SetError(@error, @extended, False)
	Return $aResult[0] = 0
EndFunc   ;==>_GDIPlus_BitmapDispose


Код:
Func _GDIPlus_ImageDispose($hImage)
	Local $aResult = DllCall($ghGDIPDll, "int", "GdipDisposeImage", "handle", $hImage)
	If @error Then Return SetError(@error, @extended, False)
	Return $aResult[0] = 0
EndFunc   ;==>_GDIPlus_ImageDispose




Добавлено:
Сообщение автоматически объединено:

После вызова _WinAPI_GetDC() нужно вызывать _WinAPI_ReleaseDC().
 
Автор
V

Viktor1703

AutoIT Гуру
Сообщения
1,535
Репутация
413
;D странно, зачем же тогда 2е одинаковые функции..., кстати, этот пример (передача скриншота по интернет) Ваш, после _WinAPI_GetDC() вызывается _WinAPI_DeleteDC(), вообщем я решил проблему с утечкой памяти. :smile:
 
Верх