_GUICtrlComboBoxEx_SetImageList
Устанавливает список изображений для ComboBoxEx
#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetImageList($hWnd, $hHandle)
Параметры
| $hWnd | Дескриптор элемента |
| $hHandle |
Дескриптор списка изображений устанавливаемый в элемент |
Возвращаемое значение
Успех: Возвращает дескриптор предыдущего списка изображений связанного с ComboBoxEx или возвращает NULL, если ранее не был установлен список изображенийСм. также
_GUICtrlComboBoxEx_GetImageListПример
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>
$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hImage, $hCombo
; Создаёт GUI
$hGUI = GUICreate("Устанавливает список изображений", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
$hImage = _GUIImageList_Create (16, 16, 5, 3)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
; Устанавливает список изображений
_GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)
For $x = 0 To 8
_GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)), $x, $x)
Next
; Получает дескриптор списка изображений
MemoWrite("Дескриптор списка изображений : " & _GUICtrlComboBoxEx_GetImageList($hCombo) & @CRLF & _
"IsPtr = " & IsPtr(_GUICtrlComboBoxEx_GetImageList($hCombo)) & @CRLF & _
"IsHwnd = " & IsHWnd(_GUICtrlComboBoxEx_GetImageList($hCombo)))
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite