↑  ←  Описание функции

_GUICtrlTreeView_Create

Создаёт TreeView

#include <GuiTreeView.au3>
_GUICtrlTreeView_Create($hWnd, $iX, $iY [, $iWidth=150 [, $iHeight=150 [, $iStyle=0x00000037 [, $iExStyle=0x00000000]]]])

Параметры

$hWnd Дескриптор родительского окна или окна владельца
$iX Координата левого края
$iY Координата верхнего края
$iWidth [необязательный] Ширина элемента
$iHeight [необязательный] Высота элемента
$iStyle [необязательный] Стили элемента:
    $TVS_CHECKBOXES - Добавляет Checkbox для пунктов. Checkbox отображается, только если изображение связано с пунктом. При установке этого стиля, TreeView эффективно использует DrawFrameControl для создания и установки списка изображений состояния, содержащего два изображения. Изображение состояния 1 является Checkbox без галочки, а изображение состояния 2 является Checkbox с галочкой. Установка состояния изображения в 0 удаляет Checkbox. Версия 5.80 отображает Checkbox даже если изображение не связано с пунктом.
    $TVS_DISABLEDRAGDROP - Предотвращает высылку уведомления TVN_BEGINDRAG элементу TreeView
    $TVS_EDITLABELS - Позволяет пользователю редактировать тексты пунктов
    $TVS_FULLROWSELECT - Разрешает полное выделение строки. Вся строка выбранного пункта подсвечивается, и клик в любой части строки пункта приводит к его выбору. Этот стиль не может использоваться в сочетании с $TVS_HASLINES style.
    $TVS_HASBUTTONS - Отображает кнопки плюс "+" и минус "-" возле родительских пунктов. Пользователь кликает кнопки свернуть или развернуть родительский пункт с вложенными пунктами. Чтобы добавить кнопки плюс (+) и минус (-) для пунктов в корне дерева укажите также стиль $TVS_LINESATROOT.
    $TVS_HASLINES - Использовать линии, отображающие иерархию пунктов
    $TVS_INFOTIP - Получение ToolTip информации, отправив уведомление $TVN_GETINFOTIP     $TVS_LINESATROOT - Использовать линии, отображающие иерархию для пунктов в корне дерева. Это значение игнорируется, если не указан стиль $TVS_HASLINES.
    $TVS_NOHSCROLL - Отключает горизонтальную прокрутку. TreeView не отобразит ни каких горизонтальных полос прокрутки.
    $TVS_NONEVENHEIGHT - Высота пунктов может быть установлена до нечетного значения высоты с использованием сообщения TVM_SETITEMHEIGHT. По умолчанию высота пунктов должна быть четным значением.
    $TVS_NOSCROLL - Отключает вертикальную и горизонтальную прокрутки. TreeView не будет отображать ни каких полос прокрутки.
    $TVS_NOTOOLTIPS - Отключает ToolTips
    $TVS_RTLREADING - Отображает текст справа-налево, для таких языков, как иврит или арабский, которые читаются справа-налево
    $TVS_SHOWSELALWAYS - Выделенный пункт остаётся выделенным, когда TreeView теряет фокус.
    $TVS_SINGLEEXPAND - Клик на пункте будет автоматически разворачивать его дерево и сворачивать остальные невыбранные пункты оставшееся от предыдущего выбора. Если мышь использует одиночный клик для выбора пункта и этот пункт свёрнут, то клик развернёт пункт. Если пользователь удерживает клавишу CTRL при выборе пункта, остальные невыбранные пункты не будет сворачиваться. Версия 5.80 - клик на пункте будет автоматически разворачивать его дерево и сворачивать остальные невыбранные пункты оставшееся от предыдущего выбора. Если пользователь удерживает клавишу CTRL при выборе пункта, остальные невыбранные пункты не будет сворачиваться.
    $TVS_TRACKSELECT - Подчёркивает текст пункта при наведении на него
    По умолчанию: $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS     Принудительно: $WS_CHILD, $WS_VISIBLE
$iExStyle [необязательный] Расширенные стили элемента

Возвращаемое значение

Успех:Возвращает дескриптор элемента
Ошибка:Возвращает 0

Примечания

Эта функция предназначена для опытных пользователей и для изучения того, как элемент работает.

См. также

_GUICtrlTreeView_Destroy

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $hTreeView

_Main()

Func _Main()

    Local $GUI, $hItem
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
    $GUI = GUICreate("Создание TreeView (UDF)", 400, 300)

    $hTreeView = _GUICtrlTreeView_Create($GUI, 2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 1 To Random(2, 10, 1)
        $hItem = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] Пункт", $x))
        For $y = 1 To Random(2, 10, 1)
            _GUICtrlTreeView_AddChild($hTreeView, $hItem, StringFormat("[%02d] Дочерний", $y))
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndTreeview
    $hWndTreeview = $hTreeView
    If Not IsHWnd($hTreeView) Then $hWndTreeview = GUICtrlGetHandle($hTreeView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndTreeview
            Switch $iCode
                Case $NM_CLICK ; Высылается, когда пользователь кликнул левой кнопкой мыши на пункте
                    _DebugPrint("$NM_CLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; не ноль, чтобы не допустить встроенную обработку
                    Return 0 ; ноль, чтобы допустить встроенную обработку
                Case $NM_DBLCLK ; Высылается, когда пользователь сделал двойной клик левой кнопкой мыши на пункте
                    _DebugPrint("$NM_DBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; не ноль, чтобы не допустить встроенную обработку
                    Return 0 ; ноль, чтобы допустить встроенную обработку
                Case $NM_RCLICK ; Высылается, когда пользователь кликнул правой кнопкой мыши на пункте
                    _DebugPrint("$NM_RCLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; не ноль, чтобы не допустить встроенную обработку
                    Return 0 ; ноль, чтобы допустить встроенную обработку
                Case $NM_RDBLCLK ; Высылается, когда пользователь сделал двойной клик правой кнопкой мыши на пункте
                    _DebugPrint("$NM_RDBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; не ноль, чтобы не допустить встроенную обработку
                    Return 0 ; ноль, чтобы допустить встроенную обработку
                Case $NM_KILLFOCUS ; Высылается, когда TreeView теряет фокус
                    _DebugPrint("$NM_KILLFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $NM_RETURN ; Элемент управления имеет фокус ввода и пользователь нажал клавишу
                    _DebugPrint("$NM_RETURN" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; не ноль, чтобы не допустить встроенную обработку
                    Return 0 ; ноль, чтобы допустить встроенную обработку
;~              Case $NM_SETCURSOR ; Элемент устанавливает курсор в ответ на сообщение WM_SETCURSOR
;~                  Local $tinfo = DllStructCreate($tagNMMOUSE, $ilParam)
;~                  $hWndFrom = HWnd(DllStructGetData($tinfo, "hWndFrom"))
;~                  $iIDFrom = DllStructGetData($tinfo, "IDFrom")
;~                  $iCode = DllStructGetData($tinfo, "Code")
;~                  _DebugPrint("$NM_SETCURSOR" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
;~                          "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
;~                          "-->Code:" & @TAB & $iCode & @LF & _
;~                          "-->ItemSpec:" & @TAB & DllStructGetData($tinfo, "ItemSpec") & @LF & _
;~                          "-->ItemData:" & @TAB & DllStructGetData($tinfo, "ItemData") & @LF & _
;~                          "-->X:" & @TAB & DllStructGetData($tinfo, "X") & @LF & _
;~                          "-->Y:" & @TAB & DllStructGetData($tinfo, "Y") & @LF & _
;~                          "-->HitInfo:" & @TAB & DllStructGetData($tinfo, "HitInfo"))
;~                  Return 0 ; to enable the control to set the cursor
;~                  Return 1 ; nonzero to prevent the control from setting the cursor
                Case $NM_SETFOCUS ; Высылается, когда TreeView получил фокус
                    _DebugPrint("$NM_SETFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $TVN_BEGINDRAGA, $TVN_BEGINDRAGW
                    _DebugPrint("$TVN_BEGINDRAG")
                Case $TVN_BEGINLABELEDITA, $TVN_BEGINLABELEDITW
                    _DebugPrint("$TVN_BEGINLABELEDIT")
                Case $TVN_BEGINRDRAGA, $TVN_BEGINRDRAGW
                    _DebugPrint("$TVN_BEGINRDRAG")
                Case $TVN_DELETEITEMA, $TVN_DELETEITEMW
                    _DebugPrint("$TVN_DELETEITEM")
                Case $TVN_ENDLABELEDITA, $TVN_ENDLABELEDITW
                    _DebugPrint("$TVN_ENDLABELEDIT")
                Case $TVN_GETDISPINFOA, $TVN_GETDISPINFOW
                    _DebugPrint("$TVN_GETDISPINFO")
                Case $TVN_GETINFOTIPA, $TVN_GETINFOTIPW
                    _DebugPrint("$TVN_GETINFOTIP")
                Case $TVN_ITEMEXPANDEDA, $TVN_ITEMEXPANDEDW
                    _DebugPrint("$TVN_ITEMEXPANDED")
                Case $TVN_ITEMEXPANDINGA, $TVN_ITEMEXPANDINGW
                    _DebugPrint("$TVN_ITEMEXPANDING")
                Case $TVN_KEYDOWN
                    _DebugPrint("$TVN_KEYDOWN")
                Case $TVN_SELCHANGEDA, $TVN_SELCHANGEDW
                    _DebugPrint("$TVN_SELCHANGED")
                Case $TVN_SELCHANGINGA, $TVN_SELCHANGINGW
                    _DebugPrint("$TVN_SELCHANGING")
                Case $TVN_SETDISPINFOA, $TVN_SETDISPINFOW
                    _DebugPrint("$TVN_SETDISPINFO")
                Case $TVN_SINGLEEXPAND
                    _DebugPrint("$TVN_SINGLEEXPAND")
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Строка(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint