Хочу несколько ячеек для копирования (таких же как CTRL+C)

ClipGet
ClipPut

Global $item[10] ; массив ячеек
For $i = 0 To 9
	HotKeySet("^" & $i, "_Read") ; Ctrl + [0-9] Горячие клавиши для импорта в ячейку
	HotKeySet("^+" & $i, "_Paste") ; Ctrl + Chift + [0-9] Горячие клавиши для экспорта из ячейки в позицию курсора
Next

HotKeySet("{ESC}", "_Exit") ; для выхода из программы
Func _Exit()
	Exit
EndFunc

TraySetIcon("shell32.dll", -218) ; назначаем иконку в трее
TraySetToolTip('Расширенный буфер обмена') ; устанваливает текст иконки в трее

While 1
	Sleep(1000)
WEnd

Func _Read()
	Send('^{INS}') ; копируем выделенное в буфер обмена
	$item[StringRight(@HotKeyPressed, 1)] = ClipGet() ; Сохраняем из буфера обмена в ячейку
	TraySetToolTip(_GetText10Item()) ; для просмотра содержимого ячеек в трее
	; MsgBox(0, 'Сообщение', 'Скопировано', 1) ; сигнализировать о событии
EndFunc

Func _Paste()
	ClipPut($item[StringRight(@HotKeyPressed, 1)]) ; Вставляем из ячейки в буфер обмена
	Send('+{INS}') ; вставляем из буфера в позицию курсора
	; MsgBox(0, 'Сообщение', 'Вставлено', 1)
EndFunc

Func _GetText10Item() ; для просмотра содержимого ячеек в трее
	$sText = ''
	For $i = 0 To 9
		$sText &= $i & ' - ' & StringLeft($item[$i], 20) & @CRLF
	Next
	Return StringTrimRight($sText, 2)
EndFunc