↑  ←  Описание функции

_GUICtrlListView_GetGroupRect

Возвращает координаты прямоугольника для указанной группы

#include <GuiListView.au3>
_GUICtrlListView_GetGroupRect($hWnd, $iGroupID [, $iGet = $LVGGR_GROUP])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iGroupID ID группы, информация которой извлекается
$iGet [необязательный] Флаг определяющий координаты получаемого прямоугольника, может быть одним из следующих значений:
    $LVGGR_GROUP - Координаты всей развёрнутой группы
    $LVGGR_HEADER - Координаты только заголовка (свёрнутой группы)
    $LVGGR_LABEL - Координаты только метки
    $LVGGR_SUBSETLINK - Координаты только подмножества строк (помеченное подмножеством)

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - X-координата левого верхнего угла прямоугольника
        [1] - Y-координата левого верхнего угла прямоугольника
        [2] - X-координата правого нижнего угла прямоугольника
        [3] - Y-координата правого нижнего угла прямоугольника

Примечания

Минимальная операционная система: Windows Vista

Пример

If @osversion = "WIN_XP" And MsgBox(4160 + 4 + 256, "Информация", "Эта функция не работает в WinXP" & @lf & "продолжить?") = 7 Then Exit
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $aInfo, $hImage, $hListView

    GUICreate("Получает прямоугольник группы", 400, 300)

    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Колонка 1", 120)
    _GUICtrlListView_AddColumn($hListView, "Колонка 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Колонка 3", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2)
    _GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1)
    _GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

    ; Создание групп
    _GUICtrlListView_EnableGroupView($hListView)
    _GUICtrlListView_InsertGroup($hListView, -1, 1, "Группа 1", 1)
    _GUICtrlListView_InsertGroup($hListView, -1, 2, "Группа 2")
    _GUICtrlListView_SetItemGroupID($hListView, 0, 1)
    _GUICtrlListView_SetItemGroupID($hListView, 1, 2)
    _GUICtrlListView_SetItemGroupID($hListView, 2, 2)

    ; Получает прямоугольник группы с идентификатором - ID 2
    $aInfo = _GUICtrlListView_GetGroupRect($hListView, 2)
    MsgBox(4160, "Информация", "Прямоугольник: " & @LF & _
        @TAB & "Левый: " & $aInfo[0] & @LF & _
        @TAB & "Верхний: " & $aInfo[1] & @LF & _
        @TAB & "Правый: " & $aInfo[2] & @LF & _
        @TAB & "Нижний: " & $aInfo[3])

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>_Main