↑  ←  Описание функции

_GUICtrlListBox_GetCaretIndex

Возвращает индекс пункта, который находится в фокусе прямоугольника

#include <GuiListBox.au3>
_GUICtrlListBox_GetCaretIndex($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех:Возвращает выбранный пункт, отсчёт от 0
Ошибка:Возвращает -1, если нет выбранного пункта

См. также

_GUICtrlListBox_SetCaretIndex

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

; Создаёт GUI
$hGui = GUICreate("Получает индекс в фокусе", 300, 196)
$hListBox = GUICtrlCreateList("", 2, 2, 296, 140, $LBS_MULTIPLESEL)
$Button = GUICtrlCreateButton('Получить', 10, 150, 80, 28)

; Добавляет строки
_GUICtrlListBox_BeginUpdate($hListBox)
For $i = 0 To 8
    _GUICtrlListBox_AddString($hListBox, $i & " Пункт " & Random(10, 99, 1))
Next
_GUICtrlListBox_EndUpdate($hListBox)

GUISetState()

; Цикл выполняется, пока окно не будет закрыто
While 1
    Switch GUIGetMsg()
        Case $Button
            $iIndex = _GUICtrlListBox_GetCaretIndex($hListBox)
            MsgBox(0, 'Сообщение', 'Индекс: ' & $iIndex & @CRLF & _
                    'Текст: ' & _GUICtrlListBox_GetText($hListBox, $iIndex), 0, $hGui)
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd