↑  ←  Описание функции


_WinAPI_ShowWindow

Устанавливает состояние отображения указанного окна

#include <WinAPI.au3>
_WinAPI_ShowWindow($hWnd [, $iCmdShow = 5])

Параметры

$hWnd Дескриптор окна
$iCmdShow [необязательный] Указывает как окно будет отображаться:
    @SW_HIDE - Скрывает окно и активизирует другое окно
    @SW_MAXIMIZE - Разворачивает указанное окно
    @SW_MINIMIZE - Сворачивает указанное окно и активизирует следующее окно верхнего уровня в Z-порядке
    @SW_RESTORE - Активизирует и отображает окно восстановленным
    @SW_SHOW - Активизирует окно и отображает его с текущим размером и позицией
    @SW_SHOWDEFAULT - Устанавливает основное состояние отображения окна с SW_ флагом указанным в структуре STARTUPINFO
    @SW_SHOWMAXIMIZED - Активизирует и разворачивает окно
    @SW_SHOWMINIMIZED - Активизирует и сворачивает окно
    @SW_SHOWMINNOACTIVE - Сворачивает окно
    @SW_SHOWNA - Отображает окно в его текущем состоянии
    @SW_SHOWNOACTIVATE - Отображает окно с его последним размером и позицией
    @SW_SHOWNORMAL - Активизирует и отображает окно

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

Искать ShowWindow в библиотеке MSDN

Пример

#include <WinAPI.au3>
; Запуск блокнота
Run('notepad.exe')

; Ожидание 5 секунд до появление окна блокнота
$hWnd = WinWait("[CLASS:Notepad]", "", 5)
If Not $hWnd Then
    MsgBox(4096, 'Сообщение', 'Окно не найдено, завершаем работу скрипта')
    Exit
EndIf

; Поверх всех окон, только для удобства просмотра эффектов
WinSetOnTop($hWnd, "", 1)

; Устанавливает состояния окна
_WinAPI_ShowWindow($hWnd, @SW_HIDE)
If IsHWnd($hWnd) Then MsgBox(4096, 'Сообщение', 'Окно скрыто', 5)
_WinAPI_ShowWindow($hWnd, @SW_SHOW)
If IsHWnd($hWnd) Then MsgBox(4096, 'Сообщение', 'Окно отображено', 5)
_WinAPI_ShowWindow($hWnd, @SW_MINIMIZE)
If IsHWnd($hWnd) Then MsgBox(4096, 'Сообщение', 'Окно свёрнуто', 5)
_WinAPI_ShowWindow($hWnd, @SW_MAXIMIZE)
If IsHWnd($hWnd) Then MsgBox(4096, 'Сообщение', 'Окно на весь экран', 5)
_WinAPI_ShowWindow($hWnd, @SW_RESTORE)
If IsHWnd($hWnd) Then MsgBox(4096, 'Сообщение', 'Окно восстановлено', 5)

; Закрывает блокнот.
WinClose($hWnd)