↑  ←  Описание функции

_GUICtrlListView_SetBkColor

Устанавливает цвет фона ListView

#include <GuiListView.au3>
_GUICtrlListView_SetBkColor($hWnd, $iColor)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iColor Устанавливаемый цвет фона или CLR_NONE - без фонового цвета

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlListView_GetBkColor

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <Constants.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView - Устанавливает цвет фона", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Устанавливает цвет (BGR)
    _GUICtrlListView_SetBkColor($hListView, $CLR_MONEYGREEN)
    _GUICtrlListView_SetTextColor($hListView, $CLR_BLACK)
    _GUICtrlListView_SetTextBkColor($hListView, $CLR_MONEYGREEN)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 100)

    ; Добавляет пункты
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($hListView, "Пункт " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Показывает цвет
    MsgBox(4160, "Информация", "Цвет фона ...............: " & _GUICtrlListView_GetBkColor($hListView) & @CRLF & _
            "Цвет текста ............: " & _GUICtrlListView_GetTextColor($hListView) & @CRLF & _
            "Цвет фона текста: " & _GUICtrlListView_GetTextBkColor($hListView))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main