↑  ←  Описание функции

_SQLite_GetTable

Выводит одномерный массив, содержащий имена колонок и данные выполненного запроса

#include <SQLite.au3>
_SQLite_GetTable($hDB, $sSQL, ByRef $aResult, ByRef $iRows, ByRef $iColumns [, $iCharSize = -1])

Параметры

$hDB Дескриптор открытой базы данных, укажите -1 для использования последней открытой базы данных
$sSQL SQL-выражение, которое будет выполнено
$aResult Вывод результата
$iRows Вывод количества строк данных
$iColumns Вывод количества столбцов
$iCharSize [необязательный] Указывает максимальный размер поля данных

Возвращаемое значение

Успех:Возвращает $SQLITE_OK
Ошибка:Возвращаемое значение можно сравнить с константами $SQLITE_ *
@error:-1 - SQLite сообщил об ошибке (Проверьте возвращаемое значение)
1 - Вызов предотвращен безопасным режимом
2 - Ошибка возвращенная функцией _SQLite_Query в @extended
3 - Ошибка возвращенная функцией _SQLite_FetchNames в @extended
4 - Ошибка возвращенная функцией _SQLite_FetchData в @extended

Примечания

Число значений вставляемых в $aResult будет (($iRows) + 1) * ($iColumns)
это число вставляется в $aResult[0].
Значение NULL будет возвращен как число 0.
Если вам не нужен результат (или его нет), то рассмотрите возможность использования _SQLite_Execute() или _SQLite_Exec().

См. также

_SQLite_GetTable2d, _SQLite_Exec, _SQlite_Query

Пример

#include <SQLite.au3>
#include <SQLite.dll.au3>

Local $aResult, $iRows, $iColumns, $iRval

_SQLite_Startup()
If @error Then
    MsgBox(16, "Ошибка SQLite", "Не удалось загрузить SQLite3.dll")
    Exit -1
EndIf
ConsoleWrite("Версия библиотеки SQLite = " & _SQLite_LibVersion() & @CRLF)
_SQLite_Open() ; открывает базу данных в памяти
If @error Then
    MsgBox(16, "Ошибка SQLite", "Не удалось загрузить базу данных")
    Exit -1
EndIf

; пример таблицы
;   Имя | Возраст
;   -----------------------
;   Алиса   | 43
;   Андрей  | 28
;   Елена   | 21

If Not _SQLite_Exec(-1, "CREATE TEMP TABLE persons (Имя, Возраст);") = $SQLITE_OK Then _  ; создаёт таблицу "persons"
        MsgBox(16, "Ошибка SQLite", _SQLite_ErrMsg())
If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Алиса','43');") = $SQLITE_OK Then _ ; вставляет значения в таблицу
        MsgBox(16, "Ошибка SQLite", _SQLite_ErrMsg())
If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Андрей','28');") = $SQLITE_OK Then _
        MsgBox(16, "Ошибка SQLite", _SQLite_ErrMsg())
If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Елена','21');") = $SQLITE_OK Then _
        MsgBox(16, "Ошибка SQLite", _SQLite_ErrMsg())

; запрос
$iRval = _SQLite_GetTable(-1, "SELECT * FROM persons;", $aResult, $iRows, $iColumns)
If $iRval = $SQLITE_OK Then
;   $aResult выглядит так:
;       [0]    = 8
;       [1]    = Имя
;       [2]    = Возраст
;       [3]    = Алиса
;       [4]    = 43
;       [5]    = Андрей
;       [6]    = 28
;       [7]    = Елена
;       [8]    = 21
    _ArrayDisplay($aResult, "Результат запроса")
Else
    MsgBox(16, "Ошибка SQLite: " & $iRval, _SQLite_ErrMsg())
EndIf

_SQLite_Close()
_SQLite_Shutdown()