↑  ←  Описание функции

_GUICtrlComboBoxEx_SetCurSel

Выбирает строку в списке ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetCurSel($hWnd [, $iIndex = -1])

Параметры

$hWnd Дескриптор элемента
$iIndex [необязательный] Индекс выбираемой строки, отсчёт от 0.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Если $iIndex равен -1, то любой текущий выбор в списке убирается и поле ввода очищается.

Если $iIndex больше, чем количество пунктов в списке или если $iIndex равен -1, то возвращаемое значение равно -1 и выбор очищается.

См. также

_GUICtrlComboBoxEx_GetCurSel

Пример

#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hImage, $hCombo

    ; Создаёт GUI
    $hGUI = GUICreate("Выбирает пункт в списке", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
    GUISetState()

    $hImage = _GUIImageList_Create (16, 16, 5, 3)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage ($hCombo, 100, 200)

    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)
    For $x = 0 To 99
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", $x), Random(0, 8, 1), Random(0, 8, 1), Random(0, 8, 1))
    Next
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)

    ; Выбирает пункт в списке
    _GUICtrlComboBoxEx_SetCurSel ($hCombo, Random(0, 99, 1))

    ; Получает выбранный пункт
    MsgBox(4160, "Информация", "Выбранный пункт: " & _GUICtrlComboBoxEx_GetCurSel ($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main