_GUICtrlMenu_SetItemSubMenu
Связывает выпадающее меню или подменю с указанным пунктом меню
#include <GuiMenu.au3>
_GUICtrlMenu_SetItemSubMenu($hMenu, $iItem, $hSubMenu [, $fByPos = True])
Параметры
| $hMenu | Дескриптор меню |
| $iItem |
Идентификатор или позиция пункта меню |
| $hSubMenu |
Дескриптор выпадающего меню или подменю |
| $fByPos |
[необязательный] Флаг для идентификации меню: True - $iItem является позицией пункта, отсчёт от 0 False - $iItem является идентификатором пункта |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
См. также
_GUICtrlMenu_GetItemSubMenuПример
#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout
; Создаёт GUI
$hGUI = GUICreate("Связывает подменю с пунктом", 400, 300)
; Создаёт меню "Файл"
$hFile = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hFile, 0, 'Новый', $idNew)
_GUICtrlMenu_InsertMenuItem ($hFile, 1, 'Открыть', $idOpen)
_GUICtrlMenu_InsertMenuItem ($hFile, 2, 'Сохранить', $idSave)
_GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem ($hFile, 4, 'Выход', $idExit)
; Создаёт меню "Правка"
$hEdit = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hEdit, 0, 'Вырезать', $idCut)
_GUICtrlMenu_InsertMenuItem ($hEdit, 1, 'Копировать', $idCopy)
_GUICtrlMenu_InsertMenuItem ($hEdit, 2, 'Вставить', $idPaste)
; Создаёт меню "Справка"
$hHelp = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hHelp, 0, 'О программе', $idAbout)
; Создаёт главное меню
$hMain = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hMain, 0, 'Файл', 0, $hFile)
_GUICtrlMenu_InsertMenuItem ($hMain, 1, 'Правка', 0, $hEdit)
_GUICtrlMenu_InsertMenuItem ($hMain, 2, 'Справка', 0, 0)
; Устанавливает главное меню окна
_GUICtrlMenu_SetMenu ($hGUI, $hMain)
; Создаёт элемент для заметок
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Установить / получить меню "Справка"
MemoWrite('Дескриптор подменю "Справка": ' & _GUICtrlMenu_GetItemSubMenu ($hMain, 2))
_GUICtrlMenu_SetItemSubMenu ($hMain, 2, $hHelp)
MemoWrite('Дескриптор подменю "Справка": ' & _GUICtrlMenu_GetItemSubMenu ($hMain, 2))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite