Тема: Удаление файлов из архива *.zip (Прочитано 1736 раз)

Yashied

Я не читал всю эту ветку, но по-моему, это проще сделать с помощью 7Zip.au3. Данный пример выводит информацию о содержимом всех .zip и .7z архивов в указанной папке и всех ее подпапках (обычная рекурсия). _FileListToArrayEx() - это просто улучшенный вариант _FileListToArray().

Код: AutoIt [Выделить]

#Include <7Zip.au3>
#Include <Date.au3>

_FindFiles(@DesktopDir & '\Test', '*.zip;*.7z')

Func _FindFiles($sRoot, $sFile, $sFilter = '*')

    Local $FL

    $FL = _FileListToArrayEx($sRoot, $sFile, 1)
    If Not @error Then
        For $i = 1 To $FL[0]
            _EnumArcFiles($sRoot & '\' & $FL[$i], $sFilter)
        Next
    EndIf
    $FL = _FileListToArrayEx($sRoot, '*', 2)
    If Not @error Then
        For $i = 1 To $FL[0]
            _FindFiles($sRoot & '\' & $FL[$i], $sFile)
        Next
    EndIf
EndFunc   ;==>_FindFiles

Func _EnumArcFiles($sPath, $sFilter)

    ConsoleWrite($sPath & @CR)
    ConsoleWrite('------------------------------------------------------------' & @CR)

    Local $hArc, $tInfo, $Result = 0

    Do
        $hArc = _7ZipOpenArchive(0, $sPath)
        If Not $hArc Then
            ExitLoop
        EndIf
        $tInfo = _7ZipFindFirst($hArc, $sFilter)
        If Not IsDllStruct($tInfo) Then
            ExitLoop
        EndIf
        Do
            $File = DllStructGetData($tInfo, 'szFileName')
            If StringRight($File, 1) <> '\' Then
                ConsoleWrite('File:   ' & $File & @CR)
                ConsoleWrite('Size:   ' & DllStructGetData($tInfo, 'dwOriginalSize') & @CR)
                ConsoleWrite('Date:   ' & _Date_Time_DOSDateToStr(DllStructGetData($tInfo, 'wDate')) & @CR)
                ConsoleWrite('Time:   ' & _Date_Time_DOSTimeToStr(DllStructGetData($tInfo, 'wTime')) & @CR)
                ConsoleWrite('Attrib: ' & DllStructGetData($tInfo, 'szAttribute') & @CR)
                ConsoleWrite(@CR)
            EndIf
            $tInfo = _7ZipFindNext($hArc, $tInfo)
        Until Not IsDllStruct($tInfo)
        $Result = 1
    Until 1
    If Not $Result Then
        ConsoleWrite('Error!' & @CR)
    Else
        ConsoleWrite(@CR)
    EndIf
    Return $Result
EndFunc   ;==>_EnumArcFiles

Func _FileListToArrayEx($sPath, $sFilter = "*", $iFlag = 0)
    Local $hSearch, $aResult, $sFile, $sFileList, $sDelim = "|"
    $sPath = StringRegExpReplace($sPath, "[\\/]+\z", "") & "\"
    If Not FileExists($sPath) Then Return SetError(1, 1, "")
    If StringRegExp($sFilter, "[\\/:><\|]|(?s)\A\s*\z") Then Return SetError(2, 2, "")
    If Not ($iFlag = 0 Or $iFlag = 1 Or $iFlag = 2) Then Return SetError(3, 3, "")
    $hSearch = FileFindFirstFile($sPath & '*')
    If @error Then Return SetError(4, 4, "")
    While 1
        $sFile = FileFindNextFile($hSearch)
        If @error Then ExitLoop
        If ($iFlag + @extended = 2) Then ContinueLoop
        $aResult = DllCall('shlwapi.dll', 'int', 'PathMatchSpecW', 'wstr', $sFile, 'wstr', $sFilter)
        If (Not @error) And ($aResult[0]) Then $sFileList &= $sDelim & $sFile
    WEnd
    FileClose($hSearch)
    If Not $sFileList Then Return SetError(4, 4, "")
    Return StringSplit(StringTrimLeft($sFileList, 1), "|")
EndFunc   ;==>_FileListToArrayEx

EnumArchive.zip

P.S

Удалить файл из архива можно с помощью функции _7ZipDelete() из того же 7Zip.au3.

RUVATA

Yashied
Будет время обязательно попробую... но я решил справиться сам...
при помощи своей наработки я получил структуру в супермассив (все завязано на рекурсию это само сабой

)
А далее дело техники -

Цитата

7za.exe d test.zip -r -x!*.1CD при таких параметракто молниеносно быстро рекурсивно удаляются все файлы кроме *.1СD... причем -x! можно задавать сколь угодно много...

Yashied

"Супермассивы" - это запутанный код + сложное использование + ограничение + нежелательное использование мссива в массиве.

RUVATA

Yashied [?]

Цитата

"Супермассивы" - это запутанный код + сложное использование + ограничение +

Код не слишком запутанный, на мой взгляд... если например сравнить с приведенным вами кодом _FileListToArray()
Разобраться можно, пусть не с ходу как книгу но можно... причем я позаимствовал конструкцию из C++, мой супермассив не что иное как колекция, просто AutoIt добавляет шарма, т.к. не объектноориентированый

Цитата

нежелательное использование массива в массиве.

- это верно... в данном случае это факт, но иначе не выходит - динамическая типизация, невозможность определять классы и т.д.

А вот насчет ограничений и сложного использования - можно по подробнее ?

Yashied

Код: AutoIt [Выделить]

$Demonstration = Struct_Reader('C:\')

Код: [Выделить]

C:\Users\Jack\Desktop\New folder\New AutoIt v3 Script.au3 (71) : ==> Variable used without being declared.:
_ArrayDisplay($Result, "Result")
_ArrayDisplay(^ ERROR