↑  ←  Описание функции


_GUICtrlMenu_GetItemText

Возвращает текст указанного пункта меню

#include <GuiMenu.au3>
_GUICtrlMenu_GetItemText($hMenu, $iItem [, $fByPos = True])

Параметры

$hMenu Дескриптор меню
$iItem Идентификатор или позиция пункта меню
$fByPos [необязательный] Флаг для идентификации меню:
    True - $iItem является позицией пункта, отсчёт от 0
    False - $iItem является идентификатором пункта

Возвращаемое значение

Успех:Возвращает текст пункта меню
Ошибка:Устанавливает @error

См. также

_GUICtrlMenu_SetItemText

См. также

Искать GetMenuString в библиотеке MSDN

Пример

#include <GuiMenu.au3>

_Main()

Func _Main()
    Local $hWnd, $hMain, $hFile

    ; Запуск блокнота
    Run("notepad.exe")
    $hWnd = WinWaitActive("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)
    $hFile = _GUICtrlMenu_GetItemSubMenu($hMain, 0)

    ; Установить / получить текст пункта "Файл/Открыть..."
    Writeln("Текст пункта: " & _GUICtrlMenu_GetItemText($hFile, 1))
    _GUICtrlMenu_SetItemText($hFile, 1, "Изменённый текст пункта")
    Writeln("Текст пункта: " & _GUICtrlMenu_GetItemText($hFile, 1))

EndFunc   ;==>_Main

; Записывает строку текста в блокнот
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", $sText & @CR)
EndFunc   ;==>Writeln