_SoundPlay
Воспроизводит звуковой файл.
#include <Sound.au3>
_SoundPlay($aSnd_id [, $iWait])
Параметры
| $aSnd_id | Sound ID массив, возвращённый функцией _SoundOpen() или путь к файлу |
| $iWait |
[необязательный] Этот флаг указывает, будет ли скрипт ожидать завершение проигрывания, перед тем как продолжить: 0 = (по умолчанию) продолжить выполнение скрипта, не ожидая завершение воспроизведения звука 1 = ожидать завершение проигрывания |
Возвращаемое значение
| Успех: | Возвращает 1 |
| Ошибка: | Возвращает 0 и устанавливает @error |
| @error: | 1 = Не удалось воспроизвести |
| 2 = Недопустимое значение параметра $iWait | |
| 3 = Неверный Sound ID. Используйте массив, возвращённый функцией _SoundOpen() или существующий путь к файлу. |
Примечания
В Vista и выше, "\Windows\Media\..." файлы, содержащие пробелы предварительно должны быть открыты с помощью _SoundOpen() с возвращённым Sound ID массивом, чтобы использовать его в _SoundPlay().См. также
_SoundPause, _SoundStop, _SoundSeek, _SoundOpen, _SoundResumeПример
#include <Sound.au3>
Local $sPath = _GetMaxFile(@WindowsDir & '\media', '*.wav')
If @error Then Exit
; Открывает звуковой файл
Local $aSound = _SoundOpen($sPath)
If @error = 2 Then
MsgBox(4096, "Error", "Файл не существует")
Exit
ElseIf @extended Then
Local $iExtended = @extended ; сохраняет значение, потому что @extended может измениться после DllCall
Local $tText = DllStructCreate("char[128]")
DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "ptr", DllStructGetPtr($tText), "int", 128)
MsgBox(4096, "Ошибка", "Не удалось открыть." & @CRLF & _
"Номер ошибки: " & $iExtended & @CRLF & _
"Описание ошибки: " & DllStructGetData($tText, 1) & @CRLF & _
"Обратите внимание: звук еще может быть корректно воспроизведён.")
Else
MsgBox(4096, "Успешно", "Файл открыт успешно")
EndIf
_SoundPlay($aSound, 1)
_SoundClose($aSound)
Func _GetMaxFile($sPath, $sMask)
Local $aFileList = _FileListToArray($sPath, $sMask, 1)
If @error Then SetError(1)
Local $iSize = 0, $sFile = '', $iSizeTmp
For $i = 1 To $aFileList[0]
$iSizeTmp = FileGetSize($sPath & '\' & $aFileList[$i])
If $iSizeTmp > $iSize Then
$sFile = $aFileList[$i]
$iSize = $iSizeTmp
EndIf
Next
Return $sPath & '\' & $sFile
EndFunc ;==>_GetMaxFile