↑  ←  Описание функции


_GUICtrlListView_InsertGroup

Добавляет группу

#include <GuiListView.au3>
_GUICtrlListView_InsertGroup($hWnd, $iIndex, $iGroupID, $sHeader [, $iAlign = 0])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс добавляемой группы. Если -1, то группа добавляется в конец списка.
$iGroupID Идентификатор группы (ID)
$sHeader Текст заголовка
$iAlign [необязательный] Выравнивание текста заголовка группы:
    0 - Влево
    1 - По центру
    2 - Вправо

Возвращаемое значение

Успех:Возвращает индекс добавляемой группы
Ошибка:Возвращает -1

Примечания

Минимальная ОС - Windows XP.

Группы невозможно добавить в пустой ListView.

См. также

_GUICtrlListView_SetItemGroupID

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hImage, $hListView

    GUICreate("ListView - Вставляет группу", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    ; Устанавливает расширенный стиль
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Колонка 1", 120)
    _GUICtrlListView_AddColumn($hListView, "Колонка 2", 120)
    _GUICtrlListView_AddColumn($hListView, "Колонка 3", 120)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1, 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2, 2)
    _GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1, 2)
    _GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

    ; Создание групп
    _GUICtrlListView_EnableGroupView($hListView)
    _GUICtrlListView_InsertGroup($hListView, -1, 1, "Группа 1")
    _GUICtrlListView_InsertGroup($hListView, -1, 2, "Группа 2")
    _GUICtrlListView_SetItemGroupID($hListView, 0, 1)
    _GUICtrlListView_SetItemGroupID($hListView, 1, 2)
    _GUICtrlListView_SetItemGroupID($hListView, 2, 2)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main